Office: (Office 2000) Access-Hauptfenster: Größe festlegen und fixieren

rainerZZ · 28. Juni 2020

Hallo zusammen,

ich würde gerne die Größe des Access-Hauptfensters beim Starten der Datenbank immer gleich haben (Größe in VBA festlegen?) und auch (wenn möglich) ein vergrößern/verkleinern (Maus am Rand des Fensters) des Hauptfensters unterbinden.

Geht sowas?

Danke vorab für eure Hilfe.

Gruß, Rainer

:)

Mokkie · 30. Juni 2020

Hallo Rainer,

das kann man, auch, mit VBA machen
Code:

Private Sub Form_Activate ()
DoCmd.MoveSize x, x, xxxxx, xxxxx
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ansonsten sollte das doch auch bei den Eigenschaften, des Formulars einstellbar sein.

ebs17 · 30. Juni 2020

https://lmgtfy.com/?q=ms+access+gr%C...e+hauptfenster

Daneben: Größe ist auch abhängig von der verwendeten Bildschirmauflösung. Da gibt es heutzutage allerhand Varianten.

rainerZZ · 30. Juni 2020

\@Mokkie,
danke für den Hinweis. Es geht aber nicht um die Formulargröße, sondern um die Größe des Access-Fensters.

@ebs17,
wenn ich mit den dort vorliegenden Lösungsansätzen zurecht gekommen wäre, hätte ich hier nicht nochmal spezifisch nachgefragt. Außerdem müsstest du deinen Google-Witz dann bei 90% der Beiträge hier posten *Smilie

ebs17 · 30. Juni 2020

spezifisch nachgefragt
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn Du aus einer Vielzahl aus Varianten Dir nichts entnehmen kannst, wie hoch ist da eine Wahrscheinlichkeit, dass das bei einer weiteren Wiederholung gelingt und wie hoch ist der Sinn, eine solche Wiederholung noch einmal aufzuschreiben?

knobbi38 · 1. Juli 2020

Hallo Rainer,

wenn du mit einer bei Google gefundenen Lösung nicht zurande gekommen wärest, hätte man aber konkret einen Ansatzpunkt gehabt, woran es denn happerte. Nochmal eine ähnliche Lösung hier aufzuführen, hätte dir dann vermutlich auch nicht weiter geholfen. Insofern hat Eberhard schon recht.

Trotzdem einmal der Versuch. Hier ist eine weit verbreitete Klasse, die auch für das Access Hauptfenster genutzt werden kann:
Forms: Move and Resize form windows from code

Zu deiner zweiten Frage, könnte man eventuell einen Versuch mit der API Funktion SetwindowLongA() machen. Ob das aber auch mit dem bereits geöffnetem Access-Window möglich ist, habe ich noch nicht probiert, weil ich bisher dafür noch nie die Notwendigkeit gesehen habe.

Ulrich

ebs17 · 1. Juli 2020

Fixieren: Database, Application ... haben keine eigenen Ereignisse, die ja Basis für eine Überwachung wären.

Also dürfte man von Windows aus das spezielle Fenster überwachen (nichttrivial), oder man leitet ein solches Ereignis aus einem häufig genutzten Formular (Timer fände ich übertrieben) ab und setzt die Größe jeweils neu aus gespeicherten Daten.

knobbi38 · 1. Juli 2020

\@Eberhard:
Normalerweise würde man den WindowStyle, speziell den Rahmen, so anpassen, daß eine Größenänderung nur noch per Software gemacht werden kann, ähnlich wie bei einem Dialogfenster. Dann muß das nicht extra überwacht werden.

Gruß Ulrich

ebs17 · 1. Juli 2020

Dann hätten sich die Eingangsfragen aber bereits erledigt. Ein Softwarezugriff wäre explizit und müsste einem ins Bewusstsein kommen.

knobbi38 · 1. Juli 2020

Hallo,

es ist mit SetWindowLong möglich, den Rahmen des Accessfensters entsprechend zu ändern. Ich hatte das doch schon mal umgesetzt, aber komplett verdrängt, weil man es eigentlich nur selten braucht.

Für alle, die daß mal ausprobieren möchten, hier der Code für ein Modul mit den notwendigen API Deklarationen:
Code:

' *****************************************************************************
' Modul: modWindowUI
' *****************************************************************************
'
Option Compare Database
Option Explicit

Public Const MOD_NAME As String = "modWindowUI"

' SetWindowPos Flags
Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOZORDER = &H4
Private Const SWP_NOREDRAW = &H8
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_FRAMECHANGED = &H20 ' The frame changed: send WM_NCCALCSIZE
Private Const SWP_SHOWWINDOW = &H40
Private Const SWP_HIDEWINDOW = &H80
Private Const SWP_NOCOPYBITS = &H100
Private Const SWP_NOOWNERZORDER = &H200 ' Don't do owner Z ordering

Private Const SWP_DRAWFRAME = SWP_FRAMECHANGED
Private Const SWP_NOREPOSITION = SWP_NOOWNERZORDER

' Field offsets for GetWindowlong
Private Const GWL_STYLE = (-16)

#If Win64 Then
Private Declare PtrSafe Function apiGetWindowLongPtr Lib "user32" _
Alias "GetWindowLongPtrA" ( _
ByVal hWnd As LongPtr, _
ByVal nIndex As Long) As LongPtr

Private Declare PtrSafe Function apiSetWindowLongPtr Lib "user32" _
Alias "SetWindowLongPtrA" ( _
ByVal hWnd As LongPtr, _
ByVal nIndex As Long, _
ByVal dwNewLong As LongPtr) As LongPtr
#Else
Private Declare PtrSafe Function apiGetWindowLongPtr Lib "user32" _
Alias "GetWindowLongA" ( _
ByVal hWnd As LongPtr, _
ByVal nIndex As Long) As LongPtr

Private Declare PtrSafe Function apiSetWindowLongPtr Lib "user32" _
Alias "SetWindowLongA" ( _
ByVal hWnd As LongPtr, _
ByVal nIndex As Long, _
ByVal dwNewLong As LongPtr) As LongPtr
#End If

Private Declare PtrSafe Function apiSetWindowPos Lib "user32" _
Alias "SetWindowPos" ( _
ByVal hWnd As LongPtr, _
ByVal hWndInsertAfter As LongPtr, _
ByVal x As Long, _
ByVal y As Long, _
ByVal cx As Long, _
ByVal cy As Long, _
ByVal wFlags As Long) As Long

Public Sub AccessLockScreen(ByVal Value As Boolean)
' Enable/disable the resize feature of the access application window
' by resetting then WS_THICKFRAME/WS_SIZEBOX

Const WS_THICKFRAME = &H40000

Dim lngStyle As LongPtr
Dim lngResult As LongPtr

lngStyle = apiGetWindowLongPtr(Application.hWndAccessApp, GWL_STYLE)

If Not Value Then
lngStyle = lngStyle Or WS_THICKFRAME
Else
lngStyle = lngStyle And Not WS_THICKFRAME
End If

lngResult = apiSetWindowLongPtr( _
Application.hWndAccessApp, GWL_STYLE, lngStyle _
)
ReDrawNonClient Application.hWndAccessApp
End Sub

Public Sub ReDrawNonClient(ByVal hWnd As LongPtr)
Dim swpFlags As Long
Dim lngResult As Long

swpFlags = SWP_FRAMECHANGED Or SWP_NOMOVE Or SWP_NOZORDER _
Or SWP_NOSIZE Or SWP_NOACTIVATE
lngResult = apiSetWindowPos(hWnd, 0, 0, 0, 0, 0, swpFlags)
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Der Aufruf erfolgt dann mit:
Code:

AccessLockScreen True
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß Ulrich

markusxy · 7. Januar 2021

\@Ulrich,

von knobbi38

Code:
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Private Declare PtrSafe Function apiSetWindowLongPtr Lib "user32" _
Alias "SetWindowLongPtrA" ( _
ByVal hWnd As LongPtr, _
ByVal nIndex As Long, _
ByVal dwNewLong As LongPtr) As LongPtr

Dim lngStyle As LongPtr
Dim lngResult As LongPtr
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei so was muss ich dann schon *biggrin.gif* .
Zum Glück ist es egal, wenn man so was falsch deklariert.

Viel interessanter ist es, dass sich der TS nicht meldet. *grins

Edit:
Das mit dem LongPtr nehme ich gleich wieder zurück.
Laut online Doku steht LONG_PTR.
Also alles Bestens.
So ist es wenn man sich erst als Klugscheißer betätigt und erst dann die Doku anschaut.
Die Logik fehlt mir aber dennoch.

knobbi38 · 2. Juli 2020

\@markusxy:
das da etwas zunächst merkwürdig erscheint, ist schon richtig.

Interessant sind allerdings bei beiden Deklarationen von "SetWindowLongA" und "GetWindowLongA" für den 32Bit Teil. Hier wird der Rückgabewert ebenfalls als LongPrt deklariert, obwohl er eigentlich als Long deklariert sein sollte. Da aber beide einen 32Bit Ganzahlwert aufnehmen können, wird das hier geschickt ausgenutzt, damit innerhalb der Funktionen selber nicht auch noch zwischen 32Bit und 64Bit unterschieden werden muß. Das übernimmt in diesem Fall der Kompiler selber.

Hatte jetzt gar nicht damit gerechnet, daß das überhaupt jemandem auffällt. *wink.gif*

Gruß Ulrich

markusxy · 7. Januar 2021

von knobbi38

@markusxy:
das da etwas zunächst merkwürdig erscheint, ist schon richtig.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Logik fehlt deshalb, weil es kein Pointer ist.

Vielleicht wurden einfach die Flags erweitert, oder eine Erweiterung ist angedacht und man kommt dann mit 32Bits nicht mehr aus.

Da hat man wohl versucht einen einheitlichen Aufruf zwischen 32 und 64 Bit zu ermöglichen zum Preis von fehlender Logik.
Daher auch LongPrt bei GetWindowLongA.

Aber vielleicht gibts auch eine andere Erklärung.
Aber das Thema ist zu nebensächlich, um sich da weitere Gedanken zu machen. *Smilie

Office: (Office 2000) Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren

Access-Hauptfenster: Größe festlegen und fixieren - Similar Threads - Access Hauptfenster Größe

Excel Sheet in Access einbinden mit acOLECreateLink

Access Datei wird per Makro nicht gespeichert

Ausdruck eines Etiketts auf verschiedenen PCs steuern

Access als Mediaplayer

Smarttags in Access LTE (2021)

Access Hauptfenster ausblenden aber Berichte einblenden

Access Hauptfenster ausblenden