Office: Excel: Text zwischen 2 Unterstrichen ausgeben

Helfe beim Thema Excel: Text zwischen 2 Unterstrichen ausgeben in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo, ich stehe vor der Aufgabe dass ich die Größe der Artikel aus der Artikelnummer ausgeben muss. Die Artikelnummer hat folgende Struktur:... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von inzeka, 20. September 2022.

  1. inzeka Neuer User

    Excel: Text zwischen 2 Unterstrichen ausgeben


    Hallo,

    ich stehe vor der Aufgabe dass ich die Größe der Artikel aus der Artikelnummer ausgeben muss. Die Artikelnummer hat folgende Struktur:
    AB180_K100_30mm_Elox-schwarz
    Die Größe steht zwischen 2 Unterstrichen und hat 4 oder 5 Zeichen (30mm bis 200mm)

    Es soll "30mm" ausgegeben werden.Wie geht das?

    Danke für Eure Hilfe!
     
  2. Exl121150 Erfahrener User
    Hallo,
    wenn deine Artikelnummer in Zelle A1 steht, kannst du in irgendeiner Zelle folgende Formel eingeben:
    =XMLFILTERN("<x><g>"&WECHSELN(A1;"_";"</g><g>")&"</g></x>";"//g[3]")
     
    Exl121150, 20. September 2022
    #2
  3. inzeka Neuer User
    Danke Anton, das hilft!
    Das übersteigt nur leider meine Fähigkeiten zur Anpassung in anderen Fällen :-) Gibt es auch eine Lösung mit den Excel Funktionen (TEIL, MID, FINDEN,.....)???
     
  4. Exl121150 Erfahrener User

    Excel: Text zwischen 2 Unterstrichen ausgeben

    Hallo,

    du brauchst ja nur die Zelle A1 in dieser Formel entsprechend anpassen. Was ist da die Schwierigkeit?
     
    Exl121150, 20. September 2022
    #4
  5. Beverly
    Beverly Erfahrener User
    Per Formel TEIL, MID, FINDEN z.B. so:

    =LINKS(RECHTS(TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1);LÄNGE(TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1))-FINDEN("_";TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1)));FINDEN("_";RECHTS(TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1);LÄNGE(TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1))-FINDEN("_";TEIL(A1;FINDEN("_";A1)+1;LÄNGE(A1)-FINDEN("_";A1)+1))))-1)



    Excel: Text zwischen 2 Unterstrichen ausgeben GrußformelExcel: Text zwischen 2 Unterstrichen ausgeben Beverly's Excel - Inn
     
  6. Exl121150 Erfahrener User
    Hallo,
    Die Formel:=XMLFILTERN("<x><g>"&WECHSELN(A1;"_";"</g><g>")&"</g></x>";"//g[3]")
    Die Artikelnummer in A1: AB180_K100_30mm_Elox-schwarz

    In der Formel steht "A1" (rot) für die Zelle, aus der eine Teilzeichenkette gezogen werden soll.

    Nach "A1" folgt "_" (braun): Das ist das Trennzeichen, mit dessen Hilfe die Zeichenkette in A1 in Teilzeichenketten zerlegt werden soll. Im Beispiel oben wären das: "AB180", "K100", "30mm", "Elox-schwarz"

    Aus diesen Teilzeichenkette willst du die dritte Zeichenkette: Deshalb steht am Ende der Formel "//g[3]", wobei der violett eingefärbte Dreier bewirkt, dass die dritte Zeichenkette von der Formel geliefert wird: "30mm"

    Nimmst du dort zB. "//g[2]", bekommst du "K100" zurück aus der Formel.

    Schreibst du statt dessen zB. "//g", bekommst du alle 4 Teilzeichenketten zurück, wobei du auf deine Excel-Version achten musst. Vor Excel2019 musst du diese Formel als Array-Formel eingeben, ab Excel2019 bekommst du ein dynamisches Array-Resultat geliefert.
     
    Exl121150, 20. September 2022
    #6
  7. Beverly
    Beverly Erfahrener User
    Hi Anton,

    Stimmt so nicht ganz: in Excel2016 muss die Formel nicht als Array-Formel eingegeben werden. Und bei Eingabe von "//g" erhält man als Ergebnis nur den Teil vor dem 1. Trennzeichen - gleichgültig ob als Array-Formel oder normal.


    Excel: Text zwischen 2 Unterstrichen ausgeben GrußformelExcel: Text zwischen 2 Unterstrichen ausgeben Beverly's Excel - Inn
     
  8. Exl121150 Erfahrener User

    Excel: Text zwischen 2 Unterstrichen ausgeben

    Hallo @Beverly,

    was Excel2016 betrifft, weiß ich nicht wirklich - vielleicht funktionieren dort bereits die dynamischen Arrays (vielleicht teilweise?).

    Ich habe Excel365 und soviel ich weiß, ist das ab Excel2019, Excel2021 gültig:
    Mit dem Parameter "//g" werden alle Teilstrings als Spalten-Array angezeigt. Will man ein Zeilen-Array, muss man zusätzlich MTRANS(...) einsetzen. Ich habe das nochmals soeben getestet.

    Es wird dann nur die 1. Spalte zurückgegeben, wenn man statt einer einfachen Zelle (also zb. A1) der Formel ein Array füttern will, zB. A1:F1 oder A1:A5. Man würde dann eine Matrix als Resultat erwarten, was aber offenbar dann die XMLFILTER-Funktion überfordert. Man bekommt dann jeweils nur das 1. Element zurück.
     
    Exl121150, 20. September 2022
    #8
  9. {Boris} hat Ahnung
    Hallo zusammen,

    ich denke schon, dass das Array in Excel 2016 (intern) vorhanden ist.
    Das 3. Elemente mal mit INDEX auslesen:

    =INDEX(XMLFILTERN("<x><g>"&WECHSELN(A1;"_";"</g><g>")&"</g></x>";"//x/g");3)

    Oder aber 4 leere Zellen markieren, dann die Formel

    =XMLFILTERN("<x><g>"&WECHSELN(A1;"_";"</g><g>")&"</g></x>";"//g")

    eingeben und mit Strg+Shift+Enter abschließen. Dann hat man eine zusammenhängende Matrix, die imho alle 4 Einträge zeigen sollte. Karin, kannst Du das mal testen?
     
  10. Beverly
    Beverly Erfahrener User
    Funktioinert beides.


    Excel: Text zwischen 2 Unterstrichen ausgeben GrußformelExcel: Text zwischen 2 Unterstrichen ausgeben Beverly's Excel - Inn
     
  11. Exl121150 Erfahrener User
    Hallo,

    will man mit den alt hergebrachten Funktionen LINKS/TEIL/RECHTS/WECHSELN etc. das Problem lösen, so bin ich es folgendermaßen angegangen:
    1) Ab Excel2021/Excel365 kann man die LET-Funktion einsetzen. Mit dieser lässt sich das wie folgt lösen:
    =LET(s;B1;n;B2; t;C2; ss;WECHSELN(t& s &t;t;"|";n); sm; TEIL(ss;FINDEN("|";ss)+1;255); LINKS(sm;FINDEN(t;sm)-1))
    Die Zeichenkette ist dabei in B1,
    die Nr. der Teilzeichenkette, die extrahiert werden soll, ist in B2,
    das Trennzeichen der Teilzeichenketten in C2
    Dabei habe ich das Zeichen "|" als zusätzliches Trennzeichen, das vor dem abzufragenden Teilstring statt des bisherigen Trennzeichens (C2) eingefügt wird, eingesetzt - dieses darf natürlich nicht in B1 enthalten sein

    2) Hat man aber kein Excel2021/Excel365 zur Verfügung, muss man die sukzessiven Berechnungen durch Funktionsverschachtelungen ersetzen:
    =LINKS(TEIL(WECHSELN(C2&C14 & C2;C2;"|";B2); FINDEN("|";WECHSELN(C2&C14 & C2;C2;"|";B2))+1;255); FINDEN(C2; TEIL(WECHSELN(C2&C14 & C2;C2;"|";B2); FINDEN("|"; WECHSELN(C2&C14 & C2;C2;"|";B2))+1;255))-1)
    Die Zeichenkette ist dabei in B1,
    die Nr. der Teilzeichenkette, die extrahiert werden soll, ist in B2,
    das Trennzeichen der Teilzeichenketten in C2

    3) Bei beiden Formeln kann man statt B1 ein (Zell-)Array übergeben, zB. A1:C1 oder auch A1:A3 - im Gegensatz zur XMLFILTER-Funktion.
     
    Exl121150, 20. September 2022
    #11
  12. {Boris} hat Ahnung
    Hi Karin

    Funktioniert beides.

    Danke für`s Testen!

    VG, Boris
     
  13. Pan
    Pan Erfahrener User

    Excel: Text zwischen 2 Unterstrichen ausgeben

    Geile Formel, das mit dem XMLFilter, kannte ich nicht, jetzt kann ich REGEX in Excel faken :)
    Mit 365 würde ich bei dem Problem eher TEXTSPLIT() nehmen. Das gibt auch Arrays aus.

    pan
     
Thema:

Excel: Text zwischen 2 Unterstrichen ausgeben

Die Seite wird geladen...
  1. Excel: Text zwischen 2 Unterstrichen ausgeben - Similar Threads - Excel Text Unterstrichen

  2. Teil der Daten von Spalte A in Spalte B verschieben

    in Microsoft Excel Hilfe
    Teil der Daten von Spalte A in Spalte B verschieben: Hallo zusammen, ich habe in Spalte A/ Zelle 1 folgenden Textinhalt: P-100-403497-EL30. Gerne möchte ich nun "-EL30" von Spalte A/Zelle1 ausschneiden und in Spalte B/Zelle 1 "EL30" einfügen....
  3. Text zu Excel

    in Microsoft Excel Hilfe
    Text zu Excel: Moin, könnt Ihr mir einen Tipp geben, wie ich diese Text-Datei (siehe unten) in Excel Spalten bekomme? 41 Name Vorname Nachname Nickname im Forum xxxx Anzahl Motorräder 1 Adresse Hans- Str.,...
  4. Abfrage in Excel importieren - Werte von mehrwertigen Feldern als Text anzeigen

    in Microsoft Access Hilfe
    Abfrage in Excel importieren - Werte von mehrwertigen Feldern als Text anzeigen: Hallo Ihr Lieben, ich habe verschiedene Felder als mehrwertiges Feld definiert und z.B zusätzliche Tabellen erstellen, aus welchen ich Daten für das mehrwertige Feld ziehe. Nun möchte ich eine...
  5. TXT-Import brauchbar machen

    in Microsoft Excel Hilfe
    TXT-Import brauchbar machen: Hallo zusammen, mein Problem sieht wie folgt aus. In regelmäßigen Abständen erhalte ich Daten als txt, die in Excel importiert werden müssen. Das importierte Format kann nur mit sehr viel...
  6. excel Text summe

    in Microsoft Excel Hilfe
    excel Text summe: Hallo, hoffe hier Hilfe zu bekommen: Zeile B3 bis Af3, enthalten sind Zahlen sowie der Text U8 und U6 Für U8 soll die Zahl 8 addiert werden und für U6 die Zahl 6 Ziffern sollen normal addiert...
  7. Word Text Inhaltssteuerelement mit Excel VBA füllen

    in Microsoft Excel Hilfe
    Word Text Inhaltssteuerelement mit Excel VBA füllen: Hallo zusammen, ich möchte gerne in Word Inhaltsteuerelemente mit Excel VBA füllen. Leider erhalte ich immer die Fehlermeldung: Laufzeitfehler '5941' Das angeforderte Element ist nicht in der...
  8. Dropdown - bei Auswahl bestimmte Texte in Zeilen einfügen

    in Microsoft Excel Hilfe
    Dropdown - bei Auswahl bestimmte Texte in Zeilen einfügen: Hallo zusammen, ich habe da mal ein kleines Problem. Aktuell arbeite ich an einer Exceltabelle wo ich ein Prüfprotokoll erstelle. Die Auswahl der Komponenten habe ich mit Dropdown-Listen...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden