Office: (Office 2013) Summieren von Text

Moin,

gibt es eine Möglichkeit folgende Zeilen zu summieren?

2:12:3
1:3:1

(Als Text formatiert und per Zellbezug aus anderer Tabelle bezogen)

Als Ergebnis soll

3:15:4

in der Zeile darunter stehen.

Ich habe versucht hiermit eine Lösung zu generieren:
Excel - Zellen mit Zahl und Text addieren
Allerdings gelingt es mir hier nur den Teil vor dem ersten Doppelpunkt und nach dem zweiten Doppelpunkt zu summieren. An die Zahl in der Mitte komme ich nicht ran.

Gibt es eine andere Möglichkeit?

Grüße, Markus!

 

Deine Zellen A1:A2. Wenn Du z.B. 7 statt 3 Segmente hast: ...SPALTE(A:G)... .

A3: =TEXTVERKETTEN(":";;NACHSPALTE(WENNFEHLER(--GLÄTTEN(TEIL(WECHSELN(A1:A2;":";WIEDERHOLEN(" ";399));SPALTE(A:C)*399-398;399)););LAMBDA(a;SUMME(a))))

 

Moin lupo1

Warum nicht TEXTTEILEN()?

Code:

=TEXTVERKETTEN(":";WAHR;TEXTTEILEN(A1;":")+TEXTTEILEN(A2;":"))

 

Du zeigst es via TEXTTEILEN-Einzelbearbeitung (klappt), ich möchte aber das Array A1:A2. Oder auch A1:A999999.

maninweb hat eine Lösung mit REDUCE. Für ca. unter 1000 Zeilen ok.

 

Danke für die Lösungsvorschläge, allerdings gibt es ein Problem. TEXTVERKETTEN und TEXTTEILEN wurden erst ab Office 2016 eingeführt.
Ich muss hier aktuell leider mit Office 2013 arbeiten...

Ich gehe fast davon aus, dass es in der Version nicht möglich ist.

 

Nimm doch XLWeb. Kost nix

 

Auch das ist leider nicht möglich. Muss in Excel 2013 sein. Sorry!

 

Tja ... in Excel 2013 hätte ich den Bedarf zu so etwas einfach nicht gespürt ;) Dort kannst Du es aber mit Hilfszellen und meiner o.g. GLÄWEXWDH machen.

 

Hi,

in diesem speziellen Fall (3 Zahlen durch zwei Doppelpunkte getrennt, die Summe der Stunden kleiner 24 und die der Minuten und Sekunden jweils kleiner 60) würde auch folgendes funktionieren

Code:

=STUNDE(ZEITWERT(A1))+STUNDE(ZEITWERT(A2))&":"&MINUTE(ZEITWERT(A1))+MINUTE(ZEITWERT(A2))&":"&SEKUNDE(ZEITWERT(A1))+SEKUNDE(ZEITWERT(A2))

oder einfacher

Code:

=TEXT(ZEITWERT(A1)+ZEITWERT(A2);"h:m:s")

Aber wäre es nicht viel sinnvoller einfach die Ausgangszahlen zu addieren und zusammenzufügen? Für was braucht man überhaupt einen solch seltsamen Text, mit dem man dann auch noch rechnen will?

 

Es handelt sich hier um Personenanzahlen.

2:10:1
2 Abteilungsleiter, 10 Mitarbeiter, 1 Auszubildender.

In einer anderen Abteilung sind aber eben nur 1:5:0.

Nun sollen die Anzahl aller Mitarbeiter nach dem Schlüssel dargestellt werden, also

3:15:1

Lustigerweise funktioniert die Lösung über die ZEITWERTE von HKindler, da die Anzahl der Mitarbeiter hier nicht über 24, bzw. 60 steigen kann. Bei einem Test war aber selbst dies egal.
Auch wenn das ne Krücke ist und die Zahlen dann gefühlt ne andere Eigenschaft bekommen, ist das sehr gut!

Vielen Dank für die schnelle Unterstützung hier! Sehr geil!

Grüße,
Markus

 

=
SUMME(--GLÄTTEN(TEIL(WECHSELN(A1:A2;":";WIEDERHOLEN(" ";399));001;399)))&":"&
SUMME(--GLÄTTEN(TEIL(WECHSELN(A1:A2;":";WIEDERHOLEN(" ";399));400;399)))&":"&
SUMME(--GLÄTTEN(TEIL(WECHSELN(A1:A2;":";WIEDERHOLEN(" ";399));799;399)))

erweitert es auf

mehr als 2 Abteilungen,
Mannstärkenbruchteile und
maximale Excelzahlen.

Für jedes Billigexcel. Möglicherweise dort {}-Abschluss nötig ...

Braucht man auch quer mehr als 3 Kategorien, erweitert man die Formel einfach auf 1198, 1597, ...

 

Hi,

Excel hat mehr als 17 Mio Zellen pro Blatt. Hast du so viele Daten, dass du keine 6 Zellen pro Abteilung übrig hast:

Code:

Abteilung Leiter :   Mitarbeiter :   Azubi
Abt 1     2      :   10          :   1
Abt 2     1      :   5           :   0

Und dabei habe ich dem Doppelpunkt sogar jeweils eine eigene Zelle spendiert...

 

Vielleicht kann er ja nix dafür, und die "Uhrzeiten" fliegen seit "Urzeiten" durch die Firma, und treffen auf uns zur "Unzeit".

2^34 = 17 Mrd.+

 

Stimmt. Man sollte die Anzahl Ziffern einer Zahl richtig zählen können.

 

Danke, so geht es auch! Werde es vermutlich hiermit umsetzen.
Bin eben nicht weiter drauf eingegangen, da oben noch "Lambda" mit dabei stand und das in der 2013er auch nicht existiert. Muss mir diese Formel auch nochmal genauer ansehen, um sie zu verstehen.

Nein, hab ich nicht. Die Zahlen werden einem Kalender entnommen und ändern sich täglich. Für jeden Tag 6 weitere Zellen befüllen, ist wenig elegant und es sind auch nicht die einzigen Informationen, die extrahiert werden.


Ich bedanke mich herzlich für die Hilfe! Das Thema ist für mich erledigt!!