Office: Checkbox mit mehreren Funktionen

Hallo,

ich arbeite mit Excel 2003 und überarbeite grad eine Meldeliste für Dienstplanungen.
In der linken Spalte stehen die Namen der Mitarbeiter (MA).
In der nächsten Spalte wird dann vermerkt, ob ein MA zum nächsten Dienst kommt oder nicht.
Hier wäre dann auch noch die Möglichkeit, den Eintrag offen zu lassen, wenn keine Meldung erfolgt ist.
Bisher wurde das ganze mit X = Teilnahme oder - = keine Teilnahme oder kein Eintrag = keine Meldung gekennzeichnet.
Dies ist allerdings für den Organisator auf dauer etwas aufwendig, weshalb ich das gern durch eine Checkbox erleichtern würde.
(Die Erscheinung ist dann natürlich auch professioneller!)

Sinngemäß: Checkbox leer > 1x klicken = Haken drin > nochmal klicken = Haken wird zu X > nochmal klicken = Checkbox wider leer

Leider kann ich die Checkbox bisher nur mit oder ohne Haken einstellen.
Gibt es Möglichkeiten hierfür eine Art Mehrfachfunktion zu erstellen?


Freundliche Grüße!
Silberfalke84

 

Hi,

welche CheckBoxen verwendest du - Formularsteuerelemente oder ActiveX-Steuerelemente?

Bis später,
Karin

 

Hi Karin,

ich habe bei Google nach einer entsprechenden Funktion gesucht und bin so bei den Formularsteuerelementen gelandet.
Dann habe ich ein bisschen damit experementiert und so herausgefunden wie man z.B. Verknüpfungen mit Zellen einrichten kann.
Dadurch war es dann auch möglich die Haken zählen zu lassen, was auch wichtig für mich war, da die Anzahl der gemeldeten MA ausschlaggebend ist.
Viel weiter geht mein Wissen allerdings noch nicht.

Grüße!
Chris

 

Hi Chris,

ist dein Problem damit gelöst oder noch offen?

Man könnte sich die Kontrollkästchen sparen, wenn man mittels VBA per Doppelklick auf die entsprechende(n) Zelle(n) z.B. ein X in diese Zelle(n) schreibt und diese dann - wie gehabt - zählt.

Bis später,
Karin

 

Hi Karin,

also das Problem besteht noch immer.
VBA sagt mir leider nichts. Wie gesagt, mein Wissen ist hier ziemlich begrenzt.
Bin aber auch für andere Möglichkeiten wie ActiveX offen, falls das zur Lösung beiträgt.
Wichtig sind dabei nur die Funktionen und ein anständiges Erscheinungsbild.

Grüße!
Chris

 

Hi Chris,

leider kenne ich deinen Tabellenblaufbau nicht, deshalb kann ich nur ein prinzipielles Beispiel erstellen: wenn im Bereich B2:B8 ein Doppelklick auf eine Zelle ausgeführt wird, dann wird, falls sie leer ist, ein X eingetragen. Ist bereits ein X vorhanden, wird dieses wieder gelöscht.

Bis später,
Karin

 

Hi Karin,

der Tabellenaufbau passt so. Allerdings ist, wenn ich die Datei öffne, keine Funktion vorhanden (Nur das Zusammenzählen funktioniert).
Die Funktion wäre hier aber auch die Gleiche wie bei der Formular-Checkbox. Also JA (X) oder NEIN/keine Meldung (Checkbox leer) + Zusammenzählen der JAs.

(Finde die Formular-Checkbox optisch ansprechender, aber die könnte man ja z.B. in die entsprechende Zelle zeichnen oder per Rahmen zurechtbauen)

Problem ist jedoch weiterhin die Funktion.
Hier suche ich nach: JA (Haken oder X) oder NEIN (X oder -) oder KEINE INFO (Checkbox leer) + Zusammenzählen der JAs

Also eine Checkbox mit 3 Zuständen + Zusammenzählen der JAs.

Grüße!
Chris

 

Hi Chris,

also du die Mappe geöffnet hast, hast du da die Makros aktiviert? Das ist erforderlich, damit der Code funktioniert.

Wenn du Ja, Nein und leer in der Zelle benötigst, dann ändere den Code - Rechtsklick auf den Tabellenreiter -> Code anzeigen. Dadurch gelangst du in den VBA-Editor und siehst im rechten Fenster den vorhandenen Code. Ersetze ihn durch diesen:

Code:

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   If Not Intersect(Target, Range("B2:B8")) Is Nothing Then
      Cancel = True
      Select Case Target
         Case "Ja"
            Target = "Nein"
         Case "Nein"
            Target.ClearContents
         Case ""
            Target = "Ja"
      End Select
   End If
End Sub

dann erhältst du den von dir gewünschten Zustand Ja -> Nein -> Leer.

Bis später,
Karin

 

Hi Karin,

das funktioniert super und ich hab auch gleich ein bisschen damit experementiert.
Da stellten sich dann folgende Fragen:

1. Wie kann ich den Range so erweitern, dass er nicht blos Spalten oder Zeilen erfasst, sondern auch Felder, mehrere Spalten/Zeilen oder mehrere Einzelzellen usw.?

2. Wie kann ich eine weitere Funktion für eine andere Spalte hinzufügen, so dass z.B. in der ersten Spalte Ja/Nein/Leer auswählbar ist und in der Spalte daneben z.B. Kommentare wie Krank/kommt später/...?

3. Ist die ganze Funktion auch mit einem einfachen klicken statt mit einem Doppelklick möglich?

Grüße!
Chris

 

Hi Chris,

zu 1.: erweitere den Code um die entsprechenden Zellen/Zellbereiche - so in der Art

Code:

If Not Intersect(Target, Range("B2:D12, E20, M19:P30")) Is Nothing Then

zu 2.: um einen anderen Bereich mit anderen Bedingungen festzulegen, muss man das Ganze nur um einen ElseIf-Teil erweitern

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   ' für Bereich B2:B8
   If Not Intersect(Target, Range("B2:B8")) Is Nothing Then
      Cancel = True
      Select Case Target
         Case "Ja"
            Target = "Nein"
         Case "Nein"
            Target.ClearContents
         Case ""
            Target = "Ja"
      End Select
   ' für Bereich C2:C8
   ElseIf Not Intersect(Target, Range("C2:C8")) Is Nothing Then
      Cancel = True
      Select Case Target
         Case "Krank"
            Target = "kommt später"
         Case "kommt später"
            Target = "Urlaub"
         Case "Urlaub"
            Target.ClearContents
         Case ""
            Target = "Krank"
      End Select
   End If
End Sub

zu 3.: theoretisch geht das schon, aber du müsstest erst eine andere Zelle anwählen, ehe du wieder zurück gehst und damit der nächste Text angezeigt würde. Außerdem - falls du es doch in Kauf nehmen würdest erst eine andere Zelle auszuwählen und dann wieder zurück (was allerdings nicht seht produktiv ist) - würde ich persönlich es nicht so lösen, denn es wäre die Gefahr groß, dass du aus Versehen in eine der Zellen klickst und etwas eingetragen würde was nicht gewünscht ist.

Bis später,
Karin

 

Hi Karin,

hab jetzt soweit alles fertig und funktioniert wunderbar :)

Vielen Dank für deine Hilfe!
Grüße!
Chris