Office: Daten aus zwei Zeitreihen zuordnen - suche nach kürzesten Zeitabständen zweier Datensätze

Hallo liebe Excel-Experten,
ich habe 2 Datensätze mit Messdaten vorliegen, also Zeitreihen, mit nicht immer identischen Datums- und Zeitangaben. Die beiden Zeitreihen sollen nun aber zusammengeführt werden, d.h. dem Zeitstempel in Spalte D soll der zeitlich nächstgelegene Wert aus Spalte A zugeordent werden (und später auch der zugehörige Messwert aus Spalte B, das ist aber dann über einen Verweis vermutlich einfach zu machen).
Ich habe versucht die beiden Zeitstempel über einen SVERWEIS zuzuordnen, mit Argument "WAHR", jedoch wird mir nicht immer der zeitlich nächste Wert zurückgegebe - es müsste eine Suche in beide Richtungen erfolgen, also der Wert in Spalte A kann auch zeitlich vor oder nach dem Wert in Spalte D gemessen sein, es ist halt der geringste Unterschied in Minuten entscheidend.
Leider kann ich das mittels Excel nicht umsetzen, kann mir da jemand helfen?
Eine Datei mit den Datensätzen habe ich angefügt.
Dankeschön, Rike

 

Entw. altes Excel I2: =VERGLEICH(D2;A$2:A$4843)+WENN(
ABS(D2-INDEX(A:A;VERGLEICH(D2;A$2:A$4843)+{1;0}))=MIN(
ABS(D2-INDEX(A:A;VERGLEICH(D2;A$2:A$4843)+{1;0})));{1;0})
Oder neues Excel I2: =@LET(x;VERGLEICH(D2;A$1:A$4843);y;ABS(D2-x+{0;1});x+WENN(y=MIN(y);{0;1}))
F2[:G2]: =INDEX($A:$B;$I2;SPALTE(A2))

alle drei (I2,F2,G2) runterziehen. J2 reparierst Du selbst.

 

Hallo lupo1,
vielen Dank für deine Hilfe.
Ich habe jetzt das Problem, dass ich in Zelle I2 einen "Überlauf" in zwei Zellen bekomme und dadurch doch nicht richtig zugeordnet wird.

Du hattest als erste Antwort die Formel mit =MIN... gepostet - da war die Zuordnung besser.
Oder was mache ich falsch??
Danke und Gruß,
Rike

 

Wenn ich die Formel eingebe, bekomme ich nun doch wieder nur die Zuordnung in eine Richtung, also dass Zeitpunkt aus Spalte A immer vor dem Zeitpunkt in Spalte D liegt - das sollte ja nicht so sein.

 

Ich habe weiter korrigiert. Lies.

Die =MIN-Formel war kürzer, aber suboptimal, weil mit exponenziellem Rechenbedarf.

Die altes-Excel-Formel klappt im neuen Excel nicht. Es muss ein @ gegen den #ÜBERLAUF! rein, aber wenn Du #ÜBERLAUF! hast, nimmst Du eh die neue Formel.

 

Hallo lupo1,
danke für die Formel und die Infos - mit @ klappt es zwar den Überlauf zu verhindern, aber das Datum(sformat) passt gar nicht mehr, ich bin im Jahr 1900 gelandet, und gar nicht mehr bei meinem Zeitstempel.
Hilfe! Kann ich da was am Format umstellen, oder was könnte da los sein?
Merci, Rike

 

I2 ist eine Hilfsspalte (kein Datum!), damit F:G nicht doppelt gerechnet werden. Daher ist das Fmt in I2 egal (nimm Standard, dann siehst Du 192). In F:G weisest Du das gewünschte Fmt zu.

 

Hab alle Spalten eingefügt und ausprobiert, danke vielmals, die Zuordnung stimmt. Dann kann ich ja die übrigen x-Tabellenblätter damit bearbeiten, super klasse.
Nur für die persönliche Weiterbildung: hast du einen Tipp wie ich das in Spalte I korrekt formatieren kann?
Ich danke dir für die schnelle und professionelle Lösung meines Problems!

 

Ach sorry, da steht es ja schon mit dem "Standard" - habs überlesen.
Merci nochmal!

 

Leider bleibt aber doch dieses Problem bei einzelnen Wertepaaren (zu erkennen wenn die Zeitdifferenz (Spalte H) groß ist:
Wenn ich die Formel eingebe, bekomme ich nun doch wieder nur die Zuordnung in eine Richtung, also dass Zeitpunkt aus Spalte A immer vor dem Zeitpunkt in Spalte D liegt
aber immernoch bestehen - die Zuordnung geht nicht absolut, rein nach Zeitraum, oder?

 

Oh ... Fehler. MIN machte es wohl richtig. Ich schau noch mal nach.

So hieß die MIN-Formel
I2: =MIN(WENN(ABS(D2-A$2:A$4843)=MIN(ABS(D2-A$2:A$4843));ZEILE(A$2:A$4843)))

Bitte prüfe das hier mal (so ganz sicher bin ich mir nicht):
I2: =LET(z;A$1:A$4843;x;VERGLEICH(D2;z)+{0.1};y;ABS(D2-INDEX(z;x));a;x+WENN(y=MIN(y);{0.1});KÜRZEN(NACHZEILE(a;LAMBDA(a;SUMME(a)))/2))

 

Hallo @lupo1,

die letzte Formel für Zelle I2 müsste man auch vereinfachen können zu:
=LET(z;$A$1:$A$4843;
x;VERGLEICH($D7;z)+{0.1};
y;ABS($D7-INDEX(z;x));
a;x+WENN(y=MIN(y);{0.1};{1.0});
INDEX(a;1))

 

Danke, Anton! Stimmt, das hat es gelöst! Hier noch etwas kürzer:

I2:
=LET(z;$A$1:$A$4843;b;$D2;
x;VERGLEICH(b;z)+{0.1};
y;ABS(b-INDEX(z;x));
INDEX(x+(y<>MIN(y));1))