Office: (Office 2013) Anwesenheit in Zeitraum prüfen und zählen

Hi,

bräuchte da mal eure Hilfe. Habe eine Tabelle mit Anreisedatum in Spalte A; Abreisedatum in Spalte B. In den folgenden Spalten stehen weitere Infos zu den Gästen.

Nun soll geschaut werden wie viele Gäste am Tag anwesend sind.

 

Hallo!

=SUMMENPRODUKT((A$2:A$999<=G2)*(B$2:B$999>=G2))

 

Vielen Dank für die Rasche Antwort!
Leider bekomme ich nur "0" als Rückmeldung.

Ich versuche mein Problem mal anders zu beschreiben.
Als Grundlage habe ich Zeiträume (Anfang Spalte A - Ende Spalte B). Daraus benötige ich für einzelne Tage die Anzahl der anwesenden Gäste.

Es müsste also geprüft werden ob das Datum in Spalte G im Zeitraum von Spalte A und B liegt und diese Zeilen zählen.

 

Hallo!

Ich habe sehr wohl verstanden, was du möchtest. ;)

	A	B	C	D	E	F	G	H
1	Beginn	Ende					Tag	Anwesend
2	25.06.2015	12.07.2015					01.07.2015	3
3	25.06.2015	12.07.2015					25.06.2015	2
4	26.06.2015	20.07.2015					26.06.2015	4
5	26.06.2015	27.06.2015					19.07.2015	1

<br />

Formeln der Tabelle[parsehtml]

Zelle	Formel
H2	=SUMMENPRODUKT((A$2:A$999<=G2)*(B$2:B$999>=G2))
H3	=SUMMENPRODUKT((A$2:A$999<=G3)*(B$2:B$999>=G3))
H4	=SUMMENPRODUKT((A$2:A$999<=G4)*(B$2:B$999>=G4))
H5	=SUMMENPRODUKT((A$2:A$999<=G5)*(B$2:B$999>=G5))

</td></tr></table>[/parsehtml] <br /><br /><span style="font-family:Arial; font-size:9pt; font-weight:bold;background-color:#ffffff; color:#000000; ">Excel Tabellen im Web darstellen &gt;&gt; </span><a style ="font-family:Arial; font-size:9pt; color:#fcf507; background-color:#800040; font-weight:bold;" href="http://www.excel-jeanie-html.de" target="_blank"> Excel Jeanie HTML 4.8 </a>


Wenn die Formel bei dir nur "0" ausgibt, dann liegt das nicht an der Formel, sondern an deinen Daten!
Möglicherweise, bzw. höchstwahrscheinlich liegen einige deine Datumswerte als Text vor und nicht als Zahl.
Mit der Funktion ISTTEXT bzw. ISTZAHL solltest du das bei deinen Originaldaten mal checken.

 

*hmpf* Problem beseitigt, wie von dir beschrieben - es funktioniert :-)

Vielen Dank!

 

Hallo,

kann man die Formel auch dahingehend erweitern das in Abhängigkeit zu Spalte E bedingt gezählt wird?

In Spalte E haben wir unseren Buchungstext stehen aus dem hervorgeht wie viele Gäste zu der Buchung gehören.
Es müsste zu der Prüfung des Zeitraums dann noch geschaut werden ob ein "&" in Spalte E (an beliebiger Position) vorhanden ist und in dem Fall für diese Buchung mit zwei Gästen summiert werden.

 

Hola,

ungetestet:

Code:

=SUMMENPRODUKT((A$2:A$999<=G2)*(B$2:B$999>=G2)*(ISTZAHL(SUCHEN("&";$E$2:$E$999))))

Gruß,
steve1da

 

Hallo!

Ja, das geht:

	A	B	C	D	E	F	G	H
1	Beginn	Ende					Tag	Anwesend
2	25.06.2015	12.07.2015			abc&xyz		01.07.2015	6
3	25.06.2015	12.07.2015					25.06.2015	3
4	26.06.2015	20.07.2015			xxx&yyy&zzz		26.06.2015	7
5	26.06.2015	27.06.2015					19.07.2015	3

<br />

Formeln der Tabelle[parsehtml]

Zelle	Formel
H2	=SUMMENPRODUKT((A$2:A$999<=G2)*(B$2:B$999>=G2)*(1+LÄNGE(E$2:E$999)-LÄNGE(WECHSELN(E$2:E$999;"&";))))
H3	=SUMMENPRODUKT((A$2:A$999<=G3)*(B$2:B$999>=G3)*(1+LÄNGE(E$2:E$999)-LÄNGE(WECHSELN(E$2:E$999;"&";))))
H4	=SUMMENPRODUKT((A$2:A$999<=G4)*(B$2:B$999>=G4)*(1+LÄNGE(E$2:E$999)-LÄNGE(WECHSELN(E$2:E$999;"&";))))
H5	=SUMMENPRODUKT((A$2:A$999<=G5)*(B$2:B$999>=G5)*(1+LÄNGE(E$2:E$999)-LÄNGE(WECHSELN(E$2:E$999;"&";))))

</td></tr></table>[/parsehtml] <br /><br /><span style="font-family:Arial; font-size:9pt; font-weight:bold;background-color:#ffffff; color:#000000; ">Excel Tabellen im Web darstellen &gt;&gt; </span><a style ="font-family:Arial; font-size:9pt; color:#fcf507; background-color:#800040; font-weight:bold;" href="http://www.excel-jeanie-html.de" target="_blank"> Excel Jeanie HTML 4.8 </a>

@steve1da: Genau das dachte ich auch zuerst... ;)

 

Hi,

wenn ich das richtig verstehe/sehe zählt diese Formel die Anzahl der Buchungen bei denen mehrere Gäste an dem Tag da sind. Summiert mit der Anzahl Buchungen aus der vorhergehenden Formel erhalte ich somit die Gesamtzahl Gäste.

Super und noch einmal vielen Dank!

 

Hola,

@Schatzi: aber deine Formel ergibt doch jetzt viel mehr Tage, obwohl ein Einschränkungskriterium hinzugekommen ist ;)

Gruß,
steve1da

 

Hallo Steve!

Lies dir #6 nochmal genau durch.
Wenn ich es richtig verstanden habe, dann

- soll die Formel "1" addieren, wenn in Spalte E z.B. "Anna" steht
- soll die Formel "2" addieren, wenn in Spalte E z.B. "Anna&Berta" steht
- soll die Formel "3" addieren, wenn in Spalte E z.B. "Anna&Berta&Carla" steht
usw.

Wenn ich falsch liegen sollte, dann bitte korrigieren!

 

Hola,

verdammt, du hast Recht - glatt überlesen :D

War ein langer Tag heute :)

Gruß,
steve1da

 

Hallo,

dieser Beitrag war schon sehr hilfreich für mich. Allerdings muss ich noch zusätzliche Spalten zählen.
Ich muss separat sehen können wie viele Wohnmobile, Wohnwagen, Zelte und PKWs an dem ausgewählten Datum auf dem Platz sind.

Ich habe bisher nur die Formel zur allgemeinen Anwesenheit anwenden können:
=SUMMENPRODUKT((A$2:A$999<=I2)*(B$2:B$999>=I2))

Kann mir da jemand weiter helfen ?

 

=SUMMENPRODUKT(($A$2:$A$999<=$I2)*($B$2:$B$999>=$I2)*($D$1:$G$1=J$1)*($D$2:$G$999>0))

 

Vielen Dank für die schnelle Antwort. Ich habe noch ein kleines Verständnisproblem damit. Ich brauche doch für jedes Feld eine separate Formel oder nicht ? Wohnmobile, Wohnwagen Zelte Pkws. Mit der jetzigen Formel zählt er nur die Wohnmobile und das stimmt auch nicht mit dem richtigen Ergebnis überein.