Office: Alphanumerische Zelle trennen

Ich habe vergleichbares gefunden, jedoch möchte ich ein anderes Ergebnis.

Spalte A hat z.B. folgende Werte:

DER3453
FRJ78
RUH8879
GBI445
BA909
BHJ5453P

Ich möchte in selber Spalte die Buchstaben von den Zahlen trennen.
Die Anzahl der Buchstaben und Zahlen variieren.
Wenn es eine Lösung für Spalte 6 gibt (Buchstabe am Ende), den Buchstaben zu ignorieren oder den Buchstaben zu löschen, wäre das auch ok.

Ich nutze Office 2016 und kenne mich mit Makros so gut wie nicht aus.

 

Warum muss man immer zurückfragen? Soll

DER3453
FRJ78
RUH8879
GBI445
BA909
BHJ5453P

werden (in 2 Spalten) zu

DER 3453
FR J78
RUH 8879
GBI 445
BA 909
BHJP 5453

?

 

Hallo,

in folgendem Link dürfte dein Problem gelöst sein:
Zahl von Text trennen (herber.de)
Ob am Ende der Zeichenkette Text enthalten ist oder nicht, ist für die Formeln bedeutungslos: Man kann damit eine enthaltene Zahl aus der Zeichenkette extrahieren.

Aber Achtung: Array-Formeln (Formeleingabe mit Tastenkombination UMSCHALT+Strg+EINGABE als Eingabeabschluss)

 

ich möchte innerhalb der selben Zellen die Trennung eines Leerzeichen haben.
Das Splitten ist mir bekannt. Es geht wesentlich um das Formatieren dieser Zellen, dass eine Trennung der Buchstaben und Zahlen folgt.

 

Hallo,

1) Von einem Leerzeichen war in deinem ersten Posting keine Rede.
2) Um in derselben Zelle jeweils die Leerzeichen vor der Zahl (bzw. auch nach der Zahl) einzufügen, so wirst du das händisch machen müssen. Da gibt es keine Formellösung. Denn wollte man eine solche versuchen, erhält man naturgemäß zwingend einen Zirkelbezug (die Formel bezieht sich dann auf sich selbst - Baron Münchhausen lässt grüßen bei dem Versuch, sich selbst aus dem Sumpf zu ziehen).

 

Verzeih meine Formulierung.
Ich verstehe die Logik dahinter, jedoch hoffte ich auf einer Funktion (z.B. Formatierung), wo keine Formel nötig wäre und evtl. versteckt in einer Einstellung zu finden sei.
Wie sieht es mit Makros aus ? Einfache Bedingungen ...
Wenn 4. Stelle Zahl, dann Leerzeichen nach (Buchstabe) 3. Stelle.
Wenn 4. Stelle Buchstabe, dann prüfe 5. Stelle.
Wenn 5. Stelle Zahl, dann Leerzeichen nach 4. Stelle ....

 

Code:

Option Explicit

Sub trennen()

    Dim t$, i&, j&
    Dim b As Boolean
    Dim StartZeile&, EndZeile&

    StartZeile = 4
    EndZeile = 9

    For j = StartZeile To EndZeile
        If Len(Cells(j, 1)) Then
            b = False
            t = Trim$(Cells(j, 1))
           
            For i = 1 To Len(t)
                b = IsNumeric(Mid$(t, i, 1))
                If b Then
                    t = Mid$(t, 1, i - 1) & " " & Mid$(t, i)
                    If Not IsNumeric(Right$(t, 1)) Then        'Einen Buchstaben am Ende löschen
                        t = Mid$(t, 1, Len(t) - 1)
                    End If
                    Cells(j, 1) = t
                    Exit For
                End If
            Next
        End If
    Next
End Sub

 

Kopier die Spalte nach Word, führ dort eine Platzhaltersuche aus mit Suchen/Ersetzen und füg damit das Leerzeichen ein, dann kopier das wieder zurück wenns getrennt ist. :)

 

Die Zelle soll nicht in 2 getrennt werden.
Es soll ein und die selbe Zelle sein.
Warum ?
- Es wäre eine Schritt, der wegfallen würde und ich nicht knapp 600 Zeilen editieren müsste.
BHJ5453P war hier nur ein Beispiel an Anfrage, ob auch zusätzlich der letzte Buchstaben hier ignoriert bzw gelöscht werden kann durch einer Formatierung oder Formel.

 

Also, es gibt auch in Excel selbst noch die Möglichkeit mit strg+e
In der Spalte daneben beim "blödesten" Wert die Trennung mit Leerzeichen vornehmen und dann in die Zelle drunter oder drüber gehe und strg+e drücken.

 

Siehe #7

Funktioniert auch mit #7

 

@knolli sorry, aber ich habe vieles versucht, jedoch zeigt der Code keine Wirkung.
Wie bereits beschriebe, kenne ich mich mit Makros nicht wirklich gut aus.
Die Spalte D ist bei meiner Tabelle ausschlaggebend.
Ich habe meine Mappe als xlsm abgespeichert. und brauchen tue ich eine CSV zum einlesen ...
wenn meine Datei am Ende ein anderes Format als CSV hat, dann ist es so, nur habe ich noch keine Änderung festgestellt.

 

Hallo,

in der beiliegenden Excel-Datei habe ich dir
1) im allgem. Codemodul "Modul1" ein VBA-Makro namens "AuswahlTrennen" eingefügt.
2) im Arbeitsblatt "Tabelle1" einen blauen Button "Ausgewählte Texte/Zahlen trennen" eingefügt
3) weiters im Zellbereich A4:A9 deine Mustertexte eingefügt.

Um nun in deinen Mustertexten die gewünschten Leerzeichen zwischen den Buchstaben- und den Ziffernabschnitten einzufügen, musst du wie folgt vorgehen:
1) Markiere den Zellbereich mit den Texten, im Beispiel den Bereich A4:A9
2) Klicke auf den Button "Ausgewählte Texte/Zahlen trennen"
und siehe: Das war die ganze Hexerei.

Alternativ kannst du das Makro auch starten, indem du die Tastenkombination Alt+F8 drückst und im erscheinenden Dialogfenster auf den Button "Ausführen" klickst.

Zum Makro "AuswahlTrennen" gelangst du, wenn du die Tastenkombination Alt+F11 drückst bzw. gelangst du mit dieser auch wieder zurück ins Arbeitsblatt. Das Makro sieht wie folgt aus:

Code:

Option Explicit

Sub AuswahlTrennen()
  Dim Zelle As Range
  Dim TxtBisher As String, Ps As Long, TxtNeu As String
  Dim IstTxtBisher As Boolean, Ch As String
 
  For Each Zelle In Selection.Cells
     With Zelle
        TxtBisher = Trim$(.Value)
        TxtNeu = ""
        IstTxtBisher = False
      
        For Ps = 1 To Len(TxtBisher$)
            Ch = Mid$(TxtBisher$, Ps, 1)
            If IsNumeric(Ch) Xor IstTxtBisher Then
               'wenn die Zeichenart wechselt
               TxtNeu = TxtNeu & " " & Ch
               IstTxtBisher = Not IstTxtBisher
            Else
               'wenn die Zeichenart gleich bleibt
               TxtNeu = TxtNeu & Ch
            End If
        Next Ps
      
        .Value = TxtNeu
     End With
  Next Zelle
End Sub

Datei liegt bei.