Office: Aus einer Spalte mit einer Zeile, mehrere Zeilen machen.

Servus Leute,

wusste leider nicht wirklich wie ich das Thema nennen sollte, darum der wahrscheinlich missglückte Name... :)

Also folgendes Problem:
Ein Auswertungstool erstellt mir eine Tabelle, welche ich wieder mit einem Tool einlesen muss.

Das Problem:
Bei dem Auswertungstool wird eine Zeile mit folgendem Inhalt erstellt.
Pat.Nr. Name Geb.datum Ort Strasse VKNR Kasse UND Karteizeilen.
In der Spalte Karteizeilen können allerdings mehrere Zeilen stehen. Ich brauche aber unbedingt für jeden Karteizeileneintrag eine Zeile. (auch wenn dann 5 mal am Stück die gleiche Pat.Nr. untereinander steht).

Mir ist leider nicht mal annähernd eine Idee gekommen, wie ich dies umsetzen kann...
Hoffe hier ist jemand ein wenig kreativer/erfahrener und hat eine Idee :)

Grüße :)

 

Hier mal ein pdf, damit Ihr euch das besser vorstellen könnt.

Bin leider noch kein Stück weiter gekommen. Danke schonmal.

 

Hi,

soweit ich dich verstanden habe willst du am Ende für eine Pat.Nr. mehrer Karteizeilen haben. Ich hatte mal irgendwo eine Mappe gesehen mit Gruppieren von Zeilen, die man dann links bei den Zahlen mit einem + aufklappen und wieder schließen kann. Ich denke dies würde dir weiterhelfen. Ich schau mal nach ob ich das Beispiel hier nocheinmal finde, wenn nicht suche ich etwas passendes raus.

Bis gleich... :mrgreen:

So, da ich vor kurzem vom 2003 auf 2007 aufgestiegen bin, hatte ich schon Probleme das gesuchte zu finden.

Makiere die Zellen die zusammengehören, gehe zu Menü > Daten > Gruppieren, bei 2007 fragt er nach anklicken des Gruppieren ob Zeilen oder Spalten gruppiert werden soll. In deinem Fall Zeile und mit OK bestätigen.

Hoffe das es dir in etwa so vorgestellt hast. So kannst mehrere Zeilen zusamenfassen und über das + schließen, so siehst nur die erste Zeile wo nicht mit eingrupiert hast.

Per Google gibt es schöne Beispiele zu "Excel gruppieren".

Sorry, hab's eilig und auf der Suche nach einer Lösung

Gruß
Emi ;-)

 

:mrgreen:

Hi, (nochmal sry)

mich hat es jetzt interessiert wie das genau geht, das gute ist das nebenbei eine Bsp.-Datei rausspringt.

Wichtig ist das beim Makieren um zu gruppieren die erste Zeile nicht makierst, sonst verschwindet die Zeile mit Namen und co. auch wenn per + die Gruppierung schließt.

Hoffe sehr dir weitergeholfen zu haben.

Nebenbei habe ich die erste Zeile fixiert, so das beim Downscrollen die erste Zeile immer zu sehen ist.

Gruß
Emi

 

Hallo Emi,

ist zwar eine sehr coole Excel Option, leider aber nicht die, die ich brauche.

Mein Problem ist, ich brauche für jeden Eintrag bei "Karteizeilen" (durch alt+enter getrennt) einmal die Kompletten Daten von "Patient" bis "Karteizeilen".

Danke aber für deine hilfe

gr+ße
nathan

 

Hi,

da war ich wohl zu schnell, da ich keine Lösung für mein Problem finde versuche ich mal bei dir.

Verstehe ich es jetzt richtig? Die eine Zelle wo mehrere Zeilen drin stehen sollen sozusagen umgewandelt werden das am Ende jede Zeile in der Zelle eine eigene Zeile bekommt. Richtig?

GRuß
Emi :?:

 

:roll: Hallo,

also ich kann dazu nichts finden, schwer vorzustellen das es hierzu nichts geben soll. Falls ich dich richtig verstanden habe mit deinem Problem.

Vielleicht kann dir einer der Profis weiterhelfen.

Gruß
Emi

 

Hallo,

hier mal ein kleines Anfänger-Makro, was das machen sollte, was Du willst. Wenn Du wieder eine Anfrage hast, dann stelle Deine Tabelle als Excel-File ein oder zumindest mit einem der geläufigen Tools, eine PDF oder ein Bild lassen sich so schwer nachbauen:

Code:

Option Explicit

Sub Zeilenmehr()
Dim loA As Long
Dim loB As Long
Dim loc As Long
Dim loLetzte As Long
Dim varKartei As Variant
Application.ScreenUpdating = False
loLetzte = Cells(Rows.Count, 1).End(xlUp).Row
For loA = loLetzte To 1 Step -1
    If InStr(Cells(loA, 9), Chr(10)) <> 0 Then
        varKartei = Split(Cells(loA, 9), Chr(10))
        loc = UBound(varKartei)
        For loB = 1 To loc
            Rows(loA + 1).Insert shift:=xlDown
            Rows(loA).Copy Rows(1 + loA)
        Next
        For loB = 0 To loc
            Cells(loA + loB, 9) = varKartei(loB)
        Next
    End If
    loc = 0
Next
Application.ScreenUpdating = True
End Sub

Gruß

Edgar

 

Hallo NathanDrake,

da war Edgar schneller...


Hab auch noch einen Lösungsvorschlag der ähnliches macht.
Funktionieren tuen sie beide:

Code:

Option Explicit

Dim intCounter2 As Integer
Dim intTextLänge As Integer

Dim strZellwertAlt As String
Dim strZellwertNeu As String
Dim strZellwertRest As String

Dim loCounter1 As Long
Dim loLetzte As Long


Public Sub StringLänge()
    
    With ThisWorkbook.Worksheets("Tabelle1")
        
        ' letzte belegte Zelle in Spalte I
        loLetzte = IIf(IsEmpty(.Cells(.Rows.Count, 9)), .Cells(.Rows.Count, 9).End(xlUp).Row, .Rows.Count)
        
        For loCounter1 = 2 To loLetzte + 1
            strZellwertAlt = .Cells(loCounter1, 9).Value
            intTextLänge = Len(.Cells(loCounter1, 9).Value)
            
            For intCounter2 = 1 To intTextLänge
                If Mid$(strZellwertAlt, intCounter2, 1) = Chr(10) Then
                    strZellwertNeu = Left$(strZellwertAlt, intCounter2 - 1)
                    strZellwertRest = Right$(strZellwertAlt, intTextLänge - intCounter2)
                    .Cells(loCounter1, 9).Value = strZellwertNeu
                    .Rows(loCounter1 + 1).EntireRow.Insert shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
                    .Cells(loCounter1 + 1, 9).Value = strZellwertRest
                    .Range(.Cells(loCounter1, 1), .Cells(loCounter1, 8)).Copy
                    .Range(.Cells(loCounter1 + 1, 1), .Cells(loCounter1 + 1, 8)).PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, _
                        SkipBlanks:=False, Transpose:=False
                    loLetzte = loLetzte + 1
                    Exit For
                End If
            Next intCounter2
        Next loCounter1
        Application.CutCopyMode = False
    End With
    
End Sub

Falls Du Dich mit Makros nicht so auskennst, frag nach was Du nicht verstehst.
Beide Varianten müssen eventuell noch angepasst werden um bei Dir wirklich fehlerfrei zu arbeiten.