Office: Application.Undo bei ComboBoxen möglich?

Hallo zusammen!

Ich habe zwei Comboboxen, die voneinander abhängig sind. Beispiel:

[KONTINENT] Europa, Amerika ...
[LAND] Deutschland, USA ...

Nehmen wir an, sowohl Kontinent als auch das Land sind ausgewählt. Nun habe ich per VBA programmiert, dass das Land zurückgesetzt wird, sobald man den Kontinent wieder ändern will und dies noch in eine MsgBox verpackt:

"Wenn Sie den Kontinent ändern, wird das Land zurückgesetzt! Möchten Sie fortfahren?" [Ja/Nein]

Bei Klick auf Ja wird automatisch das Land zurückgesetzt.

Bei Klick auf Nein versuchte ich mit Application.Undo die bereits vorgenommene Änderung dann wieder rückgängig zu machen, da ich ja nicht möchte dass das Land gelöscht wird! Mochte Excel nicht. Ich habe dann herausgefunden, dass es geht, wenn ich z.B. Text in eine Zelle eingebe, der ist danach wieder weg sprich es wurde "rückgängig" gemacht. Das verändern der Combobox-Auswahl kann aber nicht rückgängig gemacht werden - hat jemand eine Alternative?

Ich wollte es am Anfang ganz anders machen und das Ereignis ComboBox_Click() statt ComboBox_Change() nehmen, sodass der Eintrag noch nicht geändert ist, aber ich glaube beide Ereignisse bewirken das gleiche!

Code:

Sub ComboBox_Change()
If Sheets("Daten01").Range("Land") = "1" Then
Else
    Dim byWert As Byte
    byWert = MsgBox(""Wenn Sie den Kontinent ändern, wird das Land zurückgesetzt! Möchten Sie fortfahren?", vbCritical + vbYesNo, "Kontinent ändern")
    If byWert = 7 Then
    Call Nein
    ElseIf byWert = 6 Then
    End If
End If

Sheets("Daten01").Range("Land") = "1"
End Sub

Sub Nein()
Application.Undo
End
End Sub

 

Hi,

handelt es sich um ComboBoxen im Tabellenblatt oder auf einem UserForm? Eine hochgeladene Arbeitsmappe wäre hilfreich.

Bis später,
Karin

 

Hallo Karin!

Im Tabellenblatt. Hab die XLS jetzt mal angefügt.

Einfacher gesagt suche ich eine Möglichkeit, dass bei der Frage "Wollen Sie fortfahren?" bei Klick auf Nein der vorherige Zustand der ComboBox/LinkedCell wieder hergestellt wird und bei Klick auf Ja die LinkedCell zurückgesetzt (auf 0 gestellt) wird - letzteres klappt ja schon.

Hoffe du verstehst was ich meine. Danke bereits im Voraus!

 

Hi,

bei Steuerelementen aus der Formular-Symbolleiste gibt es keine Möglichkeit, den vorhergehenden Inhalt auszulesen, sodass man auch nichts zurücksetzen kann. Verwende stattdessen eine ComboBox aus der Steuerelemente-Toolbox - sie besitzt die Eigenschaft DropButtonClick, die man verwenden kann um den ursprünglichen Zustand auszulesen.
Unter den Eigenschaften schreibst du in ListFillRange Kontinente - sonst keine weiteren Einträge. Der folgende Code im Codemodul des Tabellenblattes sollte dann alles steuern:

Code:

Option Explicit
Dim strKontinent As String
Dim booAction As Boolean

Private Sub ComboBox1_Change()
    Dim byWert As Byte
    Application.EnableEvents = False
    If ComboBox1 <> strKontinent Then
        If ComboBox1 <> "" Then
            If booAction = False Then
                byWert = MsgBox("Wenn Sie den Kontinent ändern, wird das Land zurückgesetzt! Möchten Sie fortfahren?", vbCritical + vbYesNo, "Kontinent ändern")
                booAction = True
                If byWert = 7 Then
                    ComboBox1 = strKontinent
                ElseIf byWert = 6 Then
                    Range("LandLinkedCell") = 0
                End If
            End If
        End If
    End If
    Range("G3") = ComboBox1
    Application.EnableEvents = True
End Sub

Private Sub ComboBox1_DropButtonClick()
    strKontinent = ComboBox1
    booAction = False
End Sub

Eine Formel in G3 benötigst du nicht, der Kontinent wird per Code eingetragen.

Bis später,
Karin

 

Liebe Karin,

jetzt muss ich mal danke sagen. Du hast in den Code alles gepackt, was ich für mein Projekt so gebrauchen kann.

Insbesondere Application.EnableEvents kannte ich noch nicht und diesen Befehl kann ich noch in einem anderen Code benutzen und macht mir das alles viel leichter! Ich habe schon lange nach einem Befehl gesucht, der die anderen Events aussetzt, nur dachte ich so etwas gibt es nicht ^^ Kann garnicht oft genug danken!