Office: (Office 365) ActiveX Mehrere Checkboxen abfragen bei Button onclick

Hey Leute

habe ein Button erstellt der bei Click

alles was mit der Checkbox makiert ist (Produktion) der Wert "Ist-Bestand" um 1 erhöht.
mit einer Checkbox funktioniert supi bekomme es leider nicht hin das alle funktionieren .

Habe in der Original Datei Ca 100 stück

Gibt es die Möglichkeit den Button nur einmal am Tag zu nutzen? sonst MsgBox = Produktion wurde Erfasst!

Wäre supi wenn mir Jemand Helfen könnte

MFG

 

Code:

Option Explicit

Private Sub CommandButton1_Click()
    If CheckBox1.Value = True And Range("I9") < Date Then
        Range("G9") = Range("G9") + 1
        Range("I9") = Date
    End If
End Sub

formatiere die Zelle ;;;

 

Hey Hajo

Vielen dank für die schnelle Antwort.
und das muss ich jetzt für jede Checkbox machen oder kann man alle die da sind mit einer abfrage ansprechen?

was meinst du mit formatiere die Zelle
Gruß Beno

 

Halo Benno,

da kann man eine Schleife machen, mit Steuerelementen in Tabelle bin ich niht de Fachmann.

Gruß Hajo

 

Hi,

Code:

Private Sub CommandButton1_Click()
    Dim oobBox As OLEObject
    ' nur ausführen wenn in K10 ein Datum < Heute steht
    If Range("K10").Value < Date Then
        ' Schleife über alle ActiveX-Steuerelemente
        For Each oobBox In ActiveSheet.OLEObjects
            ' wenn das laufende Element eine Checkbox ist
            If oobBox.progID = "Forms.CheckBox.1" Then
                ' wenn die Spalte der linken oberen Ecke Spalte I ist
                If oobBox.TopLeftCell.Column = 9 Then
                    ' wenn das laufende Element aktiviert ist dann Inhalt der Zelle 2 Spalten links davon um 1 erhöhen
                    If oobBox.Object Then oobBox.TopLeftCell.Offset(0, -2) = oobBox.TopLeftCell.Offset(0, -2) + 1
                End If
            End If
        Next oobBox
        ' Datum in K10 eintragen
        Range("K10") = Date
    Else
        MsgBox "Produktion wurde bereits erfasst"
    End If
End Sub

Wenn der Code nur einmal am Tag ausgeführt werden darf, dann muss das Datum irgendwo im Tabellenblatt abgelegt werden - ich habe dazu mal die Zelle K10 verwendet, weil der CommandButton darauf liegt und man die Zelle nicht sehen kann.

---