Office: Spalten verbinden? oder .....

Hallo,

es handelt sich um eine spillende Formel. Da musst du darauf achten, dass im Spillbereich sich nur leere Zellen befinden. Dann klappt auch die vollständige Ausgabe der Tabelle. Also in deinem Fall entewder die Formel mit Überschriften ab Zelle A1 (Zelle für Formel) oder die Formel ohne Überschriften ab A2.

Gruß Uwe

 

... hier noch die Datei mit beiden Formeln.

Gruß Uwe

 

Hallo,

da du nirgends deine Excel-Version angegeben hast, habe ich als Version Excel365 angenommen.
Dazu habe ich dir in Zelle Tabelle1!A3 folgende (spillende) Formel eingefügt (mit Resultatbereich Tabelle1!A3:E13 und folgende Zeilen):

Code:

=LET(
    abDatum; DATUM(2026; 6; 18);
    Matrix; Tabelle1[#Alle];
    KopfZl; INDEX(Matrix; 1; 0);
    Daten; WEGLASSEN(Matrix; 1);
    NxtZahlg; NACHZEILE(
        Daten;
        LAMBDA(zl;
            LET(
                Eintritt; INDEX(zl; ; 4);
                Monate; INDEX(zl; ; 3);
                MoDif; DATEDIF(Eintritt; abDatum; "m");
                MoNxt; AUFRUNDEN(MoDif / Monate; 0);
                EDATUM(Eintritt; Monate * MoNxt)
            )
        )
    );
    VSTAPELN(
        HSTAPELN({"Nächster". "Zahlungstermin". "". "ab Datum:"}; abDatum);
        HSTAPELN(KopfZl; "Nächste Zahlg");
        HSTAPELN(Daten; NxtZahlg)
    )
)

Diese Formel ermittelt zu einem gegebenen "abDatum" (im Beispiel der 18.06.2026), wann die nächste Zahlung fällig ist bei vorgegebenem Eintrittsdatum und Monate-Intervall. Dieses Fälligkeitsdatum wird in Spalte E angezeigt.

Das vorzugebende "abDatum" kann am Anfang der Formel festgelegt werden:
=LET(abDatum; DATUM(2026;6;18); ,,,
Die Mitgliedertabelle im Arbeitsblatt "mitglieder" hat bei dir den Namen "Tabelle1[#Alle]" und ist der Variable "Matrix" zuzuweisen, so wie oben in der Formel zu sehen ist.