Office: Artikel in Größen mit gleicher Artikelnummer zusammenfassen

Hallo zusammen,

ich stehe vor einer kleinen Herausforderung und möchte gerne aus einer Excel Tabelle die Größen mit gleicher Artikelnummer zusammenfassen. Ich habe das bereits mit einer Wenn-Dann Formel gemacht, das funktioniert auch, allerdings sind da ein paar Ausnahmen dabei. Zum Beispiel, habe ich die Größe 128 - 164, aber bei ein paar Artikeln fängt das schon bei Größe 116 an. Hat jemand eine Idee wie man das einfacher hinbekommt?

Beispiel: Ergebnis sollte dann sein:
Artikelnr. Groesse 1011821 K Größe 128-164
1011821 K 128
1011821 K 140
1011821 K 152
1011821 K 164
1011821 E S
1011821 E M
1011821 E L
1011821 E XL
1011821 E XXL
1011821 E XXXL
1011821 E XXXXL
1011821 E XXXXL

Danke euch und liebe Grüße,
Janina

 

Hola,
lade bitte eine Exceldatei mit dem aktuellen Stand hoch und trage händisch dein Wunschergebnis ein.
Gruß,
steve1da

 

Hallo Janina,

ich hab mal für meine Interpretation Deiner bisherigen Angaben mit Formeln umgesetzt. Du hast auch keine Excelversion angegeben, deshalb nachfolgend mit meiner älteren XL-Version realisiert (In XL365 geht es mit Formeln etwas einfacher als nachfolgend von mir aufgezeigt)

Nachfolgende Formeln einfach weit genug nach unten ziehend kopieren.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	Artikelnr.	Groesse		Artikelnr.	Typ	Größe
2	1011821	K 128		1011821	K	128
3	1011821	K 140		1011821	E	S
4	1011821	K 152		2222222	N	116
5	1011821	K 164		2222222	G	M
6	1011821	E S
7	1011821	E M
8	1011821	E L
9	1011821	E XL
10	1011821	E XXL
11	1011821	E XXXL
12	1011821	E XXXXL
13	1011821	E XXXXL
14	2222222	N 116
15	2222222	N 128
16	2222222	N 140
17	2222222	G M
18	2222222	G L
19	2222222	G XL
20	2222222	G XXL
21

Zelle	Formel
D2	=WENNFEHLER(AGGREGAT(15;6;A$2:A$21/(A$2:A$21>0)/(ZÄHLENWENNS(D$1:D1;A$2:A$21;E$1:E1;LINKS(B$2:B$21;2)&"*")=0);1);"")
E2	=LINKS(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$2:A$21)/(A$2:A$21=D2)/(ZÄHLENWENNS(D$1:D1;A$2:A$21;E$1:E1;LINKS(B$2:B$21;2)&"*")=0);1));2)
F2	=WECHSELN(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$2:A$21)/(A$2:A$21=D2)/(ZÄHLENWENNS(D$1:D1;A$2:A$21;E$1:E1;LINKS(B$2:B$21;2)&"*")=0);1));E2;"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

 

Habe die Excel Tabelle mal hochgeladen und die Spalte D ist das Wunschergebnis (da ist auch zurzeit noch meine Formel drin) allerdings greift die nicht bei Ausnahmen. Beispiel generell geht ein Artikel von Größe S-XXL, jetzt habe ich aber ein paar Ausnahmen die bis Größe XXXL gehen. Gibt es da eine Formel um nicht alles händisch zu überprüfen?

Danke euch :)

 

=WENN(A2<>A1;"Größe "&SVERWEIS(A2;A:C;3;0)&"-"&VERWEIS(2;1/($A$2:$A$15000=A2);$C$2:$C$15000);"")
Evtl etwas schneller:
=WENN(A2<>A1;"Größe "&SVERWEIS(A2;A:C;3;0)&"-"&INDEX($C$2:$C$15000;AGGREGAT(14;6;ZEILE($C$2:$C$15000)-1/($A$2:$A$15000=A2);1));"")

 

Hallo @steve1da,

ein klein wenig vereinfachen könnte man deine ansonsten Superformeln noch:
=WENN(A2<>A1;"Größe "&$C2&"-"&VERWEIS(2;1/($A$2:$A$15000=A2);$C$2:$C$15000);"")
bzw.
=WENN(A2<>A1;"Größe "&$C2&"-"&INDEX($C$2:$C$15000; AGGREGAT(14;6;ZEILE($C$2:$C$15000)-1/($A$2:$A$15000=A2);1));"")

 

@Anton: oh man, danke! Ist mir gar nicht aufgefallen ;-)

 

Oh wow, super! Danke das klappt