Office: VBA ändern

Hallo,

ich hoffe mir kann jemand helfen.

wie kann ich statt die Ausgabe Datum( Date ) den Text: Hallo eingeben:

.Cells(naechste, 4) = Date

Gruß jürgen

 

Noch ein Problem:

kann man den Code so umsetzten, das er es nicht nur in Tabellenblatt"Werkstatt" sondern auch in das Tabellenblatt "Protokoll" einfügt.

Anbei der komplette Code:

Sub zueruck()
Dim naechste As Long
If ActiveCell.Column = 4 Then
If MsgBox("Werkstatt?", vbQuestion + vbYesNo, "Nachfrage") _
_
= vbYes Then
With Worksheets("Werkstatt")

naechste = .Cells(Rows.Count, 1).End(xlUp).Row + 1
.Cells(naechste, 1) = ActiveCell
.Cells(naechste, 2) = ActiveCell.Offset(, 1)
.Cells(naechste, 3) = Application.InputBox("Was ist defekt ?", "Grund")
.Cells(naechste, 4) = Date

End With
ActiveCell.Resize(1, 2).ClearContents
End With
End If
End If

End Sub

Und wenn es geht, wie mache ich das , dass das Tabellenblatt Protokoll gesperrt ist. Damit keiner was herumfuschen kann. Mit Passwort.
Hoffe ihr könnt mir bei meine drei Problemen helfen:-)
Besten Dank
Jürgen

 

Hallo Jürgen,

das wird ja doch nicht allzu schwer zu erraten sein:
.Cells(naechste, 4) = "Hallo"

Was dein von dir angeführtes Makro betrifft: Es ist in dieser Gestalt nicht funktionstüchtig - es enthält einen Syntaxfehler:
Es enthält nur 1 "With"-Anweisung, jedoch 2 "End With"-Anweisungen.

Ich habe das so interpretiert, dass du das, was ins Blatt "Werkstatt" eingefügt wird, gleichzeitig auch ins Blatt "Protokoll" einfügen möchtest.
Hier folgt eine mögliche Code-Version:

Code:

Sub zueruck()
  Dim naechste As Long, naechsteP As Long
  
  If ActiveCell.Column = 4 Then
     With ActiveSheet
        If .Name = "Werkstatt" Then
            naechste = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
            .Cells(naechste, 1) = ActiveCell
            .Cells(naechste, 2) = ActiveCell.Offset(, 1)
            .Cells(naechste, 3) = Application.InputBox("Was ist defekt ?", "Grund")
            .Cells(naechste, 4) = "Hallo"
            
            With Worksheets("Protokoll")
               [COLOR="#0000CD"].Unprotect Password:="123"[/COLOR]
               naechsteP = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
               .Cells(naechsteP, 1) = ActiveCell
               .Cells(naechsteP, 2) = ActiveCell.Offset(, 1)
               .Cells(naechsteP, 3) = Worksheets("Werkstatt").Cells(naechste, 3)
               .Cells(naechsteP, 4) = Worksheets("Werkstatt").Cells(naechste, 4)
               [COLOR="#0000CD"].Protect Password:="123"[/COLOR]
            End With
            
            ActiveCell.Resize(1, 2).ClearContents
            
        Else
           'Meldung falls das falsche Blatt aktiv ist:
            MsgBox "Das aktive Arbeitsblatt ist '" & .Name & "'. " & vbNewLine & _
                   "Es muss aber das Arbeitsblatt 'Werkstatt' sein."
        End If
     End With
  End If

 End Sub

Dieses Makro fragt auch automatisch ab, ob das aktive Arbeitsblatt das Blatt "Werkstatt" ist und ob die aktive Zelle sich in Spalte 4 dieses Arbeitsblattes befindet. Nur dann werden die gewünschten Daten im Arbeitsblatt "Werkstatt" und im Arbeitsblatt "Protokoll" gespeichert.

Im Arbeitsblatt "Protokoll" wurde auch ein Arbeitsblattschutz aktiviert durch den Befehl .Protect Password:="123"
Damit das Makro auch in dieses geschützte Blatt speichern kann, muss das Makro zuvor den Befehl .Unprotect Password:="123" ausführen.
Dabei ist "123" nur ein beispielhaftes Passwort, das du durch dein eigenes ersetzen musst, bevor das Blatt durch das Makro geschützt wird.
Du kannst den .Protect/.Unprotect-Befehl im Makro auch ohne Password-Angabe verwenden, was bedeutet, dass du das Passwort jedesmal händisch eingeben musst und zwar beim Entsperren als auch beim Sperren des Blattes.