Office: (Office 365) Aus Tabelle Summen für einzelne Jahre ausgeben

Aus der Tabelle sollen die Jahressummen, derzeit für die Jahre 2024 - 2025 berechnet werden.
Mit meinem Formel-Ansatz mit Summewenn komme ich m momentan nicht weiter und bitte Euch mal einen Blick darauf zu werfen. Viellt. bietet da Excel bessere Befehle oder andere Ansätze, welche ich noch nicht drauf habe.

Ich danke für eure Hilfe bestens.

siehe Tabelle im Anhang.
Grüße Karl

 

Moin,

=SUMME((JAHR(A$2:A$19)=B21)*C$2:C$19)

 

Hola,
=SUMMENPRODUKT((JAHR($A$2:$A$19)=B21)*($C$2:$C$19))
Gruß,
steve1da

 

Moin!
Einfügen, Pivot-Table!
Datum in Zeilen, Betrag in Werte ziehen, fettich!


Zu Deinem Nutzernamen:
Stimmt nicht!

	A	B	C
1	0	1	FALSCH

Zelle	Formel
C1	=A1<>B1

 

Hallo,

wie RPP63_neu, jedoch mit Formel:
=WENNFEHLER(GRUPPIERENNACH(JAHR($A$1:$A$19);$C$1:$C$19;SUMME;3);"")

 

Etwas off topic, aber nur ein klein wenig …
In der Hilfe zu GRUPPIERENNACH(), Argument Funktion, steht:

Einen Vektor erstelle ich gewöhnlich innerhalb von {}, was hier nicht funktioniert.
Stattdessen geht dies mittels V- oder HSTAPELN() , was unterschiedliche Darstellungen zur Folge hat.
Für die Datei:

Code:

=GRUPPIERENNACH(JAHR(A.:.A);C.:.C;HSTAPELN(SUMME;ANZAHL;MAX;MIN;PROZENTVON);1)

	F	G	H	I	J	K
1		SUMME	ANZAHL	MAX	MIN	PROZENTVON
2	2024	964,11	4	328,44	135,58	26%
3	2025	2133,72	10	299,15	83,7	58%
4	2026	569,17	4	256,63	61,92	16%
5	Gesamt	3667	18	328,44	61,92	100%

Zelle	Formel
F1	=GRUPPIERENNACH(JAHR(A.:.A);C.:.C;HSTAPELN(SUMME;ANZAHL;MAX;MIN;PROZENTVON);1)

Gruß Ralf

 

Danke Euch allen für die Hilfe, alle Formeln liefern das gewünschte Ergebnis.

Der Hinweis von RPP63_neu über die Anwendung von Pivot Table hatte ich zwar des Öfteren in den Ohren ,
ging aber nicht tiefer rein. Nach einem ersten gelungenen Test finde ich dies Art der Tabellen-Auswertung genial. Das Thema, gut beschrieben in einem meiner Excel-Bücher gehe ich nun mal gründlich durch.
Nutzernamen: Stimmt nicht!
Dann sehe ich eben meinen Nutzername Philosophisch und nicht als Excel-mathematisch korrekt an ,
auch wenn ich in meiner Excel-Version zu anderem Ergebnis komme......
=H34=I34 FALSCH
=H34<>I34 WAHR
Ich ändere meinen User daher noch nicht, bis ich fest überzeugt werde.

Die letzte Info von RPP63_neu erschlägt mich gerade mal wieder, stelle das mal wegen "Ohrenleiden" zurück.

Exl121150
Auch diese Formel mit WENNFEHLER liefert korrekte Ergebnisse, muss mich jedoch damit noch näher beschäftigen, denn die Ausgabe kann ich noch nicht entschlüsseln:

• In der Formelzelle selber ist die Formel nicht sichtbar, nur in der Eingabezeile oben wird die angezeigt:
• über den berechneten Jahressummen erscheint die Überschrift " Betrag "
• unterhalb der Jahreswerte ist " Gesamt ", rechts davon die gesamte Summe über alle Jahre weg berechnet.

Ich wünsche Euch noch ruhige entspannte Ostertage.

Grüße Karl

 

Ich habe da "ein wenig" mit einem benutzerdefinierten Zahlenformat getrickst (deshalb auch der ).
In beiden Zellen steht eine 1
In A1 ist die 1 benutzerdefiniert mit dem Format "0" versehen.

	A	B	C
1	0	1	FALSCH

Zelle	Format	Wert
A1	"0"	1

Zelle	Formel
C1	=A1<>B1

War aber nur als Gag zu verstehen.

Allseits frohe Ostern wünscht
Ralf

 

Hallo @RPP63_neu,

die beiden Funktionen
GRUPPIERENNACH(row_fields,Werte,Funktion,[field_headers],[total_depth],[sort_order],[filter_array],[field_relationship])
bzw.
PIVOTMIT(row_fields,col_fields,Values,Function,[field_headers],[row_total_depth],[row_sort_order],[col_total_depth],[col_sort_order],[filter_array],[relative_to])
besitzen mehrere Eigenschaften, die in der Microsoft-Hilfe-Dokumentation nicht (bzw. unzureichend) beschrieben sind:

1) [total_depth] - [gesamt_tiefe]: kann auch größer als 2 (bzw. -2) sein, falls genügend [row_fields]-Spalten vorhanden sind

2) [field_relationship] - [feld_beziehung]: Hier gibt es 2 Werte: 0-Hierarchie(Standard) oder 1-Tabelle: Beide beziehen sich darauf, wie mit [sort_order] bei [total_depth]>1 zu verfahren ist. Bei 0 schlägt die Spaltenhierarchie der [row_fields] zu, bei 1=Tabelle kann mittels Vektor für [sort_order] die Spaltensortierreihenfolge angegeben werden kann, wobei positive Spaltennummern aufsteigende Sortierung bedeuten und negative Spaltennummer absteigende.

3) Custom Headings - Benutzerdefinierte Kopfzeilen: Mit VSTAPELN kann eine zusätzliche (zweite) Beschriftungszeile zur Zeile der Funktionen verwendet werden. z.B. kann man die Formel für diesen Thread formulieren:
=WENNFEHLER(GRUPPIERENNACH(JAHR($A$1:$A$19);$C$1:$C$19;HSTAPELN(SUMME;ANZAHL);3);"")
oder mit benutzerdef. Kopfzeile (für die Funktionsspalten):
=WENNFEHLER(GRUPPIERENNACH(JAHR($A$1:$A$19);$C$1:$C$19;VSTAPELN(HSTAPELN(SUMME;ANZAHL);{"Su.Beträge"."Anz.Beträge"});3);"")
oder mit benutzerdef. zusätzlichen Beschriftungsspalte:
=WENNFEHLER(GRUPPIERENNACH(JAHR($A$1:$A$19);$C$1:$C$19;HSTAPELN(VSTAPELN(SUMME;ANZAHL);{"Su.Beträge";"Anz.Beträge"});3);"")

4) Arguments into Functions - mögliche Argumente, falls LAMBDA-Funktionen verwendet werden: normalerweise sind die eingesetzten Funktionen (SUMME, ANZAHL2, etc) eta-reduziert - also ohne Angabe von Argumenten. Bei benutzerdef. Funktionen muss aber mindestens 1 Argument angegeben werden - es sind aber auch 2 Argumente möglich. Das erste Argument enthält die einzelnen eindeutigen Werte, die von [row_fields] kommen, während das optionale 2. Argument enthält alle Unikat-Werte aus [row_fields]. Das erklärt auch, warum solche Funktionen wie PROZENTVON funktionieren, die ja eigentlich 2 Argumente benötigen.

Die Demo-Details sind in folgendem Youtube-Video dargestellt:
Excel's GROUPBY Function Has Hidden Features That Nobody Knows