Office: (Office 365) Spillformel gesucht

Hi,
ich bitte um Hilfe fuer eine Formel die spillt.
Beschreibung in der Datei.
Vielen Dank vorab.
VG Charly

 

Hi,

die Formel in F als Spillformel:

Code:

=LET(
  x;HEUTE();
  a;DATUM((TEXT(E2:.E2000;"MMTT")<TEXT(x;"MMTT"))+JAHR(x);MONAT(E2:.E2000);TAG(E2:.E2000));
  b;TAG(DATUM(JAHR(x);3;));
  c;TEXT(E2:.E2000;"MMTT")="0229";
  d;WENN((REST(SEQUENZ(9;;JAHR(x));4)=0)-(REST(SEQUENZ(9;;JAHR(x));100)=0)+(REST(SEQUENZ(9;;JAHR(x));400)=0)>0;SEQUENZ(9;;JAHR(x)););
  e;WENN(ODER(UND(b=29;c;MONAT(x)>2;$A$1="");UND(b=28;c;$A$1=""));DATUM(XVERWEIS(JAHR(x)+1;d;d;;1);2;29);  WENN(ODER(UND(b=29;c;MONAT(x)>2;$A$1=1);UND(b=28;c;$A$1=1));a-1;a));e
)

Wobei mir nicht verständlich, warum Du das in F nicht schaffst, aber in G!

Ansonsten verstehe ich nicht, was Du eigentlich willst.

 

Hi,

hier noch zwei Möglichkeiten:

 

Hi Edgar
Danke das du dir das angeschaut hast.
Das ist ja die selbe Formel wie in Spalte G und die liefert ein falsches Ergebnis.
Das hatte ich aber beschrieben.
Richtig ist das Ergebnis in Spalte F.
Sh. Zeile 102
VG Charly

 

Hi,

weiterschauen!!

 

Hallo,

folgende Formel - passt diese?
=LET(gdt; E2:.E999; sch; $A$1; x; HEUTE(); a; DATUM((TEXT(gdt; "MMTT") < TEXT(x; "MMTT")) + JAHR(x); MONAT(gdt); TAG(gdt)); IstSchJr; LAMBDA(ArrJahre; MAP(ArrJahre; LAMBDA(Jr; ODER(SUMME((REST(Jr; {4.100.400}) = 0) * {1.-1.1}))))); WENN(TEXT(gdt; "MMTT") = "0229"; WENNS(IstSchJr(JAHR(a)); a; sch = 1; a - 1; sch = 2; a; WAHR; DATUM((GANZZAHL(JAHR(a) / 4) + 1) * 4; 2; 29)); a))

 

Danke Edgar
Das das deckt die ersten 2 Moeglichkeiten ab aber nicht die dritte.
Ist A1 leer soll der 29.02. des nächsten Schaltjahres ausgegeben werden, sh. Spalte F.
VG Charly

 

Hi Anton
Vielen Dank, dass passt.
Muss ich in Ruhe mal versuchen nachzuvollziehen.
VG Charly

 

Hi,

meine Version:

Code:

=LET(xa;TEXT(HEUTE();"MMTT");xb;E2:.E2000;
xc;TEXT(xb;"MMTT");ya;WAHL(A1+1;"0229";"0228";"0301");
xd;WECHSELN(xc;"0229";ya);xe;JAHR(HEUTE())+(xd<xa);
xf;WENN((REST(xe;4)<>0)*(xc="0229")*(A1="");xe-REST(xe;4)+4;xe);
DATUM(xf;LINKS(xd;2);RECHTS(xd;2)))

gilt bis 2099!

 

Hi Edgar
Auch deine Version passt.
Vielen Dank
VG Charly