Office: Alternative zu SUMMENPRODUKT?

Hallo,

ich führe mit über mehrere Dateien und Arbeitsblätter verknüpfte Formeln Berechnungen in Excel aus. Vor allem rechne ich mit Matrizen mit z.B. 100 x 100 Zellen bzw. 100 Zeilen und 100 Spalten.

Bsp. 3 x 3 Matrix:
vonIndexNr\ nachIndexNr|100|200|300
100
200
300

Ich nutze für die eindeutige Wertzuweisung vonIndexNr nachIndexNr bisher die SUMMENPRODUKT-Formel:

B2:
=SUMMENPRODUKT(([Daten1.xls]Matrix1!$A$2:$A$4=$A2)*([Daten1.xls]Matrix1!$B$1:$D$1=B$1)*[Daten1.xls]Matrix1!$B$2:$D$4)

Gibt es eine schneller rechnende Formel oder andere Möglichkeit der Rechenbeschleunigung in meinem Fall?

Danke und LG, Mat

 

Hallo!

Teste mal:

=INDEX([Daten1.xls]Matrix1!$B$2:$D$4;VERGLEICH($A2;[Daten1.xls]Matrix1!$A$2:$A$4;);VERGLEICH(B$1;[Daten1.xls]Matrix1!$B$1:$D$1;))

 

Danke funzt :-) Was macht die Funktion schneller?

Und wie verhindere ich NV, wenn eine Indexbeziehung nicht vorkommt?

 

Hallo!

SUMMENPRODUKT gehört eben zu den langsameren Excel-Funktionen, VERGLEICH zu den schnelleren.
Außerdem willst du ja auch nix summieren und/oder multiplizieren, sondern "nur" suchen.

Da ich deine Daten nicht kenne, hier der klassische Fehlerabfang:
=WENN(ISTNV(DeineFormel);"";DeineFormel)

 

Danke...

mal eine generelle Zusatzfrage zu der Formelkombination INDEX - VERGLEICH: Was mache ich, wenn noch ein drittes Kriterium hinzukommt:

Bsp. 3 x 3 Matrix:

vonIndexNr|Kriterium|100|200|300
100|A
100|B
200|A
200|B
300|A
300|B

Sollte ich dann wieder SUMMENPRODUKT nehmen?
Nochmal Danke!

 

Hallo!

Wenn du mit SUMMENPRODUKT Geschwindigkeitsprobleme bekommst, dann lege einfach eine Hilfsspalte an, in der du deine beiden Spaltenkriterien verkettest,
Dann kannst du wieder auf INDEX+VERGLEICH zurückgreifen.

Ohne Hilfsspalte kannst du, wie du richtig sagst, wieder auf SUMMENPRODUKT ausweichen, oder aber INDEX+VERGLEICH als Matrixformel einsetzen.
Ich kann mir zwar kaum vorstellen, dass die Matrixformel schneller ist, aber testen kannst du's ja trotzdem.

	A	B	C	D	E	F
1
2				100	200	300
3		111	A	0,60633536	0,69067721	0,35330522
4		111	B	0,66245572	0,30005841	0,72539489
5		222	A	0,9337014	0,26611037	0,16256769
6		222	B	0,74581729	0,0564569	0,79054446
7		333	A	0,51429692	0,37673129	0,8429142
8		333	B	0,68716744	0,96741353	0,49740095
9
10
11
12	Spalte B	222
13	Spalte C	A
14	Zeile 2	200
15
16		0,26611037
17		0,26611037
18

Zelle	Formel
B16	=SUMMENPRODUKT((B3:B8=B12)*(C3:C8=B13)*(D2:F2=B14)*D3:F8)
B17	{=INDEX(D3:F8;VERGLEICH(B12&B13;B3:B8&C3:C8;);VERGLEICH(B14;D2:F2;))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]