Office: (Office 2010) Filter mit mehreren Kombinationsfeldern

Hallo Liebe Mitglieder

Ich komme mit folgendem Problem nicht weiter. Ich möchte eine Übersicht (Endlosformular) stückweise eingrenzen. Dazu habe ich mehrere Kombinationsfelder. Mit den ersten beiden funktioniert der Filter, nehme ich ein drittes Kriterium hinzu, zeigt er wieder alles an.
Dieser Code liegt bei "Nach Aktualisierung" des dritten Kombis.

Code:

Private Sub kboTest_AfterUpdate()

Dim strFilter As String

If cboAuswahlOrt <> "" Then
strFilter = "OrtNr =" & "" & Nz(cboAuswahlOrt.Value) & " AND "

End If

If cboGVZAuswahl <> "" Then
strFilter = strFilter & "t_gvz_MaNr = " & "" & (cboGVZAuswahl.Value) & " AND "

End If

If kboTest <> "" Then
strFilter = strFilter = "Bezirk = " & "" & Nz(kboTest.Value) & " AND "

End If

strFilter = Left(strFilter, Len(strFilter) - 6) 'Den String um das letzte " AND " kürzen
Me.Filter = strFilter
Me.FilterOn = True

End Sub

 

Hallo accessGast,

anstatt in jeder Kombo eine eigene Prozedur zu verwenden, rufe eine gemeinsame Prozedur auf, z.B. "RefreshFilter", welche immer alle Komboboxen auswertet und dann den String komplett neu zusammen setzt und aktiviert bzw. deaktiviert. Alles andere ist Murks.

Tip: verwende ein StringArray mit den einzelnen Filterbedingungen und dann Join(..., " and ") für das zusammensetzen - wenn die Filterbedingungen nur eingrenzende Bedingungen sind. Ansonsten müsste man die Logik noch um OR erweitern.

Knobbi38

 

Hallo Knobbi38
Vielen Dank für die schnelle Reaktion. Aber - puhh... Ich verstehe leider gerade nicht mal "Bahnhof" ;-)

An sich war das bisher so ganz praktisch. Je nachdem welcher Kombo gewählt wurde, hat dann die Datensätze eingeschränkt. Weil je nach Anwendungsfall hab ich entweder nur die eine Einschränkung benötigt oder eben auch die zweite Einschränkung (zweites Kombo) In einigen Fällen benötige ich auch noch die dritte Einschränkung. Nur die bekomm ich leider nicht hin.

Könntest Du oder jemand anders - vielleicht einen "kleinen" beispielhaften Code zur Verfügung stellen, den ich mir dann anpassen kann? Irgendwas damit ich mich damit weiter versuchen kann?
Ich nehme an "OR" steht dann für "oder" wobei ich das "AND" benötige, da mit dem jedem weiteren Kombo weiter eingeschränkt wird.. ich kapier auch nicht - warum mein Code an der Stelle nicht mehr funktioniert, wo doch die ersten beiden tadellos einschränken..

 

Wie wäre es mit ein wenig Vorarbeit deinerseits, z.B. einer kleinen Beispiel-DB. So etwas erhöht die Hilfsbereitschaft enorm.

 

Hallo,
angenommen, Deine Komboboxen arbeiten mit den Schlüsselfeldern, sind also nummerisch und haben den Standardwert 0:

Code:

Private strFilter As String

Private Sub cboAuswahlOrt_AfterUpdate()
    Filtern
End Sub

Private Sub cboGVZAuswahl_AfterUpdate()
    Filtern
End Sub

Private Sub kboTest_AfterUpdate()
    Filtern
End Sub

Private Sub Filtern()
    strFilter = ""
    If cboAuswahlOrt > 0 Then Filterschleife "OrtNr = " & cboAuswahlOrt
    If cboGVZAuswahl > 0 Then Filterschleife "t_gvz_MaNr = " & cboGVZAuswahl
    If kbotest > 0 Then Filterschleife "Bezirk = " & kbotest
    If strFilter <> "" Then Me.Filter = strFilter
    Me.FilterOn = strFilter <> ""
End Sub

Private Sub Filterschleife(Criteria As Long)
    If strFilter <> "" Then strFilter = strFilter & " AND "
    strFilter = strFilter & Criteria
End Sub

Könnte es so laufen
Gruß
Doming

 

Hallo,

Doming hat dir ja schon eine Lösung präsentiert, hier noch eine andere Variante. Dazu trägst du in den drei Komboboxen in der TAG-Eigenschaft das zu filternde Feld ein und in der Eigenschaft "AfterUpdate" den Ausdruck "=UpdateFilter()"

Im Formular hast du dann folgenden Code:

Code:

Private Function UpdateFilter()
  Dim astrCriteria(2) As String
  Dim strCriteria As String

  Debug.Print "UpdateFilter(): ";

  astrCriteria(0) = MakeCriteria(cboAuswahlOrt, dbText)
  astrCriteria(1) = MakeCriteria(cboGVZAuswahl, dbLong)
  astrCriteria(2) = MakeCriteria(kboTest, dbText)

  strCriteria = Join(VBA.Filter(astrCriteria, "="), " AND ")
 
  Debug.Print strCriteria

  Me.Filter = strCriteria
  Me.FilterOn = CBool(Len(Me.Filter) > 0)
End Function

Private Function MakeCriteria(ctl As ComboBox, DataType As DataTypeEnum) As String
  If Not IsNull(ctl.Value) Then
    MakeCriteria = BuildCriteria(ctl.Tag, DataType, ctl.Value)
  End If
End Function

Die zu übergebenden Datentypen an MakeCriteria(), z.B. dbLong usw. musst du natürlich entsprechend deinen Felddatentypen anpassen.

Knobbi38

PS:
Filterkriterien mit einem "=" im Filterstring werden von diesem Code nicht unterstützt!

 

Hier noch eine stark abgespeckte Variante, ähnlich der von Doming:

Code:

Private Const SQL_OPERATOR As String = " AND "

Private Function UpdateFilter()
  Dim strCriteria As String

  ' Einfach alle Felder hintereinander weg verketten
  strCriteria = MakeCriteria(Me.cboAuswahlOrt, dbText) & _
                MakeCriteria(Me.cboGVZAuswahl, dbLong) & _
                MakeCriteria(Me.kboTest, dbText)

  ' Das erste " AND " am Anfang abschneiden, falls der String nicht leer ist
  If Len(strCriteria) > 0 Then strCriteria = Mid(strCriteria, Len(SQL_OPERATOR) + 1)

  Me.Filter = strCriteria
  Me.FilterOn = (Len(strCriteria) > 0)

  Debug.Print "Filter: " & IIf(strCriteria = "", "(keiner)", strCriteria)
End Function

Private Function MakeCriteria(ctl As ComboBox, DataType As DataTypeEnum) As String
  If Not IsNull(ctl.Value) Then
    MakeCriteria = SQL_OPERATOR & BuildCriteria(ctl.Tag, DataType, ctl.Value)
  End If
End Function

Private Sub Form_Load()
  Me.AllowFilters = False
  UpdateFilter
End Sub

 

Ein freundliches Hallo. Leider komm ich erst jetzt dazu zu lesen.
Vielen Dank vorab.
Knobbi38, Ja Beispiel DB-stimmt. Daran scheitert es bei mir meist auch aus Zeitgründen. Das muss hier immer alles nebenhehr gemacht werden (sonnst hab ich nichts, womit ich arbeiten kann) und daran schleift es dann wieder - die Zeit zu haben - das vorzubereiten (Beispiel-DB) Dafür Sorry. Ich bin quasi immer der Zeitgejagte zwischen ich möchte mir die Arbeit erleichtern, also für mich und meine Kollegen eine Lösung suchen und "ich habe leider an sich keine Zeit, etwas zu formen, was mir zusätzliche Arbeitszeit am Ende einspart" Wenn ich das hier nicht machen würde, würden wir immer noch mit Papierlisten umherrennen.
Ich habe als erstes Doming seine Variante getestet. Es sind alles Felder vom Typ Zahl Long Integer. Trotzdem bekomme ich beim Test (Auswahl treffen) einen LZF 13 "Typen unverträglich"

 

Schön das du dir soviel Arbeit mit dem Bild machst, aber was soll ich damit anfangen, zumal das auch noch so klein ist, dass man nichts erkennen kann. Welche Inhalte welche Variablen haben, musst du so selber herausfinden, aber Filterschleife() erwartet einen Long-Wert, wenn dir das hilft.

Bitte denke daran, dass die Helfer das hier ehrenamtlich machen und ihre Freizeit investieren. Wenn du für deine Firma nicht ebenso dazu bereit bist, wird es schwierig mit der Hilfe. Eine solche Aussage kommt meist nicht gut an.

Knobbi38