Office: Per Userform Order erstellen

Helfe beim Thema Per Userform Order erstellen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Moin ihr Profis, ich muss jedes Jahr sehr viele Ordner erstellen, was sehr Zeit intensiv ist. Kann man eine Userform erstellen wo ich den Ordner... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Hobbit, 7. Februar 2023.

  1. Hobbit Erfahrener User

    Per Userform Order erstellen


    Moin ihr Profis,
    ich muss jedes Jahr sehr viele Ordner erstellen, was sehr Zeit intensiv ist.
    Kann man eine Userform erstellen wo ich den Ordner auswählen kann wo dann erst die Monate erstellt werden und dann die Tage in den Monaten?
    Vorher muss ich noch den Pfad eingeben können.
    z.B. 1. Ordner Export 1 da sollen dann die Monate rein.
    dann sollen in die Monate noch die Tage als Unterordner rein.
    Ich habe mal eine Beispiel Datei hochgeladen mit den Daten.

    Kann mir da einer helfen?

    Vielen dank für die Mühe.
     
  2. Exl121150 Erfahrener User
    Hallo,

    in der beiliegenden Datei habe ich dir in einem allgem. VBA-Codemodul das folgende Makro "VerzeichnisseErstellen"
    Code:
    Option Explicit
    
    Public Sub VerzeichnisseErstellen()
      Dim rngOrdnerAuswahl As Range, OrdnerAuswahl As String
      Dim Pfad As String, Stammverzeichnis As String, MoVerzeichnis As String
      Dim Jahr As String, Mo As Integer, dt As Date
     
      On Error GoTo Err_VerzErstellen
     
      With Worksheets("Tabelle1")
         Set rngOrdnerAuswahl = .Range("N3:N9")  'Bereich "Auswahl Ordner"
         Pfad = .Range("N12").Value              'Bereich "Pfad"
      End With
     
      'Testen, ob AktiveZelle im Bereich "Auswahl Ordner"
      If Intersect(rngOrdnerAuswahl, ActiveCell) Is Nothing Then
         MsgBox "Die aktive Zelle (" & ActiveCell.Address & ") befindet sich nicht in der Ordnerauswahl."
      Else
         'Gib Jahr ein und teste es
         Jahr = InputBox(Prompt:="Geben Sie das zu erzeugende Jahr ein:", Title:="Jahreseingabe", Default:=Year(Date))
         If Len(Jahr) = 0 Then Exit Sub           '--> Abbruch-Button gedrückt
         If Not IsNumeric(Jahr) Then Exit Sub     '--> Jahr war keine Zahl
         If Val(Jahr) < 2020 Then Exit Sub        '--> Jahr war kleiner 2020
        
         dt = DateSerial(Jahr, 1, 1)  'Neujahrsdatum
     
         'Falls Pfad nicht existiert -> erzeuge ihn
         If Len(Dir(Pfad, vbDirectory)) = 0 Then MkDir Pfad
        
         OrdnerAuswahl = ActiveCell.Value
         Stammverzeichnis = Pfad & "\" & OrdnerAuswahl
        
         'Falls Stammverzeichnis nicht existiert -> erzeuge es
         If Len(Dir(Stammverzeichnis, vbDirectory)) = 0 Then MkDir Stammverzeichnis
    
         For Mo = 1 To 12
           dt = DateSerial(Jahr, Mo, 1)
           MoVerzeichnis = Stammverzeichnis & "\" & Format(dt, "MM YYYY")
           MkDir MoVerzeichnis
           Do
             MkDir MoVerzeichnis & "\Tag " & Format(dt, "DD")
             dt = dt + 1
           Loop While Month(dt) = Mo
         Next Mo
        
      End If
      Exit Sub
     
    Err_VerzErstellen:
    
      MsgBox "Der Fehler " & Err.Number & vbNewLine & _
             "(" & Err.Description & ")" & vbNewLine & _
             "ist aufgetreten. --> Abbruch."
    
    End Sub
    

    eingefügt und den blauen Button "Erstelle Export-Verzeichnisse" damit verknüpft.

    Bedienung:
    1) Die aktive Zelle muss in den dunkelgrünen Zellbereich "Auswahl Ordner" positioniert werden.
    2) Blauen Button anklicken
    3) a) Dadurch wird der Pfad und die Auswahl Ordner als Startverzeichnis verwendet.
    3) b) Es erscheint eine Inputbox, in die noch das Kalenderjahr einzugeben ist.
    4) Mit diesen Angaben wird die Verzeichnisstruktur, wie sie in den Spalten A-L enthalten ist, erzeugt. Dabei werden allerdings die Angaben dieser Spalten (A-L) nicht benötigt, denn das Makro weiß selbst, wie so ein Kalenderjahr ausschaut und erzeugt die Verzeichnisse. Die Inhalte der Spalten A-L können also, was das Makro anbelangt, auch entfernt werden.
     
    Exl121150, 8. Februar 2023
    #2
    1 Person gefällt das.
  3. Hobbit Erfahrener User
    Moin,
    das ist voll der Hammer.

    Vielen dank.
     
  4. Hobbit Erfahrener User

    Per Userform Order erstellen

    Moin ich nochmal,
    Was müsste geändert werden damit nur die Monate erstellt werden?

    vielen Dank für die Mühe.
     
  5. Hobbit Erfahrener User
    Dann hätte ich gerne gewusst, wie den Button erstellt hast?
    Vielen dank
     
  6. Exl121150 Erfahrener User
    Hallo,
    1) Menüband > Tabulator "Einfügen" > Gruppe "Illustrationen" > Listbox "Formen" > Abschnitt "Rechtecke" > Klick auf "Rechteck: Abgerundete Ecken"

    2) Der Mauszeiger wird zu einem "+" - damit an die Stelle fahren, wo die linke obere Ecke des Rechtecks erscheinen soll.

    3) Linke Maustaste niederdrücken und diese gedrückt halten und in diesem Status das Rechteck bis zur gewünschten Größe aufziehen (Mauszeiger ist dabei jeweils in der rechten unteren Ecke des Rechtecks platziert).

    4) Sobald man mit dem Mauszeiger ins Innere des Rechtecks zeigt, erscheint ein spezielles Mauszeigerkreuz - damit ins Innere mit der rechten Maustaste klicken, den Befehl "Text bearbeiten" auswählen und den gewünschten Beschriftungstext eingeben.

    5) Nochmals mit der rechten Maustaste ins Innere des Rechtecks klicken, den Befehl "Makro zuweisen..." auswählen, den Listeneintrag "VerzeichnisseErstellen" auswählen, OK-Button klicken

    Fertig ist der Button samt Funktionalität.
     
    Zuletzt bearbeitet: 9. Februar 2023
    Exl121150, 9. Februar 2023
    #6
  7. Hobbit Erfahrener User

    Vielen dank,
    kannst du mir das auch noch beantworten?

    Danke
     
  8. Exl121150 Erfahrener User

    Per Userform Order erstellen

    Hallo,

    einfach die folgenden 4 Codezeilen weglassen:
    Code:
          Do
            MkDir MoVerzeichnis & "\Tag " & Format(dt, "DD")
            dt = dt + 1
          Loop While Month(dt) = Mo
    
     
    Exl121150, 9. Februar 2023
    #8
  9. Hobbit Erfahrener User
    Moin,

    vielen Dank.
     
Thema:

Per Userform Order erstellen

Die Seite wird geladen...
  1. Per Userform Order erstellen - Similar Threads - Userform Order erstellen

  2. Userform Login Benutzername in Zelle schreiben

    in Microsoft Excel Hilfe
    Userform Login Benutzername in Zelle schreiben: Hallo mal wieder ins Forum, ich habe mir nach einem Video ein Login nachgebaut. Das funktioniert auch einwandfrei. Hier der Code: Private Sub bttnAnmelden_MouseDown(ByVal Button As Integer, ByVal...
  3. Datum in Userform formatieren

    in Microsoft Word Hilfe
    Datum in Userform formatieren: Hallo! Ich habe folgende Herausforderung: Word 365. In einer Userform gibt es zwei Textboxen (TB_Datum und TB_Datum für Termin) In die Textbox TB_Datum soll ein Datum eingetragen werden können....
  4. UserForm zum bearbeiten von Tabellen und speichern

    in Microsoft Excel Hilfe
    UserForm zum bearbeiten von Tabellen und speichern: Guten Tag Ich habe leider ein Problem, das mich zur Verzweiflung bringt. Vielleicht findet hier jemand einen Lösung für mein Problem. Ich bekommen leider einen Laufzeitfehler '1004'. Zur...
  5. VBA Code Tabellenblatt kopieren und UserForm

    in Microsoft Excel Hilfe
    VBA Code Tabellenblatt kopieren und UserForm: Hallo, ich hoffe mir kann jemand helfen. Schon mal vielen Dank für die Unterstützung. Folgende Thematik: In dem Blatt 1 ist ein ComandButton. Mit Klick soll über VBA folgendes abgefragt...
  6. UserForm wechseln

    in Microsoft Excel Hilfe
    UserForm wechseln: Hallo Vorweg der Hinweis, dass ich ein VBA-Programm habe, welches von einem anderen erstellt wurde der mir nicht mehr zur Verfügung steht. Habe Erweiterungen bisher mühsam durch Zusammentragen von...
  7. Daten aus UserForm in Tabellenblatt übertragen

    in Microsoft Excel Hilfe
    Daten aus UserForm in Tabellenblatt übertragen: Hallo zusammen, wieder eine Anfängerfrage. Ich habe eine Userform, deren Daten über einen CommandButton zum Teil in zwei Tabellenblätter übertragen werden. Wie kann ich es verhindern, dass dabei...
  8. userform schliessen, Inhalt soll erhalten bleiben

    in Microsoft Excel Hilfe
    userform schliessen, Inhalt soll erhalten bleiben: Guten Morgen, ich hoffe ich kann das verständlich erklären. Ich habe zwei Userformen. Zuerst ist nur Userform1 geöffnet. Über einen CommandButton in UF1 wird dann Userform2 geöffnet. Über einen...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden