Office: (Office 2016) Ältestes Datum finden

Hallo

In Spalte A befinden sich Personennummern. Diese können mehrfach vorkommen (hier gelb markiert).
In Spalte B ist das Eintrittsdatum der Personen zu finden.
Spalte C ist gesucht: Ich möchte die eingetragenen Ergebnisse finden. Ich habe diese hier händisch erstellt. Aber ich bin auf der Suche nach einer Formel dazu. Es soll immer das älteste Datum ausgegeben werden. Kommt die Personennummer nur einmal vor, ist das einfach. Kommt eine Personennummer aber mehrmals vor, muss das älteste Datum innerhalb der Spalte A, aber innerhalb der mehrmals vorkommenden Personennummer gesucht werden. Die weiteren Zellen mit mehrfach vorkommenden Personennummern sollen leer bleiben.



Vielen Dank und schöne Grüsse!

 

Min()

Du bist im falschen Forum. Bildbearbeitung ist ein anderes.
Bilder lade ich mir nicht runter, da Excel damit nichts anfangen kann.

Hochgeladene Bilder können zwar als solche in Excel importiert werden, sind jedoch bei der Lösung von Problemen nicht sehr hilfreich, da man die eigentlichen Daten nicht ohne große und zeitraubende Umwege direkt in die Tabelle übertragen kann.

Ich baue keine Datei nach, die Zeit hat schon jemand investiert.

http://www.excel-ist-sexy.de/bilder-statt-datei/
Eine hochgeladene Arbeitsmappe erhöht die Wahrscheinlichkeit, dass Du eine Lösung für Dein Problem erhältst.
Erstelle folglich bitte eine Demomappe, aus der deine Aufgabenstellung klar erkennbar ist und lade diese Mappe mit einem aussagekräftigen Dateinamen hoch.
Der Name einer hochgeladenen Mappe wird im Beitrag automatisch angezeigt, sodass es bei Verwendung von aussagekräftigen Namen leichter fällt, sie später im Ablageordner wiederzufinden und sie gedanklich einem bestimmten Thema zuzuordnen. Namen wie Muster*, Test*, Mappe*, Beispiel*, Fehler*, Kalender*, UserForm*, Forum* usw. sind so allgemein, dass eine Zuordnung zu einem Thema unmöglich gemacht wird.
Es sollte ein aussagekräftiger Name sein.
Wenn du an Stelle einer Demomappe deine Originalmappe hochladen willst, diese aber sensible Daten enthält, kannst du diese Daten ändern. Schaue Datei
http://hajo-excel.de/gepackt/fremd/Datei_verschluesseln.zip
Bei Download beachte bitte: von unsicheren Servern file-upload lade ich keine Datei herunter (lt. Einschätzung meines Virenprogramms)

Das ist nur meine Meinung zu dem Thema.

 

Hallo

Dann also hier nochmals mit Datei.

In Spalte A befinden sich Personennummern. Diese können mehrfach vorkommen (hier gelb markiert).
In Spalte B ist das Eintrittsdatum der Personen zu finden.
Spalte C ist gesucht: Ich möchte die eingetragenen Ergebnisse finden. Ich habe diese hier händisch erstellt. Aber ich bin auf der Suche nach einer Formel dazu. Es soll immer das älteste Datum ausgegeben werden. Kommt die Personennummer nur einmal vor, ist das einfach. Kommt eine Personennummer aber mehrmals vor, muss das älteste Datum innerhalb der Spalte A, aber innerhalb der mehrmals vorkommenden Personennummer gesucht werden. Die weiteren Zellen mit mehrfach vorkommenden Personennummern sollen leer bleiben.

 

Hallo,

sieh' dir mal die Funktion MINWENNS() an. Das sollte es sein.

Gruß Sigi

 

Hallo und vielen Dank!

Diese Formel ist leider nicht für Excel 2016 verfügbar.

LG

 

Hallo,

eine Lösung für Excel2016:

Ausgehend von deinen Beispieldaten hieße das:
1) Sortieren des Bereiches A2:B20 nach Spalte A+B aufsteigend
2) Formel in C2, Hinunterkopieren bis C20
Formel in C2: =WENN($A2=$A1;0;$B2)
3) Benutzerdef. Zahlenformat in C2:C20: TT.MM.JJJJ;;

 

Hallo Anton Exl

Das ist ein guter Hinweis!
Aber hast du auch eine Tipp ohne Sortieren?

LG

 

Hallo,

nein.

 

Hallo,

ich hatte dir gestern geschrieben, dass ich keine Formellösung für Excel2016 parat habe - das muss ich heute wieder zurücknehmen - ich habe eine:

Wollte man für Excel2021/Excel365 eine Formellösung (ohne der MINWENNS(..)-Variante) müsste sie so aussehen:
Formel in C2: =LET(dt; AGGREGAT(15;6; $B$2:$B$1976 / WENN($A$2:$A$1976=$A2;1;0);1); WENN(dt=$B2;dt;0))

Da du in Excel2016 die LET()-Funktion noch nicht zur Verfügung hast, muss man in der WENN-Funktion die AGGREGAT-Funktion 2x verwenden, womit die Formel entsprechend aufwendiger und auch langsamer wird - aber sie funktioniert:
Formel in C2: =WENN(AGGREGAT(15;6; $B$2:$B$1976 / WENN($A$2:$A$1976=$A2;1;0);1)=$B2; AGGREGAT(15;6; $B$2:$B$1976 / WENN($A$2:$A$1976=$A2;1;0);1);0)

Die Tabelle benötigt keine spezielle Sortierung - egal wie die Abfolge der Zeilendaten ist.

Datei liegt bei.

 

Wow! Herzlichen Dank! Das klappt!

 

Hallo,

die Formel von Anton lässt sich für XL2016 noch etwas vereinfachen zu:
=WENNFEHLER(AGGREGAT(15;6;B$2:B$1999/(A$2:A$1999=A2)/(AGGREGAT(15;6;B$2:B$1999/(A$2:A$1999=A2);1)=B2);1);"")

 

Hallo Werner,

danke für den Hinweis - zumindest die Vereinfachung der WENN-Funktion innerhalb des AGGREGAT zu einem logischen Term hätte ich sehen können. Aber manchmal ist man mit Blindheit geschlagen.

 

Gibt eine Lösung, so dass in den leeren Zellen ebenfalls das älteste Datum erscheint?

LG

 

Hallo,

die Formel vereinfacht sich dann erheblich:
=AGGREGAT(15;6;$B$2:$B$1976/($A$2:$A$1976=$A2);1)

Datei liegt bei.

 

Hallo Anton,

wobei aber in XL2016 en noch geprüft werden sollte, ob es die Personen.-Nr auch gibt. IN XL365 (hab ich nicht) ist das wohl wegen der dortigen "Spillfunktionalität" nicht notwendig

Deshalb mein Vorschlag für XL2016 in D2:

=WENNFEHLER(AGGREGAT(15;6;$B$2:$B$1999/($A$2:$A$1999=$A2)/(A2>0);1);"")

Ergänzend noch angemerkt. Die Formel von Anton ist mit {} geklammert. Diese wird in XL2016 nicht benötigt. Die wird nur angezeigt, weil Anton die Formel (ohne die {}) in XL365 erzeugt hat. Ältere XL-Versionen interpretieren viele "matrixformelnähniche" Formeln -also auch die vorliegende - aus neueren XL-Versionen dann so, als ob es {}-Formeln wären.