Office: Auf- und zuklappen von Spalten bei Auswahl im Dropdwon Menü

Da mir hier bisher immer so toll geholfen wurde, wende ich mich mit einem weiteren Problem an euch. Ich hoffe ich komme mal selbst so weit hier helfen zu können...

Also folgendes Problem:

Ich habe in einer Spalte A ein Dropdown Menu welches über die Datenüberprüfung erstellt wurde. Wird dort Variante A ausgewählt, soll Spalte B aufklappen, bei Variante B zuklappen und bei Variante C ebenfalls ausklappen.

Habe bisher immer mit

Columns("B:B").Select
Selection.EntireColumn.Hidden = True/False

auf- und zugeklappt, aber hier sehe ich keine Möglichkeit, wie das klappen könnte.

Freue mich auf eure Vorschläge

 

Hallo!

In der beiliegenden Excel-Datei ist in Zelle Tabelle1!A1 ein Dropdown enthalten (mit der DropDown-Liste in Tabelle1!A7:A9).
Ferner ist im Codemodul von Tabelle1 ein kleines Makro enthalten, das auf das Change-Ereignis in Zelle Tabelle1!A1 reagiert und die Spalte B ausblendet, falls in A1 der Listeneintrag "B" ausgewählt wurde - ansonsten wird die Spalte B eingeblendet.

 

Das sieht schon sehr vielversprechend aus, allerdings soll das Dropdown in der gesamten Spalte vorhanden sein. Daher ist ein reiner Bezug auf A1 nicht ausreichend. Habe schon versucht das umzugestalten, aber es hat nicht funktioniert. Noch eine Idee wie man das machen könnte?

 

Hallo Macel,
und was soll passieren wenn in A1 Variante A gewählt wurde, und dann in A2 Variante B?
usw...

 

Hallo,

in der beiliegenden Excel-Datei habe ich das Change-Ereignis fürs Arbeitsblatt 'Tabelle1' etwas modifiziert, damit es nicht bloß auf Zelle A1 anspricht, sondern auf die ganze Spalte A.

Das DropDown selbst kann ganz einfach in die restlichen Zellen der Spalte A anhand von Zelle A1 doponiert werden: durch Kopieren:
a) Zelle A1 markieren, rechte Maustaste klicken, Befehl 'kopieren' ausführen, Zielbereich in der Spalte A markieren, rechte Maustaste klicken, Befehl 'einfügen' ausführen.
b) Oder auch durch Hinunterziehen von Zelle A1 in weitere Zellen der Spalte A.

In der beiliegenden Datei habe ich das DropDown in die ersten 33 Zellen der Spalte A gespeichert. Falls Du es wirklich in alle Zellen der Spalte A einfügst, wird es (ab Excel2007) ca. 1 Million mal eingefügt und entsprechend groß wird die Datei allein aus diesem Grund. Deshalb habe ich es nur in die ersten 33 Zellen eingefügt, um die Beispieldatei klein zu halten.

 

@ fette Elfe: Es soll bei jeder neuen Auswahl "entschieden" werden, ob sich die Spalte öffnet oder nicht. So wie das in der Datei von Exl121150 ist ist es perfekt.

@Exl121150: Das ist dafür wie ich die Frage gestellt habe perfekt. Mir ist nur klar geworden, dass ich sie falsch herum gestellt habe (wollte Vereinfachen). Ich habe nämlich eigentlich meherere Ereignisse, bei denen die Spalte geschlossen sein muss und nur eines bei dem sie geöffnet wird. Habe gestern versucht das irgendwie umzuschreiben, aber meine VBA Kenntnisse reichen dafür einfach noch nicht.

Am Besten wäre es, wenn ich mehrere Target Values eingeben könnte. Wie trenne ich diese denn?
Außerdem habe ich ein weiteres Dropdown, bei dem verschiedene Spalten je nach Auswahl geöffnet werden müssen. Das gleiche Sub verändert auf die jeweilige Spalte und Target Value einfach dahinter reinkopieren funktioniert ja nicht... Wo müsste ich das denn trennen?

Vielen Dank nochmal für die Hilfe, habe schon einiges dazugelernt, aber so langsam wird es Zeit für eine Strukturierte Einarbeitung in VBA von Anfang an :)

 

Hallo!

Im Folgenden der Change-Event-Handler für ein Arbeitsblatt, den ich etwas erweitert habe:
Im 1. Teil reagiert er auf Change-Ereignisse in der Spalte A
Im 2. Teil reagiert er auf Change-Ereignisse in der Zelle C7
Das Target-Bereichsobjekt zeigt immer an, wo bzw. in welchem Bereich das Change-Ereignis stattfand, auf das reagiert werden soll.

Auf etwas muss man beim Change-Ereignis besonders achten: Führt man in der Change-Event-Behandlungsroutine Befehle im Arbeitsblatt aus, die ihrerseits wieder zur Auslösung des Change-Ereignisses führen, würde das bedeuten, dass sich die Change-Event-Behandlungsroutine rekursiv selbst wieder aufrufen würde ...(ad infinitum)... was schließlich (irgendwann) zum Absturz des Makros führt (führen kann), wenn dem kein Ende gesetzt wird.
Das ist der Grund, warum ich jeweils zu Anfang und zu Ende die Anweisungen "Application.EnableEvent=False/True" eingefügt habe.

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
  If Target.Address Like "$A$*" Then
    'Auswahl wurde auf Spalte A eingeschränkt (alle Adressen, die mit "$A$" anfangen)
    On Error GoTo Err_Ws_Change
    Application.EnableEvents = False
    Select Case Target.Value
      Case "A":
        'Befehle, falls "A" ausgewählt wurde in Spalte A:
        Columns("B:B").EntireColumn.Hidden = False
        
      Case "B":
        'Befehle, falls "B" ausgewählt wurde in Spalte A:
        Columns("B:B").EntireColumn.Hidden = True
      Case "C":
        'Befehle, falls "C" ausgewählt wurde in Spalte A:
        Columns("B:B").EntireColumn.Hidden = False
        
      Case Else
        'Befehle, falls etwas anderes als "A","B" oder "C" ausgewählt wurde in Spalte A:
      
    End Select
Exit_Ws_Change:
    Application.EnableEvents = True
  ElseIf Target.Address = "$C$7" Then
    Application.EnableEvents = False
    'Falls ein Change-Ereignis in Zelle C7 stattfand:
    'Hier können somit Befehle eingefügt werden, die darauf reagieren ...
    '....
    Application.EnableEvents = True
  End If
  Exit Sub
Err_Ws_Change:
  Resume Exit_Ws_Change
End Sub

 

Habe im Freudentaumel ganz vergessen mich zu bedanken :)
Hat super geklappt!! Vielen Vielen Dank für die Hilfe!