Office: am Ende angefügt werden soll

In meiner Excel-Datei (im Anhang) auf der "Start"-Tabelle
gebe ich Daten ein, die dann am Ende auf der
"Mitglieder"-Tabelle neu am Ende angefügt werden soll.
Hatte ein paar Tage probiert, aber hat bis jetzt
nicht so funktioniert, wie ich es haben wollte.
Kann mir jemand dabei Unterstützen?
Danke

 

Hallo Poll,

das ist leider etwas umständlich zu händeln (verbundene Zellen und Formeln im Listbojekt). Deshalb so:

Code:

Sub NeuEintragen()
    Dim arrN(), arrR1(), arrR2(), arrC(), i&
    With Tabelle4
        arrN = Array(.Range("F5").Value, .Range("I5").Value, .Range("F7").Value, .Range("F9").Value, .Range("F11").Value, _
        .Range("F13").Value, .Range("F15").Value, .Range("F17").Value, .Range("F19").Value, .Range("F21").Value, .Range("F23").Value)
        arrR1 = Array(.Range("F25").Value, .Range("F27").Value, .Range("F29").Value)
        arrR2 = Array(.Range("F31").Value, .Range("F33").Value, .Range("F35").Value, .Range("F37").Value)
    End With
    With Tabelle1.ListObjects(1)
        .ListRows.Add.Range.Resize(1, UBound(arrN) + 1) = arrN
        With .DataBodyRange
            .Cells(.Rows.Count, 14).Resize(1, UBound(arrR1) + 1) = arrR1
            .Cells(.Rows.Count, 17).Resize(1, UBound(arrR2) + 1) = arrR2
        End With
    End With
    arrC = Array("F5", "I5", "F7", "F9", "F11", "F13", "F15", "F17", "F19", "F21", "F23", "F25", "F27", "F29", "F31", "F33", "F35", "F37")
    For i = LBound(arrC) To UBound(arrC)
        Tabelle4.Range(arrC(i)) = ""
    Next i
End Sub

Die Formeln im Listobjekt sind inkonsistent.

Gruß Uwe

 

Moin,

zu Uwe's berechtigter Kritik gibt es nix hinzuzfügen. Aber alternativ könnte man es auch so lösen:

Allen relevanten Zellen im Blatt Start im Namensmanager einen Namen zuweisen.
Ich hab das im Beispiel nur für Mit-NR, Anrede und Name gemacht. Der Rest wäre dann Deine Aufgabe. Dem Speicherbutton diesen Code zuweisen:

Code:

Sub ADDNewMember()
    Dim ws As Worksheet
    Dim lo As ListObject
    Dim newRow As ListRow
   
    ' Arbeitsblatt festlegen
    Set ws = Tabelle1 'oder ThisWorkbook.Sheets("mitglieder") ' Anpassen: Blattname
   
    ' Prüfen, ob bereits eine Tabelle existiert
    On Error Resume Next
    Set lo = ws.ListObjects("Tabelle1") ' Listobjektname anpassen
    On Error GoTo 0
 
   
    ' Falls keine Tabelle vorhanden ist, eine neue erstellen
    If lo Is Nothing Then
        ' Annahme: Überschriften stehen in A1:C1 ....auch anpassen
        Set lo = ws.ListObjects.Add( _
            SourceType:=xlSrcRange, _
            Source:=ws.Range("A1:C1"), _
            XlListObjectHasHeaders:=xlYes)
        lo.Name = "Tabelle1"
    End If
   
    ' Neue Zeile am Ende der Tabelle hinzufügen
    Set newRow = lo.ListRows.Add
   
    ' Werte in die neue Zeile schreiben
    With newRow.Range
        .Cells(1, 1).Value = ThisWorkbook.Names("Mit_NR").Value       
        .Cells(1, 2).Value = ThisWorkbook.Names("Anrede").Value
        .Cells(1, 3).Value = ThisWorkbook.Names("Name").Value
'Rest ergänzen
    End With
   
    MsgBox "Datensatz erfolgreich hinzugefügt!", vbInformation
   
    'noch die Felder der Tabelle Start leeren.... kannst Du sicher auch allein...
End Sub

 

allen beide ein Herzlichen Dank.
OilMax, Deine Version habe ich getestet und bin sehr zufrieden. Nochmals Danke.
R J, Deine Version werde ich weiter daran arbeiten und diese dann auch testen.
Auch Dir nochmals Danke.
by pooll

 

Hi,

im Grunde braucht man doch die ganze Seite "Start" nicht. Man kann doch direkt in die Tabelle Mitglieder schreiben. Wenn man unbedingt eine Eingabemaske haben will, könnte man auch den Cursor in die Mitgliedertabelle setzen und dann Alt-N-M drücken (also Alt gedrückt halten und dann nacheinander N und M drücken). Damit erhält man ohne sich um irgendwas kümmern zu müssen dies:

Vielleicht reicht dir das schon?

 

Hallo HKindler,
das ganze System wird mit verschiedenen Menue-Structuren aufgearbeitet. Unter anderen, Suchen, Bearbeiten, Neuanmeldungen..... Bin dabei das dann fürs Web zu benutzen. Ja, ich weis es ist schwierig. Muss in meinem alter wieder die Erfahrungen von früher aufarbeiten.
by pooll

 

Hallo,

so ein umfangreiches Projekt würde ich in Access realisieren. Warum legst du die Beispieldatei als xlsm an, obwohl sie keine Makros enthält?

 

Hi,

Diese Punkte sind doch alle mit der "Formulareingabe" abgedeckt...

OK, es könnte sein, dass es die Formulareingabe im Web nicht gibt. Aber dort gibt es ganz sicher kein VBA!

 

Klaus-Dieter, hatte die Makros entfernt.
Wie ich schrieb, möchte ich erstmal wieder lernen. In den 80er hatte ich mich beruflich spezialisiert auf Datenbanken. Heute wieder einen Anfang zu finden ist meine Idee um wieder rein zu finden im Datenbanksystem. Excel scheint mir ein guter Anfang zu sein. Verbringe viel Zeit und Muse zu lernen. Wenn das Programm fertig ist, sollte man über den Webzugriff damit arbeiten können. Meine Idee .

By pooll

 

Hallo,

man kann eh nur in solchen Foren Wege aufzeigen, wie man ein Problem anpacken kann.
Die Lösungswege zur gestellten Frage/Bitte können vielschichtig sein, aber wenn es um persönliche Daten geht bis hin Bankdaten sollte man weder Excel noch Access als Aufbewahrungsort für solche Daten nutzen.
Vor allem dann, wenn es im Netz in welcher Form auch immer genutzt wird.

Dies bitte ich als gut gemeinten Rat zu verstehen und nicht als Vorwurf.

Wenn du dies aber zum Lernen nutzen willst oder um die "grauen Zellen" zu massieren warum nicht. Wichtig ist, keine Realdaten zu veröffentlichen.

Zurück zu deinen Ansinnen. Man kann neben deiner Idee dies im Tabellenblatt zu bauen bzw. die Nutzung des alten DataForm, was MS in neueren Excelversionen etwas versteckt hat, es auch im Userform oder gar im Ribbonband (Menüleiste) einbauen.

Je nach dem wozu oder wie man es nutzen will.

Ansonsten Viel Spaß beim Lernen.

Gruß Uwe