Office: (Office 365) Anzeige von Tagen

Moin,
ich habe ein Reinigungsplan wo alle Tage eingetragen sind.
Jetzt sollen die Sonn.- & Feiertage ausgeschrieben und rot Markiert werden.
Das mit dem Rot klappt ja, aber ich möchte halt die gesagten Tage dann dort stehen haben.

Kann mir da bitte einer helfen?

Vielen dank für die Mühen.

 

Hola,
und wo soll dann "Sonntag" oder der Feiertagsname erscheinen? Und was ist, wenn ein Feiertag auf einen Sonntag fällt? Was soll dann angezeigt werden?
Gruß,
steve1da

 

Hallo,

vielleicht reicht das schon so:=WENN(ODER(WOCHENTAG(A8;2)=7;ZÄHLENWENN(Feiertage!$G$3:$G$16;Tabelle1!A8));"Sonntag";A8) Also Ausgabe statt Datum Sontag oder Feiertag "Sonntag". Wenn du dies in Spalte A ausgeben willst dan statt A8 die bisherige Formel in A8.

Ansonsten 1. WENN() Sonntag umschlossen von 2. WENN() Feiertag:
=WENN(ZÄHLENWENN(Feiertage!$G$3:$G$16;Tabelle1!A8)=0;WENN(WOCHENTAG(A8;2)=7;"Sonntag";A8);"Feiertag")
auch hier A8 gegen Formel in A8 tauschen.


Gruß Uwe

 

Moin,
da wo jetzt das Datum steht, soll dann anstatt das Datum der Tag erscheinen. aber halt nur wenn es ein Sonn. bzw. Feiertag ist.

MFG Jens

 

=WENN(WOCHENTAG(A8;2)=7;"Sonntag";WENNFEHLER(SVERWEIS(A8;Feiertage!$G$3:$H$16;2;0);""))

 

Hi,
ich würde hier eine neue Spalte B einfügen (und Spalte A ausblenden). In B8 kommt dann die Formel
=XVERWEIS(A8;Feiertage!$G$3:$G$16;Feiertage!$H$3:$H$16;A8;0;2)

Und zusätzlich eine neue bedingte Formatierung mit der Formel
=WOCHENTAG(A8)=1
und als Format dann das Zahlenformat "TTT"

Siehe Anhang. Hier musst du nur noch A:A und G:G ausblenden.

 

Moin,
die Formel zeigt mir zwar die Sonn. u. Feiertage an, aber kein Datum mehr bei den Normalen Tagen.

 

Ich sehe gerade du hast O365 angegeben. Da kann man das gaanzz anders machen.

Gruß Uwe

 

Da reichen 2 spillende Formeln:
in A8:

Code:

=LET(xA;SEQUENZ(16;1;DATWERT("1."&$L$1);1);MAP(xA;LAMBDA(d;WENN(ZÄHLENWENN(Feiertage!$G$3:$G$16;d)=0;WENN(WOCHENTAG(d;2)=7;"Sonntag";d);"Feiertag"))))

und in F8:

Code:

=LET(xA;SEQUENZ(TAG(EDATUM(A3;1)-1)-16;1;DATWERT("1."&$L$1)+16;1);MAP(xA;LAMBDA(d;WENN(ZÄHLENWENN(Feiertage!$G$3:$G$16;d)=0;WENN(WOCHENTAG(d;2)=7;"Sonntag";d);"Feiertag"))))

Gruß Uwe

 

Hallo Jens,

Das sind spillende Formeln. Das kennst du doch aus diversen Beispielen die ich dir in CEF gezeigt hatte. Entferne also alle alten Formeln in Spalte A ab A8 und setze diese Formel in A8 und adäquat die 2. Formel.

Gruß Uwe

 

Moin,
ich kenne das nicht mit den Spillende Formel, weil ich O365 erst neu habe.
Wie muss den jetzt die Bedingte Formel heißen, damit die Sonn. u. Feiertage Rot werden?

Vielen Dank für die Mühen.

 

Moin,
mit der Bedingten Formel habe ich gelöst, es sei den du hast eine Idee für mein folgendes anliegen.
Kann man die Feiertage auch so reinschreiben lassen wie sie Heißen?

In Spalte G steht ja das Datum und in H die Bezeichnung.
Wenn es nicht so einfach geht, dann auch nicht schlimm.
So ist deine Formel schon Top.
Vielen Dank für die Mühen.

 

Doch, du kennst das schon. Schau in deinem Account in deinen Themen im Clever Excel Forum unter Egon12 nach.
Da hast du diverse spillende Sachen von mir gezeigt bekommen.

Mit dem passenden Feiertag ausgeben ist kein Problem.
Formeln auf die Schnelle (nicht optimiert)
in A8:

Code:

=LET(xA;SEQUENZ(16;1;DATWERT("1."&$L$1);1);xB;Feiertage!G3:H16;MAP(xA;LAMBDA(d;WENN(ZÄHLENWENN(INDEX(xB;;1);d)=0;WENN(WOCHENTAG(d;2)=7;"Sonntag";d);XVERWEIS(d;INDEX(xB;;1);INDEX(xB;;2))))))

und in F8:

Code:

=LET(xA;SEQUENZ(TAG(EDATUM(A3;1)-1)-16;1;DATWERT("1."&$L$1)+16;1);xB;Feiertage!G3:H16;MAP(xA;LAMBDA(d;WENN(ZÄHLENWENN(INDEX(xB;;1);d)=0;WENN(WOCHENTAG(d;2)=7;"Sonntag";d);XVERWEIS(d;INDEX(xB;;1);INDEX(xB;;2))))))

Gruß Uwe