Office: Aus Transaktionsdaten die Belegung als Heatmap erstellen

Hallo Zusammen!
Ich habe Schwierigkeiten bei der Umsetzung einer Aufgabe. Vielleicht kann mir jemand einen Tipp geben oder eine Idee vorschlagen, wie ich das am besten angehe... Ich wäre sehr dankbar
Ich habe die Daten in Power Query verarbeitet und in ein Datenmodell (Power Pivot) geladen.

Gegeben:
Eine große Datenmenge mit den Parkvorgängen an verschiedenen Objekten. Sie enthält Datum und Uhrzeit der Ein- und Ausfahrt. Eine Zeile repräsentiert einen Parkvorgang, der mehrere Tage dauern kann. Jeder Vorgang hat eine eigene ID.

Gesucht:
Erstellen einer Heatmap - Auslastung des Objekts. Der Schnittpunkt der Zeilen (Daten für das gesamte Jahr, d. h. 365 Zeilen) und Spalten (Tageszeit von 0:00 Uhr bis 23:59 Uhr, stündliche Intervalle, d. h. 24 Spalten) soll die Anzahl der in diesem Zeitraum auf dem Objekt geparkten Autos anzeigen.

 

Moin,

dies wäre eine Möglichkeit.
Nächstesmal bitte eine Datei mit Dummydaten hochladen! Kein Helfer baut sowas gerne nach.

 

Hallo,

da du keine Excelversion angegeben hast, habe ich für Excel365 eine benutzerdefinierte Funktion "Heatmap" in den Namensmanager gespeichert.
In Zelle F2 habe ich den Formelaufruf eingefügt: =Heatmap(A2:.C999)

Der zusätzliche Punkt nach dem Doppelpunkt in der Bereichsangabe bewirkt, dass der maximale Datenbereich A2:C999 solange von unten her nach oben verkleinert wird, bis die unterste Datenzeile erreicht wird. Das bewirkt, dass man solange an den momentan bestehenden Datenbereich (A1:C7) noch weitere Datenzeilen anfügen kann, bis Zeile 999 erreicht ist. Diese angefügten Datenzeilen werden automatisch im Formelresultat berücksichtigt.

Code:

Heatmap = LAMBDA(m; LET(
    UhrZt; SEQUENZ(1; 24; 0; 1 / 24);
    Anfg; MIN(GANZZAHL(INDEX(m;0;2)));
    Ende; MAX(GANZZAHL(INDEX(m;0;3)));
    Tage; SEQUENZ(Ende-Anfg+1;1;Anfg);
    hmap; MATRIXERSTELLEN(
        ZEILEN(Tage); SPALTEN(UhrZt);
        LAMBDA(i; j; LET(
            TagZt; INDEX(tage; i; 1) + INDEX(UhrZt; 1; j);
            SUMME((INDEX(m; 0; 2) <= tagZt) * (tagZt < INDEX(m; 0; 3)))
        ))
    );
    VSTAPELN(
        HSTAPELN("Datum\Uhrzeit"; UhrZt);
        HSTAPELN(Tage; hmap);
        HSTAPELN("Gesamt:"; NACHSPALTE(hmap; SUMME))
    )
));;

 

Vielen Dank für Ihre Rückmeldung und Vorschlag! Datei habe ich leider vergessen hochzuladen, sorry. Werde darauf achten. Bei mir hat leider Formel nicht funktioniert. Datei jetzt im Anhang. Die Zeilen mit den Transaktionen wurden aus Power Pivot geladen.
Das wäre die Lösung, wenn alle Transaktionen auf einem Blatt passen. Hast Du vielleicht eine Idee, wie man das über Power Query / Power Pivot machen könnte? Wenn die Transaktionen auf einen Blatt nicht mehr passen?

 

Vielen Dank für Ihre Rückmeldung und Vorschlag!
Diese Variante ist mir leider komplett fremd und ich verstehe nicht wie sie funktionieren soll, da ich kein Profi bin...
Datei von Dir habe ich runtergeladen, aber es leider kommt aus Formel Fehler raus.

Meine Datei jetzt im Anhang. Die Zeilen mit den Transaktionen wurden aus Power Pivot geladen.
Verstehe ich richtig, dass Deine Lösung auch nur dann funktioniert, wenn alle Transaktionen auf einem Blatt passen? Hast Du vielleicht eine Idee, wie man das über Power Query / Power Pivot machen könnte? Wenn die Transaktionen auf einen Blatt nicht mehr passen.

 

Moin,

deine Daten werden nicht als echte Datumswerte erkannt, daher das Problem.
Beheben ließe sich das mit dieser Formel:
=SUMME((1*TR!$B$2:$B$999<=$B3+C$2)*(1*TR!$C$2:$C$999>$B3+C$2))

Aber schlauer wäre es vermutlich, die Daten schon in Power Pivot entsprechend aufzuhübschen und bereits dort per Multiplikation mit 1 oder auf noch elegantere Weise (bin kein PowerPivot-Kenner) umzuwandeln.

Bzgl. der Menge der Daten: Man kann diese Daten auch irgendwie "nur" in ein Modell laden, dann sind auch mehr Datensätze möglich als Excel Zeilen hat. Google mal, da findet sich bestimmt irgendwas.

 

Ok, besten Dank. Ich versuche es