Office: (Office 2007) Anzahl der erfassten Tage pro Monat

Hallo,
ich habe eine Tabelle (Excel XP) mit folgenden für mein Problem relevanten Spalten:
C:C = Arbeitende Person
G:G = Datum Arbeitstag
H:H = Monat in dem der Tag liegt
In dem Sheet erfasse ich die Arbeiten aus den abgegebenen Stundenzetteln. D.h. ein Tag kann auch in mehreren Zeilen erscheinen, da an diesem Tag verschiedene Arbeiten gemacht wurden. Leider sind manche Mitarbeiter schlampig im Abgeben der Stundenzettel, was sich negativ auf deren Arbeitskonto auswirkt. Um die Überstunden zu erfassen möchte ich Bezug nehmen auf die Anzahl der erfassten Tage/Monat und nicht auf die Arbeitstage/Monat (sonst hätte mancher nur Fehlstunden *wink.gif* ).
Mit welcher Formel kann ich XL die Anzahl der erfassten Tage pro Monat zählen lassen? Ich komme da selber leider nicht mehr weiter *frown.gif*
Für Hilfe wäre ich sehr dankbar.
Gruß
Andreas

:)

 

Hallöchen!

Die allerletzte Formel dieser Seite müsste deine Lösung sein.

 

Hallo,
danke für deine Antwort. Ich denke die von dir vorgschlagene Formel passt nicht. Ich habe in der Spalte G ja nicht ein bestimmtes Kriterium welches ich Zählen will sondern verschiedene Monatsdatumsangaben. Z.B. 01.02.2007 / 02.02.2007/ 03.02.2007/ 03.02.2007 / 05.04.2007 /... Nun sollen alle Tage des februar gezählt werden. Die richtige Antwort wäre 3. Und das dann noch verknüpft mit den verschiedenen Mitarbeitern.
Ich hoffe das War verständlich.
Gruß und Danke
Andreas

 

Hallöchen!

Ja, genauso habe ich deine Anfrage auch verstanden und dich daher auf diese Seite verwiesen. Die Formel passt prima:

	A	B	C	D	E
1	01.02.2007	Müller		Name:	Müller
2	02.02.2007	Müller		Monat:	2
3	03.02.2007	Müller
4	03.02.2007	Müller		Tage:	3
5	05.02.2007	Meier
6	06.02.2007	Meier
7
8
9
10

Zelle	Formel
E4	{=SUMME(N(WENN((B1:B100=E1)*(MONAT(A1:A100)=E2);VERGLEICH(WENN((B1:B100=E1)*(MONAT(A1:A100)=E2);A1:A100);WENN((B1:B100=E1)*(MONAT(A1:A100)=E2);A1:A100)=ZEILE(1:100))))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen! Excel Jeanie HTML 4

 

Hallo Andreas,

wenn ich es richtig sehe, dann müßte es auch so klappen:

	A	B	C	D
1	Datum	MA
2	01.02.2007	A	Monat	Feb
3	04.02.2007	B	MA	A
4	08.02.2007	A	Anzahl	2
5	02.03.2007	B
6	03.03.2007	A
7	04.03.2007	B

Zelle	Formel
D4	=SUMMENPRODUKT(((TEXT(A2:A7;"MMM"))=D2)*(B2:B7=D3))

Excel Tabellen im Web darstellen >>

 

Hallöchen!

Myfake, wenn dem so ist, dann ist deine Formel natürlich super.
Ich habe es allerdings so verstanden, dass mehrfach auftretende Datümer nur einfach gezählt werden sollen. Da würde deine Formel (angewandt auf mein Beispiel) als Ergebnis "4" auswerfen.
Abschliessend kann das aber nur Andreas selbst beantworten.

 

Hallo,
also habe leider gerade keine Zeit. Schonmal Danke für die Mühe. KarlKatusche hat Recht, eine Datumsangabe soll auch bei Mehrfachnennung nur einmal gezählt werden.
Werde die Formeln zeitnah eingeben (wenn ich sie verstehe *Smilie ).
Also schonmal vielen Dank für die Mühe
Andreas

 

Ich muss hier das Thema nochmal aufwärmen, weil mein Problem sehr ähnlich ist, ich aber trotzdem mit der Lösung nicht klarkomme!

Ich habe eine Auflistung von Datumseinträgen (wie oben beschrieben), jedoch ohne Mitarbeiter. Ich möchte jetzt die Anzahl der Tage haben, die im Monat August, September, Oktober... liegen. Und zwar JEDER Eintrag. Wenn also der 21.09. 5 mal vorkommt, soll auch 5x gezählt werden.

Gruß
Stephan

 

Hallo Stephan,

schau mal hier:
Tabelle1

	A	B	C	D
1	Datum		Monat	Anzahl Tage
2	01.09.2009		September	3
3	02.09.2009		Oktober	4
4	10.09.2009		November	5
5	02.10.2009		Dezember	2
6	03.10.2009
7	03.10.2009
8	14.10.2009
9	01.11.2009
10	01.11.2009
11	01.11.2009
12	01.11.2009
13	05.11.2009
14	03.12.2009
15	04.12.2009

Zelle	Formel
D2	=SUMMENPRODUKT((MONAT($A:$A)=MONAT(C2))*1)
D3	=SUMMENPRODUKT((MONAT($A:$A)=MONAT(C3))*1)
D4	=SUMMENPRODUKT((MONAT($A:$A)=MONAT(C4))*1)
D5	=SUMMENPRODUKT((MONAT($A:$A)=MONAT(C5))*1)

Excel Tabellen im Web darstellen >>

 

Hi mücke!

Theoretisch JA. Habs auch mal in meine Tabelle eingebaut,... wohl aber der Wurm drin. Kannst da mal reinschaun?

Danke
Stephan

 

Hi
Ich bekam auch Fehlermeldung. Habs so geloest.

Tabellenblattname: Tabelle1

	A	B	C	D	E
1			2009	<--Jahr
2	01.09.2009		September	Oktober	Dezember
3	02.09.2009		10	4	1
4	03.09.2009
5	04.09.2009
6	05.09.2009
7	01.10.2009
8	02.10.2009
9	03.10.2009
10	04.10.2009
11	12.09.2009
12	13.09.2009
13	14.09.2009
14	15.09.2009
15	16.09.2009
16	01.12.2009
17

Benutzte Formeln:
C3: =SUMMENPRODUKT(((TEXT($A$2:$A$16;"MMMM"))=C2)*((TEXT($A$2:$A$16;"JJJJ")*1)=$C$1))
D3: =SUMMENPRODUKT(((TEXT($A$2:$A$16;"MMMM"))=D2)*((TEXT($A$2:$A$16;"JJJJ")*1)=$C$1))
E3: =SUMMENPRODUKT(((TEXT($A$2:$A$16;"MMMM"))=E2)*((TEXT($A$2:$A$16;"JJJJ")*1)=$C$1))
gruss hary

 

Hallo zusammen,

praktisch funktioniert die Formel auch! *wink.gif*
In meinem Beispiel steht der MONAT in Form von 01.09.2009 in der Zelle und ist als MMMM formatiert.
Sorry für die fehlende Info!

 

OK, jetzt sind wir soweit: Es läuft.

Vielen Dank EUCH!

 

Hallo,

das gleiche Problem habe ich auch.
Habe eine Tabelle mit etlichen Datumswerten; jedes Datum kommt mehrmals vor (SPalte A).
Wie kann ich die Anzahl der Tage ermitteln ohne zusätzlich Bezug auf den Mitarbeiter zu nehmen, wie hier angegeben:

Habe versucht, die Formel umzustellen, aber ohne Erfolg.

 

Moin
Meinst so? Tage nur einmal zaehlen?


Tabelle1

	A	B	C	D	E
1	01.06.2014		6	Juni
2	02.06.2014		8	8	<--Tage
3	03.06.2014
4	04.06.2014
5	03.06.2014
6	06.06.2014
7	03.06.2014
8	08.06.2014
9	03.06.2014
10	10.06.2014
11	11.06.2014
12	12.07.2014

verwendete Formeln
Zelle	Formel	Bereich	R1C1 für Add In
C2	{=SUMME((VERGLEICH(A1:A12;A1:A12;0)=ZEILE(1:12)*(MONAT(A1:A12)=C1))*1)}	$C	=SUM((MATCH(R[-1]C[-2]:R[10]C[-2],R[-1]C[-2]:R[10]C[-2],0)=ROW(R[-1]:R[10])*(MONTH(R[-1]C[-2]:R[10]C[-2])=R[-1]C))*1)
D2	{=SUMME((VERGLEICH(A1:A12;A1:A12;0)=ZEILE(1:12)*(TEXT(A1:A12;"MMMM")=D1))*1)}	$D	=SUM((MATCH(R[-1]C[-3]:R[10]C[-3],R[-1]C[-3]:R[10]C[-3],0)=ROW(R[-1]:R[10])*(TEXT(R[-1]C[-3]:R[10]C[-3],"MMMM")=R[-1]C))*1)

{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Tools Tabelle Forum - Hajo's Excelseiten
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007
Add-In-Version 14.02 einschl 64 Bit

gruss hary