Office: (Office 2007) If Schleife mit Variablen Zellen

Guten Tag,
ich bins mal wieder. Da die Hilfe hier ja super klappt habe ich mal wieder eine Frage, um mir unnötig viel Schreibarbeit zu ersparen.

Diese If-Schleifen habe ich bisher genutzt :

If Target.Count = 1 Then
If Target.Address = "$D$42" Then ' Wenn sich dieses Feld ändert...
Range("I42") = "" ' dann lösche dieses Feld
End If
End If
If Target.Count = 1 Then
If Target.Address = "$D$43" Then ' Wenn sich dieses Feld ändert...
Range("I43") = "" ' dann lösche dieses Feld
End If
End If
If Target.Count = 1 Then
If Target.Address = "$D$44" Then ' Wenn sich dieses Feld ändert...
Range("I44") = "" ' dann lösche dieses Feld
End If
End If

Wie man sieht handelt es sich nur um die Spalten I und D und die betroffenen Zellen liegen immer in der selben Reihe.

Gibt es eine Möglichkeit dies nur mit einer If-Schleife zu lösen?

mein bisheriger ansatz sieht so aus:
Dim y, x, t, k As Integer
s = "CPV Inseln"
t = ""
y = ActiveCell.Row
x = ActiveCell.Column
k = 9
Set wb = ThisWorkbook
Set ws = wb.Worksheets(s)
If Target.Count = 1 Then
If Target.Address = ActiveCell Then
Range("k,y") = ""
End If
End If

Danke schonmal :)

 

Hallo kabumdada,

wenn ich Dich richtig verstanden habe, könnte man es so lösen:

Code:

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    With Me
        If Target.Count = 1 Then                ' nur eine ausgewählte Zelle, kein Bereich
            If Target.Column = 4 Then           ' nur in Spalte 4 = D
                If Target.Row >= 42 And Target.Row <= 44 Then   ' Zeilenbereich begrenzen falls nötig oder gewünscht
                    .Cells(Target.Row, 9) = ""  ' Zelle in Spalte 9 = I und Zeile = Target leeren
                End If
            End If
        End If
    End With

End Sub

Ich hoffe geholfen zu haben.

 

Danke :) Funktioniert soweit schonmal ganz gut :)

Das einzige Problem ist, das sich das Feld in der Spalte I schon leert, sobald man das Feld in Spalte D nur anklickt.
Ich bräucht es aber so, dass es sich erst leert wenn der Inhalt verändert wird.
(In Spalte D sind nur Dropdown felder)

Danke :)

 

Hallo kabumdada,

dann würde ich sowas vorschlagen:

Code:

Option Explicit

Dim varAlterZellWert As Variant     ' Zellwert der aktiven Zelle vor der Änderung


Private Sub Worksheet_Activate()

    ' Zellwert der aktiven Zelle vor der Änderung
    varAlterZellWert = ActiveCell

End Sub

Private Sub Worksheet_Change(ByVal Target As Range)

    With Me

        Application.EnableEvents = False

        If Target.Count = 1 Then                ' nur eine ausgewählte Zelle, kein Bereich
            If Target.Column = 4 Then           ' nur in Spalte 4 = D
                If (Target.Row >= 42 And Target.Row <= 44) Then ' Zeilenbereich begrenzen falls nötig oder gewünscht
                    If Not Target = varAlterZellWert Then       ' wenn Zellwert nicht gleich varAlterZellWert ist
                        .Cells(Target.Row, 9) = ""  ' Zelle in Spalte 9 = I und Zeile = Target leeren
                    End If
                End If
            End If
        End If

        Application.EnableEvents = True

    End With

End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

    ' Zellwert der aktiven Zelle vor der Änderung
    ' wenn nur eine Zelle ausgewählt ist
    If Target.Count = 1 Then
        varAlterZellWert = Target
    End If

End Sub

Der alte Zellwert wird in einer Variablen gespeichert, und mit dem neuen Zellwert verglichen.
Wurde der Zellwert verändert, wird in Spalte I gelöscht, sonst nicht.
Das passiert natürlich erst, nachdem die Zelle verlassen wurde (Enter, Tab, Mausklick in eine andere Zelle....)

Ich hoffe geholfen zu haben.

 

Moinsens!

Streiche aus

Code:

Private Sub Worksheet_[B][COLOR=#ff0000]Selection[/COLOR][/B]Change(ByVal Target As Range)

einfach den rot markierten Teil weg. Dann reagiert er nicht mehr auf Cursorpositions- sondern nur noch auf Zellinhalts-Änderungen.

Gruß, Michael

 

Mirikis Vorschlag ist wie üblich einfacher als meiner... :)))
(Hallo Michael, lange nicht gelesen)

Die Events würde ich temporär aber trotzdem abschalten, weil sonst unnötige Durchläufe entstehen.
Das sähe dann also so aus:

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    With Me

        Application.EnableEvents = False

        If Target.Count = 1 Then                ' nur eine ausgewählte Zelle, kein Bereich
            If Target.Column = 4 Then           ' nur in Spalte 4 = D
                If (Target.Row >= 42 And Target.Row <= 44) Then ' Zeilenbereich begrenzen falls nötig oder gewünscht
                    .Cells(Target.Row, 9) = ""  ' Zelle in Spalte 9 = I und Zeile = Target leeren
                End If
            End If
        End If

        Application.EnableEvents = True

    End With

End Sub

 

Vielen vielen vielen Dank :)

hat eins a geklappt. genau so wie ichs wollte :)

werd mich bei gelegenheit wenn ich wieder Probleme haben sollte hier melden.

Danke schön :)