Office: Druckverbot, wenn Zelle einen bestimmten Inhalt haben.

Hallo Zusammen,
ich brauch mal wieder etwas Hilfe bei VBA.
Ich benötige ein Druckverbot, wenn in verschiedenen Zellen ein "T" eingetragen ist.
Die Zellen sind an verschiedenen Stellen.
Dies habe ich bereits für eine einzelne Zelle:

Private Sub Workbook_BeforePrint(Cancel As Boolean)

For Each xWs In Application.ActiveWorkbook.Windows(1).SelectedSheets
If Worksheets("Tabelle1").Range("H4").Value = "T" Then
MsgBox ("Es kann nicht gedruckt werden")
Cancel = True
End If

Next
End Sub

Leider reicht mein Wissen über VBA nicht aus, um daraus etwas sinnvolles zu basteln, für mehrere Zellen.

Konkret handelt es sich um diese Zellen
H4 bis H21
I22 bis I32
H33 bis H35
I36 bis I42
G43 bis G58
Q52
Q54 bis Q58 (zusammengeführte Zellen)

Also in egal welcher Zelle ein "T" kommt, muss ein Druckverbot kommen, bis das T weg ist.


Vielen Dank im Voraus.
Miro

 

Hallo Miro,

versuch es so
Range("H4;H21;I22,I32 .....")

 

Moin!
Ich kenne da "etwas" andere Trennzeichen.
• Setze den Union-Bereich
• wende die Range.Find-Methode an
• prüfe ob die Objektvariable zugewiesen wurde oder Nothing ist:

Code:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Dim Fund As Range
Set Fund = Worksheets("Tabelle1") _
    .Range("H4:H21,I22:I32,H33:H35,I36:I42,G43:G58,Q52,Q54") _
    .Find("T", , , xlWhole)
If Not Fund Is Nothing Then
  MsgBox "Es kann nicht gedruckt werden"
  Cancel = True
End If
End Sub

(bei verbundenen Zellen ist die relevante die oben links, also Q54)

Gruß Ralf

 

Hallo Hajo,

sobald ich bei Range("") irgendetwas anderes als eine einzelne Zelle eintrage, egal ob Doppelpunkt für einen Bereich Range("H4:H21") oder Semikolon für zwei einzelne Zellen Range("H4;H5") kommt eine Fehlermeldung.
Deswegen bin ich schon verzweifelt... :'(

Hallo Ralf,
Danke für die Hilfe, funktioniert leider nur nicht.
Er druckt trotzdem. Unabhängig ob ein "T" drin ist oder nicht.
Aber evtl habe ich nicht verstanden was Du meinst.
Wie prüfe ich, ob die Objektvariable zugewiesen wurde? :)
Ich bin eine NULL was VBA an geht...
Das meiste muss ich mir mühselig im www zusammenklabern um nicht wegen jeder "Kleinigkeit" fragen zu müssen.

 

Hallo Mirisla,

du musst den Code von Ralf in "Diese Arbeitsmappe" packen und
nicht etwa in das "Tabellenblatt oder ein Modul"
und musst ggf. bei...

Code:

Set Fund = Worksheets("Tabelle1")

das entsprechende Tabellenblatt anpassen.

 

Hey Dirk,
danke für die Antwort.

Leider ist das alles bereits schon so, wie Du es beschreibst.
Der Code passt. Eigentlich nur Coppy, Paste und fertig.
Ist in der Arbeitsmappe und nicht in der Tabelle, und das Arbeitsblatt heißt einfach nur Tabelle1.

 

Hallo Marisla,
das ist für mich nicht nachvollziehbar. Habs auch nochmal probiert und es geht.
Bleibt eigetlich nur der Blick in deine Datei.

 

Moin Marisla,
Deine Aufgabenstellung ist mir noch nicht ganz klar, daher folgende Fragen:

• Du erwähnst "Tabelle1", hast Du ein oder mehrere Tabellenblätter?
• Soll überhaupt nichts gedruckt werden oder nur die gesperrten Zeilen/Arbeitsblätter nicht?
• Soll immer ein definierte Bereich geprüft werden, oder ist das einzelne "T" immer ein Druckverbotsgrund?
• Gibt es für den Marker "T" einen bestimmten Grund, oder ließe der sich z.B. durch ein Sonderzeichen ersetzen?

Lass mich lernen, bitte. Schöne Grüße

 

@DIZA

Danke für die Antwort.
Sobald ich wieder Zugang zur Datei habe - was nur in der Arbeit ist, kümmere ich mich mal um Anschauungsmaterial. :)

@d'r Bastler
Danke auch für Deine Antwort.

- Tabelle1 ist einfach nur der Tabellenblattname. Es ist das einzige.
- sobald eine der entsprechend benannten Zellen ein "T" drin hat, darf das ganze Dokument nicht gedruckt werden.
- In die benannten Zellen wird mittels "wenn dann" ein T eingetragen, wenn andere Zellen fehlerhaft eingetragen sind. Wenn alles passt, sind die benannten Zellen ohne Wert.
- Es könnte auch durch ein Sonderzeichen ersetzt werden. Das "T" als solches ist kein Zwang. Könnte auch ein "%" sein...

Ich hoffe, dass es soweit passt. :)

 

Moin Marisla,
das hilft ungemein ;-) Mit diesen Informationen lässt sich leicht was stricken. Leider nicht mehr heute Abend, muss zum Geburtstagsessen.

Grüße

 

Es sei Dir vergönnt!!
Guten Appetit und alles Gute dem Geburtstagskind! :)

 

macht Sinn, dann kann viel Gerate ausgemerzt werden.

 

Moin allerseits,

in Diese Arbeitsmappe:

Code:

Option Explicit
Private Sub Workbook_BeforePrint(Cancel As Boolean)

    Check_T
    If canPrint = False Then
        Cancel = True
    End If

End Sub

in ein Allgm. Modul:

Code:

Option Explicit
Public canPrint As Boolean

Sub Check_T()
Dim i As Integer, r As Integer
canPrint = True

With ActiveSheet

r = .UsedRange.Rows.Count

    For i = 1 To r
        If .Cells(i, 8) = "T" Then
            canPrint = False
            MsgBox "Drucken is' nicht"
            Exit Sub
        End If
    Next i

End With

End Sub

Was tut das Dingen? Es prüft vor dem Drucken, ob in der Spalte H = 8 ein einzelnes "T" zu finden ist. Falls ja, wird der Druck verhindert, falls nicht gedruckt. Andere Zelleninhalte mit T wie Tomate, Tornröschen oder Topf werden nicht als Druckblockade gesehen, womit die Spalte weiterhin auch anderweitig nutzbar ist. Dadurch wird das dedizierte Ansprechen einzelner Zellen/Ranges unnötig.

Um auch die Spalten G, I, und Q zu prüfen, lässt man die For...Next Schleife einfach auch über die Spalten 7, 9 und 17 laufen. z.B. so:

Code:

If Cells(i,7) = "T" or Cells(i,8) = "T" or Cells(I,9) = "T" or ... ... Then

Grüße

 

@d'r Bastler
Globale Variablen sind Bäh! Vor allem wenn sie sich so leicht vermeiden lassen:

Code:

Function canPrint() As Boolen
Dim i As Long
With Tabelle1
    For i = 1 To .UsedRange.Rows.Count
        If .Cells(i, 8) = "T" Then
            canPrint = False
            MsgBox "Drucken is' nicht"
            Exit Function
        End If
    Next i
End With
canPrint = True
End Function

Wobei man eigentlich eine Sub/Function niemals mit "Exit" verlassen sollte...
Auch sollte man Zeilenzähler niemals als Integer definieren. Denn jenseits von Zeile 32.768 fällt man damit auf die Schnauze.
Genauso sollte man niemals nicht ActiveSheet verwenden. Wie heißt es so schön bei Forrset Gump? "ActiveSheet ist wie eine Schachtel Pralinen: Man weiß nie, was man bekommt!". Vom TE wurde erwähnt, dass das Blatt "Tabelle1" geprüft werden soll. Also macht man auch das. Allerdings könnte der Benutzer den Namen ändern, daher habe ich hier den CodeName verwendet, der sich normalerweise nie ändert (es sei denn man macht es mutwillig).

Der Aufruf erfolgt dann mit

Code:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = Not canPrint()
End Sub

Oder man schreibt die paar Zeilen der Function gleich in BeforePrint.

So ganz nebenbei, würde übrigens dieser Einzeiler genau dasselbe machen:

Code:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
Cancel = Application.WorksheetFunction.CountIf(Tabelle1.Columns("H"), "T") <> 0
End Sub

oder mit Benachrichtigung:

Code:

Private Sub Workbook_BeforePrint(Cancel As Boolean)
If Application.WorksheetFunction.CountIf(Tabelle1.Columns("H"), "T") <> 0 Then
    MsgBox "Drucken is' nicht"
    Cancel = True
End If
End Sub

 

Moin Mirisla,

ich habe meinen Code noch einmal etwas optimiert und zeilenweise erklärt. Vielleicht erweitert er Dein VBA-Wissen ein wenig. Das Ergebnis findest Du hier.

Schöne Grüße