Office: Zeilen zufällig markieren

Hallo zusammen,

ich bräuchte bitte bei einem Problem eure Hilfe. Gibt es eine Möglichkeit, dass man Zeilen in einer Tabelle zufällig kennzeichnet?

Ich habe eine Tabelle mit 120 Zeilen. Jede Zeile repräsentiert ein Dokument und jedes Dokument hat 1-n Seiten. Aus dem Portfolio will ich jetzt eine bestimmte Anzahl von Dokumenten mit einer Seite, eine bestimmte Anzahl von Dokumenten mit 2 Seiten usw. per Zufall auswählen.



In diesem Beispiel möchte ich dann 29 von 58 Dokumenten kennzeichnen, welche 1 Seite haben. 12 von 37 Dokumenten kennzeichnen die 2 Seiten haben usw.

Die Excel ist wie folgt aufgebaut:



Vielen Dank für eure Unterstützung.
Excel-Datei habe ich mit hochgeladen.

Viele Grüße
Ned

 

Office 2016

 

Hi,

die Info zur Version kam reichlich spät...

Hier die Lösung für aktuelle Excel.

Verwandle deine Tabelle in eine Strg-T-Tabelle.
Mach eine weitere Spalte "Zufallszahl" mit der Formel =ZUFALLSZAHL()
Die Spalte "Auszuwählen" bekommt die Formel:
=LET(anz;XVERWEIS([@[Anzahl Seiten]];$D$1:$H$1;$D$4:$H$4;;0;2);[@Zufallszahl]>=KGRÖSSTE(FILTER([Zufallszahl];[Anzahl Seiten]=[@[Anzahl Seiten]]);anz))

Bei älterem Excel wird daraus:
=[@Zufallszahl]>=KGRÖSSTE(FILTER([Zufallszahl];[Anzahl Seiten]=[@[Anzahl Seiten]]);WVERWEIS([@[Anzahl Seiten]];$D$1:$H$4;4;FALSCH))

 

Das ist doch glatt gelogen. FILTER() gibt es da ja nicht...
Also bei älterem Excel:
=[@Zufallszahl]>=KGRÖSSTE(WENN([Anzahl Seiten]=[@[Anzahl Seiten]];[Zufallszahl]);WVERWEIS([@[Anzahl Seiten]];$D$1:$H$4;4;FALSCH))
Vermutlich muss man das dann auch mit CSE (Control-Shift-Enter bzw. Strg-Groß-Knickpfeil) abschließen...

 

Hallo Helmut,

zu:

Ja. Aber nicht wenn man anstelle KGRÖSSTE(WENN(...)) die Funktion AGGREGAT(14;...) einsetzt.[/QUOTE]

 

Hallo Helmut, hallo Werner,

vielen Dank für den Input. Habe es entsprechend umgesetzt aber es werden mir leider nicht die Anzahl der zufälligen Dokumente gekennzeichnet. Habe die Tabelle ein wenig umgeformt, damit man es leichter lesen kann und folgende Formel eingesetzt:

Code:

=[@ZZ]>=KGRÖSSTE(WENN([Anz. Seiten]=[@[Anz. Seiten]];[ZZ]);SVERWEIS([@[Anz. Seiten]];$I$2:$K$6;3;FALSCH))

Von den 120 Dokumenten sollten per Zufall etwa 45 Dokumente gekennzeichnet werden. Allerdings werden stets nur etwa 18 Dokumente gekennzeichnet.



Die Spalte "Werte" dient nur dazu, dass man die zufälligen abspeichert, weil ja die Zufallszahl (ZZ) stets neu generiert wird.

Viele Grüße
Ned

 

Hallo Ned,

Du hast den Hinweis von Helmut bzgl. des notwendigen Eingabeabschlusses seiner Formel in Deiner Excelversion noch nicht beachtet.

Bei meiner nachfolgenden Formel in E9 ist dies jedoch nicht notwendig:

=[@ZZ]>=AGGREGAT(14;6;[ZZ]/([Anz. Seiten]=[@[Anz. Seiten]]);SVERWEIS([@[Anz. Seiten]];$I$2:$K$6;3;0))

 

Hallo Werner, perfekt!

Habe es jetzt auf eine Datei mit über 10.000 Dokumenten angewendet und es funktioniert einwandfrei. Die Funktion AGGREGAT muss ich mir auf jeden Fall nochmals genauer ansehen.

Herzlichen Dank für die gute Hilfe. Natürlich auch an Helmut :-)
Wünsche euch einen schönen Tag.

Viele Grüße aus Berlin
Ned

 

gerne, gleiches wünsche ich auch.