Office: Anzahl mit Bedingung

Hallo,

über die Suchfunktion kam ich leider nicht weiter. Ich habe folgendes Problem:
In Spalte A habe ich mehrere Werte, die sich auch wiederholen und in Spalte B auch mehrere Werte:
1 250
2 150
1 600
4 400
3 240
2 142
3 800
1 485
Ich möchte nun die Anzahl der unterschiedlichen Werte im Bereich der Spalte A, mit der Bedingung dass der Bereich im Spalte B zwischen 0 und 500 sein sollte. Hier 4
wie kann ich das lösen. mit Anzahlwenn komm ich nicht weiter, das würde ja so aussehen: =anzahlwenn(A1:A10;B1:B10<="500") ???????

Danke für jeden Tipp,
Gruß

 

Wie wär's mit einer Hilfsspalte C, in der mit einer einfach WENN-Formel zuerst einmal bestimmt wird, ob der Wert zwischen (inklusive?) 0 und 500 liegt?
C1: =wenn(und(b1>=0;b1<=500);a1;"")
Damit wäre die erste Bedingung schonmal abgefrühstückt.

Jetzt soll das Ding nur in die Zählung kommen, wenn der Wert aus A nicht vorher schon einmal aufgetaucht ist. Verstehe ich das richtig? Also in Deinem Beispiel die "1" in der letzten Zeile wird nicht gezählt, weil die "1" in der ersten Zeile schon auftaucht. Die in der 3. Zeile wird eh nicht berücksichtigt, weil der Bereich 0..500 nicht paßt?

Ich würd mal in D sowas aufbauen:
D1: =c1
D2: =wenn(zählenwenn(c$1:c1;c2)>0;"";c2)
Damit haste dann in D jeden Wert, der auftauchen darf, immer nur 1x stehen.

Den kannste dann mit ANZAHL zählen lassen, sofern Du die Formeln in C1 und D2 entsprechend weit heruntergezogen hast:
D10: =anzahl(d1:d8)

Das ganze jetzt wieder zu optimieren und in eine Formel zusammenzuzpacken...

Gruß, Michael

 

Hallo,

teste mal die folgende Formel wobei ich hier davon ausgehe, dass die Werte in A1 bis B8 stehen:

=SUMME(N(WENN((B1:B8>0)*(B1:B8<500>0)*(B1:B8<500>0)*(B1:B8<500);A1:A8);)=ZEILE(1:8))))

Die Formel musst du mit Strg-Shift-Enter abschließen.

 

Hallo!

Ich hätte auch noch eine Matrixformel anzubieten.
In Zelle C1:

=WENN(ZÄHLENWENN(A$1:A1;A1)=1;SUMME((A1=A$1:A$100)*(B$1:B$100<=500)*(B$1:B$100>=0));"")

Eingabe mit Strg + Shift + Enter abschließen und nach unten kopieren.

P. S.: Diese Formel bringt leider eine 0 (Null), wenn ein Element in Spalte A nur einmal vorkommt und rechts davon eine Zahl >500 steht. Das Problem habe ich noch nicht lösen können.

 

Hallo Krino,

ist da etwas schief gegangen beim Posten, denn das B$1:B$100<500>=0 sieht etwas seltsam aus.

 

Hallo Peter!

Stimmt. Bei Dir ist glaube ich das Gleiche passiert. ;-)
Man muß "HTML in diesem Beitrag deaktivieren" (Häkchen setzen) - weil die Software sich sonst an den Ungleich-Zeichen verschluckt.

 

Hallo,

danke das ist mir gar nicht aufgefallen.

Dann versuchen wir es nochmal:

=SUMME(N(WENN((B1:B8>0)*(B1:B8<500);VERGLEICH(WENN((B1:B8>0)*(B1:B8<500);A1:A8);WENN((B1:B8>0)*(B1:B8<500);A1:A8);)=ZEILE(1:8))))

und mit Strg-Shift-Enter abschließen.

 

Hey Peter,

vielen Dank. Es scheint tatsächlich zu funktionieren.
ich weiß zwar nicht, wieso und was die Formel zu bedeuten hat, aber es tut.

Riesen dankeschön für eure tipps