Office: 2 Zeilen automatisch zusammenfügen

Hallo Leute,

Ich bin heute auf ein Problem gestoßen, dass ich alleine leider nicht lösen kann.
Ich habe eine Tabelle erstellt, in der automatisch bei Eintrag einer Position und Menge die Kosten errechnet werden (das war für mich schon eine Höchstleistung^^)
Screen: http://img693.imageshack.us/img693/5551/tabeller.png
Nun habe ich das Problem, dass 2 mal die selbe Position zum selben Arbeiter und Projekt(siehe Position "VE7.03") nicht vorkommen sollte.
Um den Arbeitsaufwand beim Eintragen so gering wie möglich zu halten, sollte automatisch wenn Projekt, Position und Arbeiter gleich sind Excel die beiden Zeilen zusammenlegen, d.h. die Menge addieren und die 2. Zeile sozusagen löschen.
Ist das irgendwie möglich?

Danke schonmal =)

MfG Wolfee

PS: hoffe mein Problem is rübergekommen^^

 

Hallo!

Wenn du nichts in VBA programmieren möchtest, hätte ich hier zwei Vorschläge (zur leichteren Auswertung bei 2. haben ich die Spalten Menge und Arbeiter vertauscht):

1. Löse es mit einer Pivot-Tabelle: Ziehe Projekt, Position und Arbeiter in den Zeilenbereich, Menge und Kosten in den Wertebereich.
Das Ergebnis könnte (je nach Formatierung) so aussehen wie rechts oben.

2. Eliminiere Duplikate aus den Spalten Projekt, Position und Arbeiter mit dem Erweiterten Filter ( Tutorial: Spezialfilter ) und addiere die Werte mittels SUMMENPRODUKT.
Das Ergebnis siehst du rechts unten.

	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Projekt	Positon	Arbeiter	Menge	Kosten
2	A	VE7.03	A	3	12,75				Projekt	Positon	Arbeiter	Summe von Menge	Summe von Kosten
3	A	VE7.01	B	4	9,4				A	VE7.01	B	4	9,4
4	A	VE7.03	A	2	8,5					VE7.03	A	5	21,25
5	A	VE7.06	B	1	6,5					VE7.06	B	1	6,5
6	A	VE8.12	B	4	23,4					VE8.03	B	1	4,05
7	A	VE8.03	B	1	4,05					VE8.12	B	4	23,4
8	B	VE7.01	A	1	2,35				A Ergebnis			15	64,6
9	B	VE8.05	A	4	20				B	VE7.01	A	1	2,35
10	B	VE8.04	B	1	4,4					VE8.01	A	3	6,75
11	B	VE8.10	B	5	17,75					VE8.04	B	1	4,4
12	B	VE8.01	A	3	6,75					VE8.05	A	4	20
13										VE8.10	B	5	17,75
14									B Ergebnis			14	51,25
15									Gesamtergebnis			29	115,85
16
17
18									Projekt	Positon	Arbeiter	Menge	Kosten
19									A	VE7.03	A	5	21,25
20									A	VE7.01	B	4	9,4
21									A	VE7.06	B	1	6,5
22									A	VE8.12	B	4	23,4
23									A	VE8.03	B	1	4,05
24									B	VE7.01	A	1	2,35
25									B	VE8.05	A	4	20
26									B	VE8.04	B	1	4,4
27									B	VE8.10	B	5	17,75
28									B	VE8.01	A	3	6,75

Zelle	Formel
L19	=SUMMENPRODUKT(($I19=$A$2:$A$12)*($J19=$B$2:$B$12)*($K19=$C$2:$C$12)*D$2:D$12)
M19	=SUMMENPRODUKT(($I19=$A$2:$A$12)*($J19=$B$2:$B$12)*($K19=$C$2:$C$12)*E$2:E$12)

 

die Pivottabelle funktioniert gut, aber gibt es eine Möglichkeit, dass sich die Pivottabelle automatisch aktualisiert wenn ich in der "normalen" Tabelle einen Wert ändere?

und zu diesem Spezialfilter:
wenn ich das Summenprodukt bilden muss, ist es ja wieder nicht automatisch oder versteh ich das ganze falsch?

danke für die bemühungen

 

Hallo!

Eine Pivot-Tabelle aktualisiert sich absichtlich nicht automatisch, um Rechenleistung zu sparen. Aber über die Programmierung eines entsprechenden WorksheetChange- oder SheetActivate-Ereignisses wäre auch das machbar; vielleicht noch gepaart mit einem dynamischen Bereichsnamen, falls sich die Quellliste erweitert.

Der Spezialfilter ist ebenfalls statisch. Wenn du hier eine dynamische Anpassung wünschst, dann lässt sich das auch mit Formeln lösen, hier mit der Hilfsspalte F:

	A	B	C	D	E	F	G	H	I	J
1	Projekt	Position	Arbeiter	Menge	Kosten	0		Projekt	Position	Arbeiter
2	A	VE7.03	A	3	12,75	1		A	VE7.03	A
3	A	VE7.01	B	4	9,4	2		A	VE7.01	B
4	A	VE7.03	A	2	8,5	2		A	VE7.06	B
5	A	VE7.06	B	1	6,5	3		A	VE8.12	B
6	A	VE8.12	B	4	23,4	4		A	VE8.03	B
7	A	VE8.03	B	1	4,05	5		B	VE7.01	A
8	B	VE7.01	A	1	2,35	6		B	VE8.05	A
9	B	VE8.05	A	4	20	7		B	VE8.04	B
10	B	VE8.04	B	1	4,4	8		B	VE8.10	B
11	B	VE8.10	B	5	17,75	9		B	VE8.01	A
12	B	VE8.01	A	3	6,75	10		#NV	#NV	#NV

Zelle	Formel
F2	=F1+(SUMMENPRODUKT((A$2:A2=A2)*(B$2:B2=B2)*(C$2:C2=C2))=1)
H2	=INDEX(A:A;VERGLEICH(ZEILE($A1);$F:$F;))
I2	=INDEX(B:B;VERGLEICH(ZEILE($A1);$F:$F;))
J2	=INDEX(C:C;VERGLEICH(ZEILE($A1);$F:$F;))

 

ok ich seh schon das wird mir jetz zu kompliziert^^
aber das mit der pivot tabelle funktioniert recht schön =)

vielen dank schatzi