Office: Zwei Formeln verbinden

Hallo!

Ich lerne gerade erst Excel richtig zu verwenden.
Jetzt bin ich auf ein Problem gestoßen, dass ich nicht selbst lösen kann.

Ich habe eine Liste mit Namen (D2-D39), daneben (E2-E39) soll eine Zahl automatisch eingetragen werden.
Weiter unten gibt es dieselbe Namensliste noch einmal (D61-D98).
In Spalte E61 bis AI98 steht eine Reihe von Zahlen. In manchen Spalten ist die letzte Zahl in O in manchen in Z eingetragen.

Ich möchte, dass die letzte Zahl der zum Namen passenden Zeile in E2-E39 eingetragen wird. Es kommen regelmäßig neue Zahlen dazu, deswegen brauche ich es dynamisch ("letzte eingetragene Zahl der Zeile").

Ich kann beides unabhängig voneinander. Eine Zahl direkt neben dem passenden Namen heraussuchen [Formel 1] und ich kann mir die letzte Zahl in einer Zeile anzeigen lassen [Formel 2].
Wie bekomme ich diese beiden nun aber verbunden?

[Formel 1, trägt die Zahl aus Spalte E neben dem passenden Namen ein]
=INDEX($D$61:$D$98;VERGLEICH(D39;$D$61:$D$98;0;1))

[Formal 2, findet den letzten Eintrag in der Zeile 98]
=INDEX($D$61:$D$98;MAX(ISTZAHL(A98:AI98)*SPALTE(A98:AI98)))

Ich komme nicht darauf, wie ich in Formel 2 "A98:AI98" durch "VERGLEICH(D39;$D$61:$D$98;0)" ersetzen kann, ohne etwas kaputt zu machen.

Geht das überhaupt?
Oder habe ich einen komplett zu komplizierten Ansatz?
Ich hatte auch die Idee, dass mir Formel 2 nicht den Wert ausspuckt, sondern die Zeilenanzahl neben dem Namen und ich dann ";0;1" aus Formal 1 mit diesem Wert ersetze?


Grüße

 

nur wenige schauen auf Deinen Rechner und sehen die Datei.
Ich möchte gerne den Fehler im Original sehen.

Ich baue keine Datei nach. Die Zeit hat schon jemand investiert.

Ein Nachbau sieht meist anders aus als das Original. <B>Darum sollte das Original verlinkt werden.</b>

Wenn du an Stelle einer Demomappe deine Originalmappe hochladen willst, diese aber sensible Daten enthält, kannst du diese Daten
Hinweis - Anonymisierung und Pseudonymisierung von Beispielmappen - MS-Office-Forum
änderrn.
Der Name einer hochgeladenen Mappe wird im Beitrag automatisch angezeigt, sodass es bei Verwendung von aussagekräftigen Namen leichter fällt, sie später im Ablageordner wiederzufinden und sie gedanklich einem bestimmten Thema zuzuordnen. Namen wie Muster*, Test*, Mappe*, Beispiel*, Fehler*, Kalender* usw. sind so allgemein, dass eine Zuordnung zu einem Thema unmöglich gemacht wird.
Es sollte ein aussagekräftiger Name sein.

Benutze hier im Forum die Funktion zum hochladen. Falls Du die nicht benutzen möchtest beachte, von unsicheren Servern wie z.B. www.file-upload.net lade ich keine Datei runter. (lt. Einschätzung meines Virenprogramms)3

Bilder lade ich mir nicht runter, da Excel damit nichts anfangen kann.

Bilder statt Datei | Excel ist sexy!

Hochgeladene Bilder können zwar als solche in Excel importiert werden, sind jedoch bei der Lösung von Problemen nicht sehr hilfreich, da man die eigentlichen Daten nicht ohne große und zeitraubende Umwege direkt in die Tabelle übertragen kann.

Das ist nur meine Meinung zu dem Thema.

 

Moin!
Ich beschränke mich auf die Beantwortung der Frage.
Voraussetzung:
Die Reihenfolge der Namen in D2:D39 und D61:D98 ist identisch.
In E2: =INDEX(61:61;MAX(ISTZAHL(61:61)*SPALTE(42:42)))
Formel herunterziehen.
Bei SPALTE(42:42) kannst Du jede beliebige Zahl zwischen 1 und 1048576 einsetzen.

	A	B	C	D	E	F	G	H
1				Name
2				a	27
3				x	78
4				r	46
5				d	55
6				u	11
7
8
59
60
61				a	34	27
62				x	92	76	78
63				r	91	47	71	46
64				d	55
65				u	97	11

Zelle	Formel
E2	=INDEX(61:61;MAX(ISTZAHL(61:61)*SPALTE(42:42)))

Gruß Ralf

 

Wenn keine Lücken in den Zahlenreihen sind, dürfte folgendes schneller rechnen:
=INDEX(E61:XFD61;;ANZAHL(E61:XFD61))

 

Oder auch:
=VERWEIS(42;1/(61:61<>"");61:61)
Die 42 kann eine beliebige Zahl >1 sein.

	A	B	C	D	E	F	G	H
1				Name
2				a	27	27	27
3				x	78	78	78
4				r	46	46	46
5				d	55	55	55
6				u	11	11	11
7
8
59
60
61				a	34	27
62				x	92	76	78
63				r	91	47	71	46
64				d	55
65				u	97	11

Zelle	Formel
E2	=INDEX(E61:XFD61;;ANZAHL(E61:XFD61))
F2	=VERWEIS(1,000001;1/(61:61<>"");61:61)
G2	=INDEX(61:61;MAX(ISTZAHL(61:61)*SPALTE(42:42)))

 

Die Namen sind leider nicht in der gleichen Reihenfolge. In der Auflistung oben sind sie in zwei Kategorien aufgeteilt, während sie unten, zur besseren Übersicht nach Alphabet sortiert sind.
Ich hänge jetzt eine gekürzte Beispielmappe an (ich hoffe es ist alles in Ordnung da drin und alles was man braucht ist vorhanden). Falls es sich nicht lösen lässt, wie ich gehofft habe, werde ich die Namen unten dann in der selben Reihenfolge sortieren müssen, wie oben.

 

Moin

Tolle Lösung mit BEREICH.VERSCHIEBEN(). Nicht.

Code:

=XVERWEIS(D2;$D$61:$D$68;$E$61:$E$68)^

=VERWEIS(9^99;XVERWEIS(D2;$D$61:$D$68;$F$61:$L$68))

 

Bei beiden Formeln kommt in meiner Excel "#NAME?" und "Fehler: Ungültiger Name", wenn ich sie einfüge. Egal ob ich das ^ mit kopiere oder nicht.

 

Dann ist deine Excel-Version älter als meine.

 

Okay, in Google Tabellen funktioniert es so. Dann arbeite ich dort weiter.

Edit: Die Eingangsfrage ist noch nicht gelößt

 

Ja, in alten Versionen ist es schwieriger.
E2 (Durchschnitt):
=INDEX(E$61:E$68;VERGLEICH(D2;D$61:D$68;0))
F2 (letzter Wert):
{=VERWEIS(2;1/(INDEX(F$61:L$68;VERGLEICH(D2;D$61:D$68;0);)<>"");INDEX(F$61:L$68;VERGLEICH(D2;D$61:D$68;0);))}

 

Dann kannst du auch Excel on the web verwenden.
Und welche Frage ist nicht gelöst?

 

Herzlichen Dank, damit ging es!

Hättest du Zeit mir kurz zu erklären, wie es funktioniert? Die 2;1 nach VERWEIS und diese Zeichenfolge <>"" sagen mir nichts.

 

Ist jetzt RPP63 gelöst worden, danke :)

 

Ja, für das alte Excel.
Für das aktuelle Excel hatte ich ja eine Lösung gepostet.