Office: (Office 2003) Anfüge abfrage

Helfe beim Thema Anfüge abfrage in Microsoft Access Hilfe um das Problem gemeinsam zu lösen; \@Eberhard: An der Stelle wollte ich nur die vorhandene DB-Instanz verwenden und nicht mit CurrentDb jeweils eine neue. Das ist ein Ansatz, den ich... Dieses Thema im Forum "Microsoft Access Hilfe" wurde erstellt von MarkderNoob, 18. Januar 2011.

Seite 2 von 5

JOSEF P.

Josef P.

Anfüge abfrage

\@Eberhard:

An der Stelle wollte ich nur die vorhandene DB-Instanz verwenden und nicht mit CurrentDb jeweils eine neue.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das ist ein Ansatz, den ich gar nicht verändern würde. *wink.gif*

Ich dachte dabei aber an so etwas:
Code:

dim db as dao.database
set db = currentdb

...
FillCollection col, db, SQL
...
db.execute ...
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Angenommen es schleicht sich irgendwann in FillCollection so etwas ein:
Code:

Private Sub FillCollection(ByRef col As Object, ByRef dbs As Object, ByVal SQL As String)
...
'Aufräumen:
...
set dbs = nothing
end Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei einer Byval-Übergabe wäre nichts passiert.

In Beispielen, die ich (bewusst) las, wurden Objekte immer als Referenz übergeben, so dass dieses von mir als selbstverständlich angenommen und nicht in Frage gestellt wurde.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das würde ich an deiner Stelle in Zukunft in Frage stellen *biggrin.gif* - das ist nämlich ein weit verbreiteter Irrtum, dass man Objektreferenzen nur per ByRef übergeben kann.
ByRef ist nur bei einer Array-Übergabe notwendig. Ansonsten sollte man es (meiner Ansicht nach) nur dort einsetzen, wo man einen veränderten Variableninhalt an die aufrufende Prozedur zurückgeben will.

mfg
Josef

Josef P., 25. Januar 2011

#16
EBS17

ebs17

Wie bekomme ich die Fillcollection mit in die Ereignisprozedur des Command Buttons?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Frage so verstehe ich nicht.

BTW: Du solltest nicht immer den kompletten und gleichen (gleich = entsprechend der vorangegangenen Diskussion) wiederholen. Die Seiteneinwürfe hast Du korrekt verarbeitet, Das ist sichtbar.
Wenn Code, dann bitte in Code-Tags. So ist das besser lesbar, auch durch die vorhandene Formatierung (Zeileneinrückungen).
Wichtig ist die Herausstellung des eigentlichen Problems.

@josef:

Das würde ich an deiner Stelle in Zukunft in Frage stellen
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das Hochschalten der kritischen Überprüfung ist bereits mit der Überraschung erfolgt.

ByRef ist nur bei einer Array-Übergabe notwendig. Ansonsten sollte man es nur dort verwenden, wo man einen veränderten Variableninhalt an die aufrufende Prozedur zurückgeben will.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bei der Collection - eine neue (leere) erzeugt, in der Subprozedur gefüllt - ist das doch gegeben, oder?
Vgl. Acc2000 - Daten im Formular filtern und als xls …:
Code:

'Recordset exportieren
Public Function Recordset2Excel (ByRef rstData As Object, _
Optional ByVal StartRowNr As Long = 1, _
Optional ByVal StartColNr As Long = 1, _
Optional ByVal bWithRecordsetHeaders As Boolean = True)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hier ist sicher nicht die Rückgabe des geänderten Recordsets geplant.
Von Dir schreibe ich besonders gerne ab.

ebs17, 25. Januar 2011

#17
JOSEF P.

Josef P.

Bei der Collection - eine neue (leere) erzeugt, in der Subprozedur gefüllt - ist das doch gegeben, oder?
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn die neue Referenz zurückgegeben werden soll, muss ByRef verwendet werden.

Hier ist sicher nicht die Rückgabe des geänderten Recordsets geplant.
Von Dir schreibe ich besonders gerne ab.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

... ein schöner Beweis, dass man jeden Code unter die Lupe nehmen sollte.*Smilie
Dieses Code-Beispiel würde ich mittlerweile mit ByVal schreiben.

mfg
Josef

Josef P., 25. Januar 2011

#18
EBS17

ebs17

Anfüge abfrage

Zurück zum eigentlichen Thema. Nachfolgend kommt ein Vorschlag, wie man die erste der in #11 genannten Varianten umsetzen könnte (Suche vorhandener Datensätze über FindFirst und Entscheidung über Edit/AddNew an Hand NoMatch):
Code:

Public Sub Import1()
' FindFirst im Recordset
Dim db As DAO.Database
Dim rsQ As DAO.Recordset
Dim rsZ As DAO.Recordset
Dim colV As VBA.Collection
Dim colS As VBA.Collection
Dim colP As VBA.Collection
Dim colC As VBA.Collection
Dim lVID As Long, lSID As Long, lPID As Long, lCID As Long

Set db = CurrentDb
db.Execute "INSERT INTO Vertriebsbereich (Vertriebsbereich) SELECT Q.Vertriebsbereich" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Vertriebsbereich Z" & _
" WHERE Z.Vertriebsbereich = Q.Vertriebsbereich)", dbFailOnError
db.Execute "INSERT INTO [Sales Manager] (Name) SELECT Q.Salesmanager" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [Sales Manager] Z" & _
" WHERE Z.Name = Q.Salesmanager)", dbFailOnError
db.Execute "INSERT INTO Projekt ([Projekt Kürzel]) SELECT Q.Projekt" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Projekt Z" & _
" WHERE Z.[Projekt Kürzel] = Q.Projekt)", dbFailOnError
db.Execute "INSERT INTO Customer ([Customer No], [Customer Name])" & _
" SELECT Q.[Customer No], Q.[Customer Name]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Customer Z" & _
" WHERE Z.[Customer Name] = Q.[Customer Name])", dbFailOnError
Set colV = New VBA.Collection
FillCollection colV, db, _
"SELECT [Vertriebsbereich ID], Vertriebsbereich FROM Vertriebsbereich"
Set colS = New VBA.Collection
FillCollection colS, db, _
"SELECT [Sales Manager ID], Name FROM [Sales Manager]"
Set colP = New VBA.Collection
FillCollection colP, db, _
"SELECT [Projekt ID], [Projekt Kürzel] FROM Projekt"
Set colC = New VBA.Collection
FillCollection colC, db, _
"SELECT [Customer ID], [Customer Name] FROM Customer"

Set rsZ = db.OpenRecordset("Kundenprojekt", dbOpenDynaset)
Set rsQ = db.OpenRecordset("Import", dbOpenSnapshot)
With rsQ
Do While Not .EOF
'Zwischenspeicherung in Variablen, weil mehrfache Verwendung
lCID = colC.Item(.Fields(2))
lPID = colP.Item(.Fields(4))
lVID = colV.Item(.Fields(6))
lSID = colS.Item(.Fields(5))
If Not rsZ.EOF Then rsZ.MoveLast ' Recordset auffüllen
If rsZ.EOF Then ' Tabelle noch leer
rsZ.AddNew
rsZ("Customer ID") = lCID
rsZ("Projekt ID") = lPID
rsZ("Vertriebsbereich ID") = lVID
rsZ("Sales Manager ID") = lSID
Else
rsZ.FindFirst "[Customer ID] = " & lCID & " AND [Projekt ID] = " & lPID & _
" AND [Vertriebsbereich ID] = " & lVID & " AND [Sales Manager ID] = " & lSID
If rsZ.NoMatch Then
rsZ.AddNew
rsZ("Customer ID") = lCID
rsZ("Projekt ID") = lPID
rsZ("Vertriebsbereich ID") = lVID
rsZ("Sales Manager ID") = lSID
Else
rsZ.Edit
End If
End If
' weitere Felder füllen/überschreiben
rsZ("description of product/solution") = Now ' Testfeld füllen
rsZ.Update
.MoveNext
Loop
.Close
End With
rsZ.Close

Set rsZ = Nothing
Set rsQ = Nothing
Set colV = Nothing
Set colS = Nothing
Set colP = Nothing
Set colC = Nothing
Set db = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 25. Januar 2011

#19
MARKDERNOOB

MarkderNoob

Optimal... Vielen lieben Dank an der Stelle. Danke für die Hilfe

MarkderNoob, 25. Januar 2011

#20
EBS17

ebs17

Code:

' weitere Felder füllen/überschreiben
rsZ("description of product/solution") = Now ' Testfeld füllen
rsZ("description of product/solution") = .Fields("FeldAusImport")
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Verwendung von Now auf ein Feld war nur eine Abkürzung für den funktionalen Test. Deine vielen Felder mit langen Namen vollständig aufzulisten überlasse ich Dir, das war mir zu anstrengend.
Du musst natürlich immer dem Feld der Zieltabelle das passende Feld der Quelltabelle gegenüberstellen, wie ich das sinnbildlich mit der zweiten Zeile gezeigt habe.

ebs17, 26. Januar 2011

#21
MARKDERNOOB

MarkderNoob

Sorry das ich so voreilig war.. Habe den Code erstmal versucht zu verstehen. Hat nach voreiligem Hilferuf dann doch noch geklappt und die Aktualisierungs-/Anfügeabfrage funktioniert tadellos.

MarkderNoob, 26. Januar 2011

#22
MARKDERNOOB

MarkderNoob

Anfüge abfrage

Es wurden weitere Tabellen gewünscht, so dass bei einer Formulareingabe Werte vordefiniert sind. Habe die 3 Tabellen versucht in die Importfunktion einzubauen. Bekomme einen Syntaxfehler in der INSERT INTO Anweisung. Nach fast 1 Stunde suchen habe ich immernoch nichts gefunden

Tabellennamen und Felder sind richtig geschrieben (auch bei Leerzeichen eingeklammert)

Kann bitte mal jmd drüber schauen? Vielleicht sieht ein professionelles Auge so einen Fehler eher als meins

Code:

Set db = CurrentDb
db.Execute "INSERT INTO Vertriebsbereich (Vertriebsbereich) SELECT Q.Vertriebsbereich" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Vertriebsbereich Z" & _
" WHERE Z.Vertriebsbereich = Q.Vertriebsbereich)", dbFailOnError
db.Execute "INSERT INTO [Sales Manager] (Name) SELECT Q.Salesmanager" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [Sales Manager] Z" & _
" WHERE Z.Name = Q.Salesmanager)", dbFailOnError
db.Execute "INSERT INTO Projekt ([Projekt Kürzel]) SELECT Q.Projekt" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Projekt Z" & _
" WHERE Z.[Projekt Kürzel] = Q.Projekt)", dbFailOnError
db.Execute "INSERT INTO Customer ([Customer No], [Customer Name])" & _
" SELECT Q.[Customer No], Q.[Customer Name]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Customer Z" & _
" WHERE Z.[Customer Name] = Q.[Customer Name])", dbFailOnError
db.Execute "INSERT INTO [CRM Status] ([CRM Status]) SELECT Q.[CRM Status]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [CRM Status] Z" & _
" WHERE Z.[CRM Status] = Q.[CRM Status])", dbFailOnError
db.Execute "INSERT INTO WinLossReason (Win-/Loss-Reason) SELECT Q.Win-/Loss-Reason" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM WinLossReason Z" & _
" WHERE Z.Win-/Loss-Reason = Q.Win-/Loss-Reason)", dbFailOnError
db.Execute "INSERT INTO Segment (Segment) SELECT Q.Segment" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Segment Z" & _
" WHERE Z.Segment = Q.Segment)", dbFailOnError
db.Execute "INSERT INTO PresalesManager (PresalesManagerName) SELECT Q.PresalesManager" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM PresalesManager Z" & _
" WHERE Z.PresalesManagerName = Q.PresalesManager)", dbFailOnError
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

MarkderNoob, 26. Januar 2011

#23
EBS17

ebs17

Nicht nur nebenbei: Bei Deinen "eckigen" Bezeichnungen (Leer- und Sonderzeichen) musst Du eckige Klammern verwenden.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Diesen Hinweis hattest Du schon ganz oben erhalten (#3), und der gilt immer noch.

ebs17, 26. Januar 2011

#24
MARKDERNOOB

MarkderNoob

Habe nur auf Leerzeichen geachtet *Smilie Danke

Bekomme jetzt einen Laufzeitfehler13 Typen unverträglich

Code:

Private Sub FillCollection(ByVal col As Object, ByVal dbs As Object, ByVal SQL As String)
Dim rs As DAO.Recordset
Set rs = dbs.OpenRecordset(SQL, dbOpenSnapshot)
With rs
Do While Not .EOF
col.Add .Fields(0).Value, .Fields(1).Value
.MoveNext
Loop
.Close
End With
Set rs = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Fields(0).Value=338, Fields(1).Value=Null -- beim debuggen

Welche Felder sind damit gemeint??

MarkderNoob, 26. Januar 2011

#25
EBS17

ebs17

Code:

With rs
Do While Not .EOF
col.Add .Fields(0).Value, .Fields(1).Value
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das Feld bezieht sich auf das Recordsetobjekt, und dieses bezieht seine Werte aus der Abfrage, aus der das Recordsetobjekt erzeugt wird. Also musst Du letzten Endes überprüfen, welche Werte die zugrunde liegende Tabelle enthält.

ich vermute mal, dass das Problem bei einer zum eigentlichen Vorschlag angefügten Tabelle besteht. Also müsstest Du vergleichen, was Du anders machst.

ebs17, 26. Januar 2011

#26
MARKDERNOOB

MarkderNoob

Zunächst einmal möchte ich mich entschuldigen dass ich hier schon wieder den gesamten Code einfüge, aber ich hoffe dass mir so jemand helfen kann.. Über die Prozedur werden in sämtlichen tabellen nur neue Daten übernommen, bzw. alte geändert.

Bis auf Customer.. Die Kunden werden doppelt eingespielt (obwohl selber Name und selbe Kundennummer) woraufhin ein Fehler in der Fill Collection entsteht..

Habe jetzt seit geschlagenen 2 Stunden versucht den Fehler ausfindig zu machen (leider ohne erfolg) ich hoffe ein fachmännisches Auge kann mir helfen

Code:

Private Sub Importieren()

Dim db As DAO.Database
Dim rsQ As DAO.Recordset
Dim rsZ As DAO.Recordset
Dim colV As VBA.Collection
Dim colS As VBA.Collection
Dim colP As VBA.Collection
Dim colC As VBA.Collection
Dim colM As VBA.Collection
Dim colW As VBA.Collection
Dim lVID As Long, lSID As Long, lPID As Long, lCID As Long, lWID As Long, lMID As Long

Set db = CurrentDb
db.Execute "INSERT INTO Vertriebsbereich (Vertriebsbereich) SELECT Q.Vertriebsbereich" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Vertriebsbereich Z" & _
" WHERE Z.Vertriebsbereich = Q.Vertriebsbereich)", dbFailOnError
db.Execute "INSERT INTO [Sales Manager] (Name) SELECT Q.SM" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [Sales Manager] Z" & _
" WHERE Z.Name = Q.SM)", dbFailOnError
db.Execute "INSERT INTO Projekt ([Projekt Kürzel]) SELECT Q.Projekt" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Projekt Z" & _
" WHERE Z.[Projekt Kürzel] = Q.Projekt)", dbFailOnError
db.Execute "INSERT INTO Customer ([Customer No], [Customer Name])" & _
" SELECT Q.[Customer No], Q.[Customer Name]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Customer Z" & _
" WHERE Z.[Customer Name] = Q.[Customer Name] AND Z.[Customer No] = Q.[Customer No])", dbFailOnError
db.Execute "INSERT INTO [CRM Status] ([CRM Status]) SELECT Q.[CRM Status]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [CRM Status] Z" & _
" WHERE Z.[CRM Status] = Q.[CRM Status])", dbFailOnError
db.Execute "INSERT INTO WinLossReason ([Win-/Loss-Reason]) SELECT Q.[Win-/Loss-Reason]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM WinLossReason Z" & _
" WHERE Z.[Win-/Loss-Reason] = Q.[Win-/Loss-Reason])", dbFailOnError

Set colV = New VBA.Collection
FillCollection colV, db, _
"SELECT [Vertriebsbereich ID], Vertriebsbereich FROM Vertriebsbereich"
Set colS = New VBA.Collection
FillCollection colS, db, _
"SELECT [Sales Manager ID], Name FROM [Sales Manager]"
Set colP = New VBA.Collection
FillCollection colP, db, _
"SELECT [Projekt ID], [Projekt Kürzel] FROM Projekt"
Set colC = New VBA.Collection
FillCollection colC, db, _
"SELECT [Customer ID], [Customer Name], [Customer No] FROM Customer"
Set colW = New VBA.Collection
FillCollection colW, db, _
"SELECT [CRM ID], [CRM Status] FROM [CRM Status]"
Set colM = New VBA.Collection
FillCollection colM, db, _
"SELECT [WinLoss_ID], [Win-/Loss-Reason] FROM WinLossReason"

Set rsZ = db.OpenRecordset("Kundenprojekt", dbOpenDynaset)
Set rsQ = db.OpenRecordset("Import", dbOpenSnapshot)
With rsQ
Do While Not .EOF
'Zwischenspeicherung in Variablen, weil mehrfache Verwendung
lCID = colC.Item(.Fields(2))
lPID = colP.Item(.Fields(4))
lVID = colV.Item(.Fields(6))
lSID = colS.Item(.Fields(5))
lWID = colW.Item(.Fields(16))
lMID = colM.Item(.Fields(22))
If Not rsZ.EOF Then rsZ.MoveLast ' Recordset auffüllen
If rsZ.EOF Then ' Tabelle noch leer
rsZ.AddNew
rsZ("Customer ID") = lCID
rsZ("Projekt ID") = lPID
rsZ("Vertriebsbereich ID") = lVID
rsZ("Sales Manager ID") = lSID
rsZ("CRM ID") = lWID
rsZ("WinLoss_ID") = lMID

Else
rsZ.FindFirst "[Customer ID] = " & lCID & " AND [Projekt ID] = " & lPID & _
" AND [Vertriebsbereich ID] = " & lVID & " AND [Sales Manager ID] = " & lSID & " AND [CRM ID] = " & lWID & " AND [WinLoss_ID] = " & lMID & " "
If rsZ.NoMatch Then
rsZ.AddNew
rsZ("Customer ID") = lCID
rsZ("Projekt ID") = lPID
rsZ("Vertriebsbereich ID") = lVID
rsZ("Sales Manager ID") = lSID
rsZ("CRM ID") = lWID
rsZ("WinLoss_ID") = lMID
Else
rsZ.Edit
End If
End If
' weitere Felder füllen/überschreiben
rsZ("description of product/solution") = rsQ("description of product/solution")
rsZ("decision date") = rsQ("decision date")
rsZ("contract duration") = rsQ("contract duration")
rsZ("real A") = rsQ("real A")
rsZ("IBS/AGB") = rsQ("IBS/AGB")
rsZ("CVS") = rsQ("CVS")
rsZ("additional turnover") = rsQ("additional turnover")
rsZ("additional turnover weighted") = rsQ("additional turnover weighted")
rsZ("Expected Order Entry Total") = rsQ("Expected Order Entry Total")
rsZ("Prob %") = rsQ("Prob %")
rsZ("Expected OE weighted") = rsQ("Expected OE weighted")
rsZ("Status of Prospect") = rsQ("Status of Prospect")
rsZ("last verify") = rsQ("last verify")
rsZ("Shared Cost 0180") = rsQ("Shared Cost 0180")
rsZ("Freecall 0800/00800") = rsQ("Freecall 0800/00800")
rsZ("TWK") = rsQ("TWK")
rsZ("TVC 0137") = rsQ("TVC 0137")
rsZ("CVS") = rsQ("CVS")
rsZ("other (auch PRS 0900)") = rsQ("other (auch PRS 0900)")
rsZ("Carrier actual") = rsQ("Carrier actual")
rsZ("IAM Project No") = rsQ("IAM Project No")
rsZ("Begründung") = rsQ("Begründung")
rsZ("Segment") = rsQ("Segment")
rsZ.Update
.MoveNext
Loop
.Close
End With
rsZ.Close

Set rsZ = Nothing
Set rsQ = Nothing
Set colV = Nothing
Set colS = Nothing
Set colP = Nothing
Set colC = Nothing
Set colW = Nothing
Set colM = Nothing
Set db = Nothing

End Sub

Private Sub FillCollection(ByVal col As Object, ByVal dbs As Object, ByVal SQL As String)
Dim rs As DAO.Recordset
Set rs = dbs.OpenRecordset(SQL, dbOpenSnapshot)
With rs
Do While Not .EOF
col.Add .Fields(0).Value, .Fields(1).Value
.MoveNext
Loop
.Close
End With
Set rs = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

MarkderNoob, 7. Februar 2011

#27
MARKDERNOOB

MarkderNoob

Anfüge abfrage

Ich komme einfach nicht auf den Fehler..

Wieso werden die Customer nicht erkannt? Kunde als auch Kundennummer sind identisch und er fügt den Kunden trotzdem neu hinzu..

Dadurch der Fehler in der FillCOllection. Falls jemand weiß woran es liegen könnte würde ich mich über einen Hinweis freuen..

Code:

Set db = CurrentDb
db.Execute "INSERT INTO Vertriebsbereich (Vertriebsbereich) SELECT Q.Vertriebsbereich" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Vertriebsbereich Z" & _
" WHERE Z.Vertriebsbereich = Q.Vertriebsbereich)", dbFailOnError
db.Execute "INSERT INTO [Sales Manager] (Name) SELECT Q.SM" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [Sales Manager] Z" & _
" WHERE Z.Name = Q.SM)", dbFailOnError
db.Execute "INSERT INTO Projekt ([Projekt Kürzel]) SELECT Q.Projekt" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Projekt Z" & _
" WHERE Z.[Projekt Kürzel] = Q.Projekt)", dbFailOnError
db.Execute "INSERT INTO Customer ([Customer No], [Customer Name])" & _
" SELECT Q.[Customer No], Q.[Customer Name]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM Customer Z" & _
" WHERE Z.[Customer Name] = Q.[Customer Name])", dbFailOnError
db.Execute "INSERT INTO [CRM Status] ([CRM Status]) SELECT Q.[CRM Status]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM [CRM Status] Z" & _
" WHERE Z.[CRM Status] = Q.[CRM Status])", dbFailOnError
db.Execute "INSERT INTO WinLossReason ([Win-/Loss-Reason]) SELECT Q.[Win-/Loss-Reason]" & _
" FROM Import Q WHERE NOT EXISTS (SELECT NULL FROM WinLossReason Z" & _
" WHERE Z.[Win-/Loss-Reason] = Q.[Win-/Loss-Reason])", dbFailOnError
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Selectabfrage vielleicht fehlerhaft???

MarkderNoob, 8. Februar 2011

#28
ATRUS2711

Atrus2711

Hi,

ich kenne ja die Daten nicht, aber die Customers sind die einzigen, bei denen Nummer und Name verglichen werden. Als "bekannt" werden also nur die erkannt, wo Nummer und Name zum Vergleichsssatz passen.

Ein Altkunde 4711/Atrus wird also nicht als vorhanden erkannt, wenn ein neuer Satz 4711/Altrus oder ein neuer Satz 4712/Atrus daherkommen.

Atrus2711, 8. Februar 2011

#29
MARKDERNOOB

MarkderNoob

Kundennummer als auch Name sind identisch. Es gibt keinerlei Unterschied.. Trotzdem wird der Kunde neu hinzugefügt

Alle anderen Daten werden erkannt..

Liegt der Fehler in der Selectabfrage für Customer?

MarkderNoob, 8. Februar 2011

#30

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 2 von 5

Thema:

Anfüge abfrage

Die Seite wird geladen...

Anfüge abfrage - Similar Threads - Anfüge abfrage
Beim Import von Exceldatei Spalte hinzufügen und füllen
in Microsoft Access Hilfe
Beim Import von Exceldatei Spalte hinzufügen und füllen: Guten Morgen, ich bin noch recht neu in der Materie. Ich habe mehrere Dateien gleicher Struktur, die automatisiert importiert werden. Um diese später mit einer UNION-Abfrage weiter zu bearbeiten...
Kann keine Attachments anfügen
in Microsoft Outlook Hilfe
Kann keine Attachments anfügen: Wenn ich in einer Mail eine Datei anhängen will, bekomme ich die Meldung "Array Index außerhalb des gültigen Bereichs".
Bestimmte Daten zwischen innerhalb eines Datumsbereichs einer Tabelle Anfügen
in Microsoft Access Hilfe
Bestimmte Daten zwischen innerhalb eines Datumsbereichs einer Tabelle Anfügen: Hallo, ich habe per Google und Foren SuFu leider nichts passendes finden können, wage aber zu bezweifeln, dass Access da an seine Grenzen kommt, da es eigentlich recht banal ist. Ich habe eine...
Anfügen von Abfragen (Power Query)
in Microsoft Excel Tutorials
Anfügen von Abfragen (Power Query): Anfügen von Abfragen (Power Query) Excel für Microsoft 365 Excel 2019 Excel 2016 Excel 2013 Excel 2010 Mehr... Weniger...
Komplizierte Anfüge Abfrage
in Microsoft Access Hilfe
Komplizierte Anfüge Abfrage: Hallo, ich habe ein problem bei dem ich einfach keine Lösung finde. Ich hoffe ihr könnt mir helfen. *Smilie Ich habe eine beispiel DB angehangen, an der ich mein Problem schildere!...
Anfügen einer vCard an eine E-Mail-Nachricht
in Microsoft Outlook Tutorials
Anfügen einer vCard an eine E-Mail-Nachricht: Anfügen einer vCard an eine E-Mail-Nachricht Outlook für Microsoft 365 Outlook 2019 Outlook 2016 Outlook 2013 Mehr... Weniger...
Anfügen-Abfrage an Zieltabelle mit Passwortschutz
in Microsoft Access Hilfe
Anfügen-Abfrage an Zieltabelle mit Passwortschutz: Hallo zusammen, ich möchte Datensätze in einer DB (Frontend) eingeben und per Anfügen-Abfrage an eine Tabelle einer Passwortgeschützten Backend DB übergeben. Wie kann ich das Passwort beim...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden