Office: In Combobox laden ohne Doppelte Einträge Sortiert

Hallo In meinem Beispiel habe ich 2 Comboboxen in der Eingabe maske (Im Reiter Aktivitätenliste - Eingabemaske userform)
In die 2 Comboboxen soll in der Ersten oben Verantwortlicher aus Reiter Raumzuteilung zum Auswählen gehen natürlich Sortiert und ohne Doppelte Einträge
Und wenn man den Namen gewählt hat dann sollen in der Combobox2 nur noch die Räume aus Spalte C für den Jeweiligen Namen zum Auswählen gehen....

wie sieht da der Vba Code aus???

Danke für Hilfe!

 

Moinsens!

Vom Ablauf her hast Du's ja schon in die richtige Richtung gebracht. Was fehlt noch? Also...

Zunächst rufst Du am besten im UserForm_Initialize() eine separate Sub auf, die für das Füllen der ComboBox1 zuständig ist. Nennen wir sie mal "Private Sub Liste_Zustaendiger_fuellen()"

Entsprechend brauchst Du aber auch noch eine Sub, die ComboBox2 füllt = "Private Sub Liste_Raeume_fuellen()". Diese wird aufgerufen, wenn sich der Wert in ComboBox1 ändert. Wird dort eine andere Person angewählt, wird der Wert dieser 2. Liste gelöscht und die Auswahl auf die passenden Räume gesetzt.

Was muß nun in diese Routine(n)? Du sagst es ja selbst: a) alle zuständigen Personen, keine doppelten Einträge, alphabetisch sortiert. Mal ganz "oldschool" ohne Schickimicki: Ein entsprechend groß dimensioniertes Array wird mit den Werten gefüllt, wobei ein Zähler mitgeführt wird. Eine verschachtelte Schleife entfernt dann die Dubletten, eine weitere verschachtelte Schleife sortiert (Bubble-Sort) die Liste.

Code:

Private Sub Liste_Zustaendiger_fuellen()

    Dim s1 As Worksheet
    Dim y1 As Long
    Dim t1 As String
    Dim n As Integer
    Dim zustaendig(100) As String
    Dim i As Integer
    Dim j As Integer
    
    'abhängige Liste leeren
    '======================
    ComboBox2.Clear


    'Array aufbauen
    '==============
    Set s1 = Worksheets("Raumzuteilung ab Start")
    y1 = 3
    t1 = Trim$(s1.Cells(y1, 5).Value)
    n = 0
    While (t1 <> "")
        n = n + 1
        zustaendig(n) = t1
        y1 = y1 + 1
        t1 = Trim$(s1.Cells(y1, 5).Value)
    Wend


    'Dubletten entfernen
    '===================
    For i = 1 To n
        j = i + 1
        While (j <= n)
            If (zustaendig(j) = zustaendig(i)) Then
                zustaendig(j) = zustaendig(n)
                n = n - 1
              Else
                j = j + 1
            End If
        Wend
    Next i


    'Array sortieren
    '===============
    For i = 1 To n - 1
        For j = i + 1 To n
            If zustaendig(j) < zustaendig(i) Then
                zustaendig(0) = zustaendig(i)
                zustaendig(i) = zustaendig(j)
                zustaendig(j) = zustaendig(0)
            End If
        Next j
    Next i


    'Array auf ComboBox
    '==================
    ComboBox1.Clear
    For i = 1 To n
        ComboBox1.AddItem zustaendig(i)
    Next i


End Sub

Die 2. Routine zum Füllen der Raum-Auswahl sieht fast genau so aus, nur daß hier eben Spalte 3 (statt 5) abgegriffen wird, wenn der Wert in Spalte 5 dem Wert der ComboBox1 entspricht.

Ich hab das mal im Anhang eingebaut. Schau mal, ob es so paßt...

Gruß, Michael