Office: (Office 2019) VBA - Wert in einer Spalte finden und diese Zeile löschen

Moin moin ihr Lieben,

ich habe nun schon im Netz nach einer Lösung gesucht, aber nichts passendes oder funktionstüchtiges gefunden.

Ich habe eine Tabelle mit Spalten A - G. Nun soll Excel in der Spalte A nach einem bestimmten Wert (zB: 100501240) suchen und wenn er diesen Wert gefunden hat, dann soll er den Inhalt in der gefunden Zeile von Spalte A - D löschen. Musterhaft würde sein, wenn die Werte in einer Hilfstabelle sein wurden, da es sich hier bei der Suche um mindestens 15 Positionen handelt. Und im Anschluss das Makro auf Tabellenblatt1, Tabelleblatt2 und Tabellenblatt3 angewant werden soll.

Habe den Entwurf als Bild mal angehängt. Das Feld "Daten löschen" bezieht sich dabei nicht auf die obige Frage, sondern löscht den gesamten Inhalt der Zellen A-D.

Vielleicht hat ja einer eine Idee oder einen einfachen Code für mich.

Vielen Dank schon einmal

 

Hallo,

warum ein Bild? Es ist immer schön, wenn man ein Makro testen kann. Dabei hilft eine Datei. Mehrere Tabellenblätter für gleichartige Daten sind auch nicht so das Optimale.

 

Lieber Klaus-Dieter. Vielen Dank schon einmal. Habe das Bild nur als Anschauung angegeben. Nach dem Makro der Umsetzung suche ich, wie ich es umsetzen könnte. Die Datei als ExcelTabelle kann ich leider nicht anhängen, da hier die Daten von der Arbeit enthalten sind und nicht unbedingt veröffentlicht werden müssen.

 

Hallo,

um ein Makro zu schreiben, muss man schon alle relevanten Zellbezüge kennen. Das ist bei dem Bild nur bedingt möglich. Wo sollen die zu suchenden Werte stehen?

 

Da komme ich zu meinem Eingangspost. In der Spalte A habe ich eine bestimmte Zahl. Taucht diese Zahl auf, so sollen die Spalten A - D in der Zeile gelöscht werden. Es sind insgesamt 6 Tabellenbätter, wo dieser Wert dann immer einmal auftaucht. Was ich oben mit Hilstabelle meinte, ist das es ca 15 bis 20 Zahlen sind, nachdem er suchen soll.

vorher habe ich mir jeder Blatt geöffnet, habe die Zellen markiert und gelöscht. Da ich die Daten immer wieder neu einspiele ist mir das manuelle zu umständlich und hatte deshalb nach einem Makro gesucht.

 

Hallo,

Mehrere Fragen:
1. ist die Tabelle ein Listobjekt (formatierte Tabelle) oder nicht. Das verrät dieses Bild nicht.
2. Soll nur gelöscht werden oder die gelöschten Zeilen in die von dir genannte Hilfstabelle unten angefügt werden.
3. Welche Office-/Excelversion nutzt du.
4. Lade eine Beispieldatei, mit deiner Fragestellung gerecht werdende mit brauchbaren Datensätzen anonymisiert hoch.

Dann wirst du auch passende Hilfe bekommen.

Gruß Uwe

 

Hallo,
mit einem Makro kann man in einer Datei auch einiges zerschießen, wenn es nicht genau an die Gegebenheiten angepasst ist. So eine Angabe: "Was ich oben mit Hilstabelle meinte, ist das es ca 15 bis 20 Zahlen sind, nachdem er suchen soll." recht nicht aus, um irgend etwas zu programmieren. Du kannst deine Datei so weit anonymisieren, dass du keine sensiblen Daten preis gibst. Insofern bin ich auch ganz bei Uwe. Also ein bisschen Butter bei die Fische, sonst können wir dir nicht helfen.

 

So habe dann mal die Daten und alten Macros, welche sich nicht auf die Anfrage von mir beziehen gelöscht und als Anschauung eine Tabelle eingefügt. Ich entschuldige schon einmal vorab mein Unwissen an Neuling, aber vielleicht hilft es so weiter. Nutze hier die Office Version 2021.
Danke Euch trotzdem. :-)

 

Hallo,

das wäre dann so:

Code:

Sub TrefferEntfernen()
    Dim i&, j&, wks As Worksheet, z As Range, arrZ(), arr(): arr = Tabelle1.UsedRange
    For i = 2 To UBound(arr)
        For Each wks In ThisWorkbook.Sheets
            If InStr(1, wks.Name, "einheit", vbTextCompare) > 0 Then
                With wks.ListObjects(1).DataBodyRange
                    For j = .Rows.Count To 1 Step -1
                        If arr(i, 1) = .Cells(j, 1) Then .Rows(j).Delete
                    Next j
                End With
            End If
        Next
    Next i
End Sub

Beachte: Diese Prozedur löscht dann ohne Rückfrage die betreffenden Zeilen im jeweiligen Listobjekt in allen Tabellenblättern, welche im Namen (Tab Name) "Einheit" enthalten.

Gruß Uwe

 

Die Deklarationen, enhalten noch 2 nicht benötige. Also diese Zeile so:

Code:

Dim i&, j&, wks As Worksheet, arr(): arr = Tabelle1.UsedRange

Gruß Uwe

 

Hallo,

mit diesem Makro würde es in deiner Beispieldatei funktionieren. Allerdings fehlt da noch eine Fehlerbehandlung, für den Fall, dass nichts gefunden wird. Da die Daten auf mehrere Blätter verteilt sind, ist das Makro aufwändiger als es sein müsste (könnte).

Code:

Option Explicit

Sub loeschen()
    Dim lngZeile As Long
    Dim lngBlatt As Long
    Dim lngAnz As Long
    Dim varDatArr As Variant
    Dim varRow As Variant
    varDatArr = Array(Tabelle6, Tabelle7)
    For lngAnz = LBound(varDatArr) To UBound(varDatArr)
        For lngZeile = 2 To Tabelle1.Range("A1").End(xlDown).Row
            varRow = Application.Match(Tabelle1.Cells(lngZeile, 1).Value, varDatArr(lngAnz).Columns(1), 0)
            varDatArr(lngAnz).Range(varDatArr(lngAnz).Cells(varRow, 1), varDatArr(lngAnz).Cells(varRow, 4)).ClearContents
        Next lngZeile
    Next lngAnz
End Sub

 

Ich werde es von Euch Beiden ausprobieren in Ruhe und schauen. Ich Danke Euch aber erst einmal und vorab für Eure Unterstützung. :-)

 

Hallo,

jetzt mit Fehlerbearbeitung:

Code:

Option Explicit

Sub loeschen()
    Dim lngZeile As Long
    Dim lngBlatt As Long
    Dim lngAnz As Long
    Dim varDatArr As Variant
    Dim varRow As Variant
    varDatArr = Array(Tabelle6, Tabelle7)
    For lngAnz = LBound(varDatArr) To UBound(varDatArr)
        For lngZeile = 2 To Tabelle1.Range("A1").End(xlDown).Row
            varRow = Application.Match(Tabelle1.Cells(lngZeile, 1).Value, varDatArr(lngAnz).Columns(1), 0)
            If Not IsNumeric(varRow) Then
                MsgBox "Keine Treffer"
                Exit For
            End If
            varDatArr(lngAnz).Range(varDatArr(lngAnz).Cells(varRow, 1), varDatArr(lngAnz).Cells(varRow, 4)).ClearContents
        Next lngZeile
    Next lngAnz
End Sub

 

Hi
vielleicht so, damit du nicht viel programmieren musst.

1. erstelle die Hilfstabelle, liste dort die zu löschenden IDs in Spalte A
2. ergänze alle Tabellen um eine weitere Spalte (H)mit dieser Formel:
=Wenn(ZählenWenns(Hilfstabelle!A:A;A2);1;"")

Als Code reicht dann
With Sheets("Tabellenblatt1")
if Worksheetfunction.Sum(.Columns(8)) > 0 Then Intersect(.Range("A:D", .Columns(8).SpecialCells(xlcelltypeformulas, 1).EntireRow).ClearContents
End With

das für alle drei Tabellenblätter wiederholen oder in einer Schleife ausführen.
die Markierung der Zeilen, die gelöscht werden sollen übernimmt die Formel, in dem sie eine 1 reinschreibt.
das Makro prüft dann, ob in dieser Spalte irgendwo eine 1 steht.
dann selektiert es diese Zeilen, bildet die Schnittmenge mit der Spalte A:D und leert den Inhalt.

Gruß Daniel