Office: (Office 2016) suche nach wert - adresse zurueckgeben

In Zeile 48, wo in F48 ‚out‘ soll mir links daneben(gelbe zelle), also in E48
der max wert aus folgendem Bereich:
zwischen dem aktuellen OUT(F48)GRÜN und dem davorhergehenden IN(F31)BLAU ausgegeben werden.

Mit =max(B48:B31) ist dies manuel kein problem, aber in eine formel ohne adressierung bekomme ich das nicht hin. Ist notwendig, die formel in jeder zeile sein soll.

vielen dank für Euch feedback.

 

bei Max brauchst Du ein Zellbereich. Ohne geht es nicht.
Mal geantwortet auf das was im Beitrag steht.

 

Hallo,

eine etwas seltsame Auswertung. Grundsätzlich sollte jede Zeile in einer Liste unabhängig von den anderen sein, das heißt, wenn die Liste sortiert wird, darf es nicht zu Veränderungen der Auswertung(en) kommen.

 

denke mir, dass muss doch möglich sein, einen wert zu suchen:
letzten wert in zeile F (F1:F47), die position zurückgeben und folgender formel zu verwenden:
max(SUCHBEGINN:F47)

leider habe ich es über stunden nicht herausgefunden und bin auch euch angewiesen!
(vgl. excel sheet)

 

Moin,

=MAX(INDEX(B:B;VERGLEICH("IN";F:F;)):INDEX(B:B;VERGLEICH("OUT";F:F;)))

 

Hi schatzi,

Ja, ABER, wenn ich formel wie im Ausgangsbeschreibung, in jede zeile kopiere, geht das nicht mehr, denn beim nächsten IN-OUT, soll ja wieder der max wert zwischen den neuen IN-OUT genommen werden.
(tabelle neu angefügt)

 

Moin,

dann probier mal dies in E2:

=WENN(F2="IN";MAX(INDEX(B2:B9999;VERGLEICH("IN";F2:F9999;)):INDEX(B2:B9999;VERGLEICH("OUT";F2:F9999;)));"")

 

@Schatzi:
Um das nochmals zu verdeutlichen, habe ich eine neue tabelle beigefügt, auf der optisch ersichtlich ist, mit welchen werten die berechnung stattfinden soll.

die Ausgabe erfolgt in jeder zeile. zb. ich bin in aktuell in Zeile 48, dann suche ich mir die zeilennummer, des nächsten IN wertes abwärts. (Ergebnis Zeile 31)

Dann kann ich in aktueller Zeile in spalte E (sprich E48) den max wert aus B31:B48 ausgeben.

Bitte sehen sie sich die aktuelle angefügte tabelle durch (da ist alles grafisch makiert)

vielen Dank!

 

Moin,

Formel für E2 (und runterziehen):

=WENN(F2="OUT";MAX(INDEX(B:B;VERWEIS(2;1/(F$2:F2="IN");ZEILE($2:2))):INDEX(B:B;VERWEIS(2;1/(F$2:F2="OUT");ZEILE($2:2))));"")

 

Hallo excelfreund,

ich hab dir das mal als VBA Alternative "gestrickt",
von meinem Verständnis her sollte das so passen.

 

Hier noch eine kleine Verkürzung meiner Antwort von vorhin:

=WENN(F2="OUT";MAX(INDEX(B:B;VERWEIS(2;1/(F$2:F2="IN");ZEILE($2:2))):INDEX(B:B;ZEILE()));"")

 

Hi,

das geht noch kürzer:

=WENN(F2="OUT";MAX(INDEX(B:B;VERWEIS(2;1/(F$2:F2="IN");ZEILE($2:2))):B2);"")

Und wenn man eine neue Excel-Version hat, geht auch:

=WENN(F2="OUT";MAX(INDEX(B:B;XVERGLEICH("IN";F$1:F2;0;-1)):B2);"")