Office: (Office 2016) Datum in Formel fortlaufend kopieren

Offenbar gibt es hier keinen "Moderator" oder sowas und es bringt nix, Spam zu melden.....

 

Hallo Onur,

ich habe mal ein PN an Schatzi (Admin) geschrieben, dass dieser Account wohl gehackt worden ist.

Gruß Uwe

 

Moin!
Ich weiß, dass das Thema uralt ist (aus 2019).
Egal:

Dazu würde ich die Funktion DATUM() nutzen.
Hintergrund ist, dass das Argument Tag nahezu beliebig hochgezählt werden kann.
Der 10.000ste Juli 2019 ist für Excel der 15.11.2046

	C
1	15.11.2046

Zelle	Formel
C1	=DATUM(2019;7;10000)

Deshalb:
Nutze die Formel
=DATUM(2019;7;ZEILE(X1))
und ziehe sie nach unten.

Gruß Ralf

 

Noch ergänzend:
Sowohl Monat als auch Tag sind durch den Integer-Wert 32767 begrenzt.
Dies macht die Funktionen MONATSENDE und EDATUM in der Regel überflüssig:
Monatsende Februar 2024 (Schaltjahr): =DATUM(2024;3;0) → 29.02.2024
10.000 Monate nach dem 14.05.1938: =DATUM(1938;5+10000;14) → 14.09.2771

 

@Ralf,

klar, für die eigenen Sachen gar kein Problem. Für unbedarfte, wenn mal Anpassungen erforderlich sind eher unübersichtlich. Ressourcenschonender als EDATUM() oder MONATSENDE() ist es allemal. Wenn man aber nur darauf schaut wirds für LET / LAMBDA und co. auch schwierig.

Gruß Uwe

 

Klar, @Uwe.
Ich wollte eigentlich nur die Hilfe zu DATUM() verlinken, stellte aber fest, dass der Integer-Hinweis für die Formel-Argumente nicht (mehr?) vorhanden ist.
Ein Jahr liste ich schon seit langem so auf:
=LET(j;2026;DATUM(j;1;SEQUENZ(365+ISTZAHL("29.2."&j))))

 

Das ist für unsereins zumindest ein gut nachvollziehbarer Weg. Die Vorgehensweise merk ich mir vor.

Gruß Uwe

 

Hallo RPP63_neu,

- dieser Teil der Formel: ISTZAHL("29.2."&j) ergibt immer FALSCH - egal ob Schaltjahr oder nicht
- in Schaltjahren wird zwar der 29.02. aufgelistet
- dafür fehlt aber der 31.12. des Jahres

Gruß von Luschi
aus klein-Paris

 

Hi,

eine Möglichkeit das zu lösen:

Code:

=LET(j;2028;DATUM(j;1;SEQUENZ(365+(MONAT(("1.1."&j)+59)=2))))
=LET(j;2026;k;"1.1."&j;l;EDATUM(k;12)-k;DATUM(j;1;SEQUENZ(l)))

 

Du hast Recht!
Hab es nur aus dem Gedächtnis geschrieben und nicht überprüft.
Die implizite Typumwandlung muss natürlich auch noch angestoßen werden:

	A	B
1	01.01.2024	01.01.2026
2	02.01.2024	02.01.2026
59	28.02.2024	28.02.2026
60	29.02.2024	01.03.2026
61	01.03.2024	02.03.2026
62	02.03.2024	03.03.2026
365	30.12.2024	31.12.2026
366	31.12.2024

Zelle	Formel
A1	=LET(j;2024;DATUM(j;1;SEQUENZ(365+ISTZAHL(--("29.2."&j)))))
B1	=LET(j;2026;DATUM(j;1;SEQUENZ(365+ISTZAHL(--("29.2."&j)))))

 

Hier mal ein Späschen ganz ohne DATUM():

Code:

=LET(xA;2024;xB;GANZZAHL((xA-1)/4)-GANZZAHL((xA-1)/100)+GANZZAHL((xA-1)/400)+1;xC;365 + ODER(UND(REST(xA;4)=0;REST(xA;100)<>0);REST(xA;400)=0);(xA-1)*365 + xB - 693595 + SEQUENZ(xC))

Gruß Uwe

 

Hi,

hie mal ein paar Formeln zusammengefasst:

Code:

=LET(j;2025;k;"1.1."&j;l;EDATUM(k;12)-k;DATUM(j;1;SEQUENZ(l)))
=LET(j;2025;DATUM(j;1;SEQUENZ(365+ISTZAHL(--("29.2."&j)))))
=LET(xA;2025;xB;GANZZAHL((xA-1)/4)-GANZZAHL((xA-1)/100)+GANZZAHL((xA-1)/400)+1;xC;365 + ODER(UND(REST(xA;4)=0;REST(xA;100)<>0);REST(xA;400)=0);(xA-1)*365 + xB - 693595 + SEQUENZ(xC))
=LET(xa;2025;xb;--("1.1."&xa);xc;REST(xa;4);xd;REST(xa;100);xf;(REST(xa;4)=0)*(REST(xa;100)<>0);SEQUENZ(365+xf;;xb))
=LET(xa;2025;xb;--("1.1."&xa);SEQUENZ(365+(REST(xa;4)=0)*(REST(xa;100)<>0);;xb))

 

Ich habe noch eine zu diesem Thema. Beginnt mit 1. KW und endet zum 31.12.

Code:

=LET(xA;B1;xB;DATUM(xA;1;4)-WOCHENTAG(DATUM(xA;1;4);2)+1;xC;DATUM(xA+1;1;4)-WOCHENTAG(DATUM(xA+1;1;4);2)+1;xD;SEQUENZ(xC-xB;1;xB;1);FILTER(xD;xD<=DATUM(xA;12;31)))

Wenn die letzte KW auch vollständig sein soll, dann einfach den Filter rausnehmen.

Gruß Uwe

 

diese Formel etwas noch entschlackt und ohne FILTER():

Code:

=LET(xA; A1;xB; DATUM(xA;1;4) - WOCHENTAG(DATUM(xA;1;4);2) + 1;xC; SEQUENZ( DATUM(xA;12;31) - xB + 1; 1; xB; 1);xD; ISOKALENDERWOCHE(xC);HSTAPELN(xD; xC))

Gruß Uwe