Office: AbfrageBox

Hallo Freunde,

habe hier ein kleines Makro, das seinen zweck voll und ganz erfüllt und zwar sollen bestimmte Zellen in der Tabelle2 gelöscht werden.

Sub Inhalte_löschen()
'
' Inhalte_löschen Makro
' Löscht die Inhalte von Tabelle2
'

'
Sheets("Tabelle2").Select
Range("E2:G20").Select
Selection.ClearContents
Range("E25:G43").Select
Selection.ClearContents
Range("E2").Select
End Sub

Allerdings hätte ich ganz gerne nachdem ich den Button für das löschen angeklickt habe, dass eine Sicherheitsabfrage kommt - Box mit Daten wirklich löschen - ja oder nein bei ja fortfahren bei nein Abbruch.

 

Hallo!

Code:

Sub Inhalte_löschen()
Dim x
x = MsgBox("Wirklich löschen?", vbYesNo)
If x = 6 Then Sheets("Tabelle2").Range("E2:G20,E25:G43").ClearContents
End Sub

 

Hallo Schatzi, danke für deine schnelle Antwort - ich hoffe, ich trete dir nicht zu nahe wenn ich SCHATZI schreibe ?

Hätte noch ein kleines Problem zu lösen fogender Code den mir hier jemand gemacht hat funktioniert bestens, wenn ich diesen von der Tabelle3 aus Starte, nun habe ich mir eine Startseite zugelegt auf dem ich alle Buttons unterbringe die Tabelle heißt "start" wenn ich jetzt den Code von dort aus Starte kommt eine Fehlermeldung ? muss da die Quelle geändert werden? oder an was muss ich dabei grundsätzlich denken, wenn ich einen Button von einer Seite auf eine andere verschiebe!.

Code:
Public Sub NichtLeereZeilen_Kopieren()
'
' jahresdienstbefreiung Makro
' Erstellt eine Kopie der mtl. Dienstbefreiungen für die Jahrestabelle
'
Dim Quelle As Range, Ziel As Range, Zeile As Range, Zelle As Range
Dim IstZeileLeer As Boolean

'Quell- und Zielbereich wie von Dir vorgegeben
Set Quelle = Range("A35:H48")
'Suche im Arbeitsblatt 'jahrestabelle' in der Spalte A nach der Zelle mit dem Text 'Dienstbefreiung(en)'
Set Ziel = Sheets("jahrestabelle").Range("A:A").Find(What:="Dienstbefreiung(en)", _
LookIn:=xlValues, LookAt:=xlWhole, SearchOrder:=xlByColumns, SearchDirection:=xlNext)
'Positioniere von dort in der drittnächsten Zelle in Spalte A (unterhalb von 'Name'):
Set Ziel = Ziel.Offset(3)
'Durchlaufe die folgende Schleife, bis eine leere Zelle in Spalte gefunden wurde
Do Until Ziel.Value = ""
Set Ziel = Ziel.Offset(1)
Loop

For Each Zeile In Quelle.Rows
'Überprüfe, ob die Quellzeile leer ist
IstZeileLeer = True
For Each Zelle In Zeile.Cells
If Not IsEmpty(Zelle) Then IstZeileLeer = False: Exit For
Next Zelle
'Quell-Zeile ist gestestet
If IstZeileLeer Then
'Sie ist leer: tue nichts
Else
'Sie ist nicht leer: kopiere die Zeile (nur Werte) von der Quelle ins Ziel
Zeile.Copy
Ziel.PasteSpecial Paste:=xlPasteValues, operation:=xlNone, skipblanks:=False, Transpose:=False
'Stelle Zielzeile 1 Zeile tiefer
Set Ziel = Ziel.Offset(1)
End If
Next Zeile
'Kopiermodus beenden
Application.CutCopyMode = False

End Sub

Wäre nett wenn du mir da weiterhelfen würdest

 

Hallo!

ungetestet:
Set Quelle = Sheets("Tabelle3").Range("A35:H48")

 

Und schon funtzt das ganze - vielen Dank - Ihr seid ein tolles Team.