Office: Index/Aggregat auf anderes Tabellenblatt

Hallo zusammen,

ich hoffe ihr könnt mir helfen, ich hänge gedanklich etwas fest.

Grundsätzlich werden im Tabellenblatt " Detailplan" Werte je nach Erreichung des Teilprojekts eingetragen.
Auf dem ersten Tabellenblatt "Deckblatt" sollen diese Teilprojekte die zb. noch nicht erfüllt sind (<50%) übersichtlich angezeigt werden, ohne das man im Detailplan lange suchen muss. Die Auswahl soll über Zelle C4 im Deckblatt erfolgen.
Im Detailplan soll die Spalte G der relevante Bezug von Zelle C4 Deckblatt sein.
Ebenso weiß ich nicht wie ich auf dem Deckblatt in Zelle C4, die Formel erstelle, dass mir Wertebereiche also bis 50% / 50 - 99% / 100% ausgewählt werden und nicht nur einzelne Prozentwerte.

ch habe es durch Hilfe einiger Foreneinträge versucht auf mein Projekt umzubauen, dies hat auch solange geklappt wie ich es auf dem Tabellenblatt eingerichtet habe, auf dem der gesamte Detailplan ist. Als ich es dann auf das vordere Deckblatt umbauen wollte, hat es dann nicht mehr geklappt und die Zuordnungen zu den einzelnen Zeilen funktionierte nicht mehr. Ich habe logischerweise die festgestellten Zellen in der Formel geändert aber leider hat das nichts gebracht.

Ich hänge da gerade gedanklich fest und komme leider nicht weiter und hoffe, dass ihr mir helfen können. vielen Dank und viele Grüße Gero

 

Hola,
grundsätzlich kann man mit C4 nichts anfangen da "<50%" reiner TEXT ist den man nicht mit ZAHLEN vergleichen kann.
Welche Excel Version hast du genau im Einsatz?
Gruß,
steve1da

 

Hallo Steve, danke dir
ich verwende Office Professional Plus 2019

Hast du eine Idee wie man so einen Bereich <50%, 50-99%, 100% einbinden kann und wie ich das in die aggregat/index Formel einbinde?

VG

 

=WENNFEHLER(INDEX(Detailplan!$A$8:$A$35;AGGREGAT(15;6;ZEILE(Detailplan!$A$8:$A$35)/(Detailplan!$G$8:$G$35<0,5);ZEILE(A1)));"")
=WENNFEHLER(INDEX(Detailplan!$A$8:$A$35;AGGREGAT(15;6;ZEILE(Detailplan!$A$8:$A$35)/((Detailplan!$G$8:$G$35>=0,5)*(Detailplan!$G$8:$G$35<1));ZEILE(A1)));"")
=WENNFEHLER(INDEX(Detailplan!$A$8:$A$35;AGGREGAT(15;6;ZEILE(Detailplan!$A$8:$A$35)/(Detailplan!$G$8:$G$35=1);ZEILE(A1)));"")

 

Hallo,

ich habe dir im Arbeitsblatt "Deckblatt" ein paar Formeln eingefügt:
1) Im Bereich O1:P5 eine kleine Von-Bis-Tabelle, um die Text-Intervalle aus Spalte N1:N4 in Zahlenbegrenzungen umzuwandeln.
2) In Bereich J3:J4 zwei SVERWEIS-Formeln, um die Text-Auswahl in Zelle C4 in Zahlenbegrenzungen umzuwandeln.
3) In Bereich B8:K35 folgende Formeln:
= WENNFEHLER(INDEX(Detailplan!$A$8:$A$35;AGGREGAT(15;6;(ZEILE(Detailplan!$A$8:$A$35)-7) / ((Detailplan!$G$8:$G$35>=$J$3)*(Detailplan!$G$8:$G$35<=$J$4));ZEILE(A1));1);"")
Aufgrund der Zahlenbegrenzungen aus Punkt 2) genügt hier jeweils 1 Formel. Sie sind im Prinzip identisch mit der 2. Formel von steve1da mit Ausnahme des zusätzlichen -7, weil sonst die falschen Zeilen von der INDEX-Funktion angezeigt werden.

 

Danke Anton! Hab ich völlig übersehen.

 

Guten Morgen

Guten Morgen,

super danke dir - klappt super

Bei der Auswertung taucht nun noch die Überschrift (Decoration) auf, wie kriege ich die ausgeblendet.

Dann kann ich dies auf die weiteren 90 Zeilen adaptieren.
Habt ein schönes Wochenende
LG Gero

 

Hallo,

vermutlich wird es sich nicht bloß um diese einzige Überschrift ("Decoration") handeln, sondern es können auch noch weitere Zeilen von diesem Einblendungsverbot betroffen sein (zB. Leerzeilen, etc.).

Das einfachste Mittel gegen eine Einblendung ist, bei solchen Zeilen im Arbeitsblatt "Detailplan" in der Spalte G einen Prozentwert per Formel einzublenden, der außerhalb des 0%-100%-Intervalls liegt, zB. 200% oder 100,01%.
Es wird ja bei solchen Zeilen eh keine "Responsible Person" einzutragen sein, sodass man bei solchen Zeilen zB. ein "-" statt des Namens eintragen könnte.
Die Formel in Spalte G würde dann lauten (Zelle Detailplan!G8 und folgende):
=WENNFEHLER(WENNS($H8="-";200%;$B$5<D8;0;$B$5>E8;1);TAGE($B$5;D8)/TAGE(E8;D8))
oder
=WENNFEHLER(WENNS($H8="-";100,01%;$B$5<D8;0;$B$5>E8;1);TAGE($B$5;D8)/TAGE(E8;D8))

 

Hey du,

Ohje die Antwort ist manchmal so einfach - ja genau die Tabelle ist insgesamt um einiges länger.
Danke dir für die schnelle Hilfe und noch einen schönen Sonntag

lieben Gruß
Gero

 

Hey du,

du hattest mir ja zu der Excel schon sehr geholfen. Mein Unternehmen möchte nun die Auswahl doch nicht über Prozente sondern über die Liste in Spalte Q.
Ich habe es versucht, die Formel zu bauen aber leider werden mir zb. bei der Auswahl complete auch andere Einträge angezeigt.

Im Reiter Detailplan Spalte H erfolgt die generelle Zuordnung in den jeweiligen Status. Ich dachte ich bräuchte die Formel dann nur so bauen, dass im Deckblatt Spalte K auf die Zuordnung aus dem Detailplan Spalte H zurückgegriffen wird.

Könntest du mir bitte nochmals helfen.

Danke dir

 

Anton schreibt:
Zeile($A$8:$A$36)-7
du schreibst
Zeile($A$8:$A$36)-8

Außerdem sollten alle Bereiche gleich groß sein,

 

Hallo nochmal ihr Lieben,

ich bräuchte nochmal bitte eure Hilfe, habt ihr eine Idee, wie ich auf dem ersten Blatt mehrere Tabellenblätter/Reiter zusammenführe. Die weiteren Blätter sind quasi identisch aufgebaut wie das Erste. Die Ergebnisse auf dem Deckblatt sollten dann fortlaufend also zuerst alle von department A dann department B usw. aufgeführt werden.

Vielen Dank euch
Lieben Gruß

 

Wenn du schon in verschiedenen Foren fragst, verlink bitte die Threads untereinander...

 

Hallo,

wenn du Excel365 hast, genügt zB. folgende einzige Formel in der linken oberen Ecke des Ausgabebereichs:
=LET(Dep;VSTAPELN('department A'!$A$8:$I$40;'department B'!$A$8:$I$50;'department C'!$A$9:$I$100); FILTER(Dep;SPALTENWAHL(Dep;8)=C4;"--"))
Voraussetzung ist weiters, dass du die Unsinnigkeit verbundener Spalten bleiben lässt (Spalten B,C,D).