Office: 2 Tabellen vergleichen/aktualisieren

hallo,

Ich habe eine Exceldatei mit 2 Tabellen. Eine Tabelle(Tabelle2), die alle offenen RMA-Vorgänge anzeigt, wird ständig aktualisiert (RMA-Nummern, Ship Dates und viele überflüssige Informationen). Die andere Tabelle(Tabelle1) soll jetzt nur die für mich wichtigsten Informationen enthalten. Da die Tabelle2 regelmäßig aktualisiert wird müssen diese Änderungen auch in Tabelle1 eingetragen werden.
Das ansich per Makro aufzeichnen zu machen ist nicht das Problem.

Aber da sich Tabelle2 ja regelmäßig verändert wird dann beim Makro ausführen die vorhandene Tabelle1 komplett überschrieben, da ja nur die momentan vorhandenen Daten übertragen werden. Es müsste also ein Abgleich zwischen Tabelle1 und Tabelle2 gemacht werden. Gleiche Daten sollen so bleiben wie sie sind. Daten die in Tabelle1 noch vorhanden sind, aber in Tabelle2 nichtmehr (da RMA-Vorgang abgeschlossen) sollen irgendwie kenntlich gemacht werden, z.B. rot hinterlegt. Daten die in Tabelle 2 neu hinzu gekommen sind sollen natürlich auch in Tabelle1 dementsprechend übernommen werden.
Tabelle1 soll also eine vortlaufende Tabelle sein und nicht nach jeder aktualisierung von Tabelle2 neu "beginnen".

Ich denke das wird irgendwie per Makro zu realisieren sein, aber ich kenne mich da nicht wirklich aus.


PS zur Datei:
Dtl Num(Tabelle2) soll übertragen werden auf RMA#(Tabelle1)
Ship Part No(Tabelle2) -----> Part(Tabelle1)
Create Date (ET) -------> Ship-Date(Tabelle1)

 

Hallo!

Keine Ahnung, ob ich dich richtig verstanden habe, aber vielleicht geht's ja in die richtige Richtung:

Code:

Sub Übertrag()
Dim Zelle As Range
Dim Ende As Long
Dim Quelle As Worksheet, Ziel As Worksheet
Set Quelle = Sheets("Tabelle2")
Set Ziel = Sheets("Tabelle1")
With Ziel
For Each Zelle In Quelle.Range("C3:C100").SpecialCells(xlCellTypeConstants)
If WorksheetFunction.CountIf(.Columns(3), Zelle) = 0 Then
Ende = .Range("C65536").End(xlUp).Row + 1
.Cells(Ende, 3) = Zelle
.Cells(Ende, 4) = Zelle.Offset(0, 4)
.Cells(Ende, 5) = Zelle.Offset(0, 7)
End If
Next Zelle
End With
End Sub

 

Ja, das geht definitiv in die richtige Richtung. Dafür erstmal nen dickes Dankeschön :D

Ich weiß halt nicht wie weit man da Modifikationen anstellen kann.
Der übersichtshalber wäre es schön, wenn bestimmte Daten automatisch gekennzeichnet werden könnten.
Folgende Situation: Tabelle2 wird aktualisiert. In Tabelle1 stehen noch Daten, die durch die Aktualisierung veraltet sind( bzw. nichtmehr in Tabelle2 vorhanden sind). Können diese Daten in Tabelle1 dann irgendwie rot markiert werden oder beliebig anders kenntlich machen.

 

Hallo!

Vielleicht so?

Code:

Sub Übertrag()
Dim Zelle As Range
Dim Ende As Long
Dim Quelle As Worksheet, Ziel As Worksheet
Set Quelle = Sheets("Tabelle2")
Set Ziel = Sheets("Tabelle1")
With Ziel
For Each Zelle In Quelle.Range("C3:C100").SpecialCells(xlCellTypeConstants)
If WorksheetFunction.CountIf(.Columns(3), Zelle) = 0 Then
Ende = .Range("C65536").End(xlUp).Row + 1
.Cells(Ende, 3) = Zelle
.Cells(Ende, 4) = Zelle.Offset(0, 4)
.Cells(Ende, 5) = Zelle.Offset(0, 7)
End If
Next Zelle
End With
For Each Zelle In Ziel.Range("C2:C65536").SpecialCells(xlCellTypeConstants)
If WorksheetFunction.CountIf(Quelle.Columns(3), Zelle) = 0 Then
Zelle.Interior.ColorIndex = 3
Else
Zelle.Interior.ColorIndex = xlNone
End If
Next Zelle
End Sub

 

genau das ist es. Danke, Danke und nochmal Danke

Du bist im wahrsten Sinne des Wortes ein schatzi :D

 

Hallo , ich habe noch eine Frage, da ich mich in der Materie "Makros" nicht wirklich auskenne.
was wäre denn im makro zu ändern, wenn ich statt Spalte J zum Beispeil Spalte M übertragen haben möchte?
ich habe zwar ein bisschen probiert, aber wie zu erwarten ohne Erfolg.
wäre nett, wenn mir jemand den entsprechenden Teil des Makros bezogen auf das Beispiel (s.o.) zeigen könnte.

Danke!

 

Hallo!

.Cells(Ende, 5) = Zelle.Offset(0, 7)

Hier wird auf Spalte J zugegriffen. Warum?
"Zelle" befindet sich in Spalte C (also Spalte 3).
Diese wird nun um 7 Spalten verschoben, also nach Spalte 3+7=10 (Spalte J).
Spalte M befindet sich noch 3 Spalten weiter, also

.Cells(Ende, 5) = Zelle.Offset(0, 10)

greift auf Spalte M zu. Warum?

"Zelle" befindet sich immernoch in Spalte C (also Spalte 3).
Dieses Mal wird sie um 10 Spalten verschoben, also in Spalte 13, also in Spalte M.

Ich hoffe, das war einigermaßen verständlich.