Office: Aus Excel Makro Word Datei ändern

pm4433 · 4. Dezember 2011

Ich muss aus einem Excel Makro eine Word Datei ändern (1x suchen und ersetzen gegen Ersatzwort) und unter anderem Namen (verlängert um das Ersatzwort) wieder speichern.

Das "Suchen und Ersetzen klappt leider nicht. In Schritt 3 gibt es einen:
Laufzeitfehler '450':
Falsche Anzahl an Argumenten oder ungültige Zuweisung zu einer Eigenschaft

In den Schritten 5-7 denke ich ist ebenfalls etwas zu verbessern. Nach dem Speichern muss einfach Word nur sauber geschlossen werden.

Es wäre toll, wenn jemand Tipps hat:

Hier ist mein Entwurf:

Code:

Sub test()

'Schritt 1: Wert der aktiven Zelle der Variablen Ersatzwort zuweisen
Ersatzwort = ActiveCell.Value

'Schritt 2: Word Datei öffnen
Dim AppWD As Object
Set AppWD = CreateObject("Word.Application") 'Word als Object starten
AppWD.Visible = True
AppWD.documents.Open "C:\Users\Test\Documents\Test.doc"

'Schritt 3: Suchen und ersetzen - Text "5234" muss gegen die Variable Ersatzwort ersetzt werden
With Selection.Find
.Text = "5234"
.Replacement.Text = Ersatzwort
.Wrap = wdFindContinue
End With
Selection.Find.Execute Replace:=wdReplaceAll
'
'Schritt 4: Dokumentschutz mit Passwort
'
ActiveDocument.Protect Type:=wdAllowOnlyFormFields, _
NoReset:=True, Password:="Code"

'Schritt 5: Dokument unter neuem Namen speichern - Word 97 doc format
' Der Name muss bestehen aus einem immer gleichen String verlängert durch die Variable
'
ActiveDocument.SaveAs Filename:="C:\Users\Test\Documents\Name-" & Ersatzwort & ".doc", _
FileFormat:=wdFormatDocument97
'Schritt 6: Dokument schliessen - ohne zu speichern
ActiveDocument.Close SaveChanges:=wdDoNotSaveChanges

'Schritt 7: Word App schliessen
AppWD.documents("C:\Users\Test\Documents\Name-" & Ersatzwort & ".doc").Close SaveChanges:=False
AppWD.Quit
Set AppWD = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

EarlFred · 6. Dezember 2011

Hallo namenloser,

Grußformeln, einleitend und abschließend, sind immer eine nette Geste. Auch ein Name, mit dem Du angesprochen werden möchtest, ist angenehmer als "Nichts".

Wenn Du in einer anderen Anwendung arbeitest als der, in der der Code gestartet wird, müssen Aktionen der Fremdanwendung immer sauber angesprochen werden. Es ist in diesem Fall für Excel-VBA unerheblich, ob Word und das Word-Document gerade im Vordergrund sind oder nicht.
Gerade das "Universal"-Objekt "Selection" ist auch in Excel bekannt. Verwendest Du dies, geht Excel immer erstmal davon aus, dass die Excel-Selection gemeint ist - das ist aber in Deinem Fall nicht korrekt.

Weiterer Punkt: Verwendete Word-Konstanten (z. B. wdFindContinue - (meist) erkennbar am Kürzel "wd" im Namen) kennt Excel nicht. Entweder, Du bindest die Word-Bibliothek in Dein Projekt ein (würde ich nicht tun, ggf. Versionskonflikte) oder Du deklarierst Dir diese Konstanten (so habe ich es mal gemacht) oder Du verwendest die zugehörigen Zahlenwerte, die hinter den Konstanten liegen (was aber nicht gerade die Übersichtlichkeit im Code erhöht).

Du brauchst also die Konstanten. Dazu würde ich das geöffnete Dokument ebenfalls in einer Variable ablegen, damit Du im weiteren Code sicher darauf zugreifen kannst.

Meines Wissens existiert die Konstante wdFormatDocument97 erst ab Word 2007. Ggf. kommt es bei älteren Wordversionen zu Problemen, das habe ich aber nicht ausgetestet.

Folgender Codevorschlag (ungetestet)
Code:

ption Explicit
Sub test()
Dim AppWD As Object
Dim objDoc As Object
Dim Ersatzwort As String
Const wdReplaceAll As Long = 2
Const wdFindContinue As Long = 1
Const wdAllowOnlyFormFields As Long = 2
Const wdFormatDocument97 As Long = 0
Const wdDoNotSaveChanges As Long = 0

'Schritt 1: Wert der aktiven Zelle der Variablen Ersatzwort zuweisen
Ersatzwort = ActiveCell.Value

'Schritt 2: Word Datei öffnen
Set AppWD = CreateObject("Word.Application") 'Word als Object starten
AppWD.Visible = True
Set objDoc = AppWD.documents.Open("C:\Users\Test\Documents\Test.doc")

'Schritt 3: Suchen und ersetzen - Text "5234" muss gegen die Variable Ersatzwort ersetzt werden
With objDoc.Content.Find
.Text = "5234"
.Replacement.Text = Ersatzwort
.Wrap = wdFindContinue
.Execute Replace:=wdReplaceAll
End With

'
'Schritt 4: Dokumentschutz mit Passwort
'
objDoc.Protect Type:=wdAllowOnlyFormFields, _
NoReset:=True, _
Password:="Code"

'Schritt 5: Dokument unter neuem Namen speichern - Word 97 doc format
' Der Name muss bestehen aus einem immer gleichen String verlängert durch die Variable
'
objDoc.SaveAs Filename:="C:\Users\Test\Documents\Name-" & Ersatzwort & ".doc", _
FileFormat:=wdFormatDocument97
'Schritt 6: Dokument schliessen - ohne zu speichern
objDoc.Close SaveChanges:=wdDoNotSaveChanges

'Schritt 7: Word App schliessen
Set objDoc = Nothing
AppWD.Quit
Set AppWD = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

pm4433 · 6. Dezember 2011

Allerbesten Dank, EarlFred, für die vielen Tipps und die Korrektur des Programmes, welches jetzt hervorragend läuft.

Viele Grüße, Pepe M.

Office: Aus Excel Makro Word Datei ändern

Aus Excel Makro Word Datei ändern

Aus Excel Makro Word Datei ändern

Aus Excel Makro Word Datei ändern - Similar Threads - Excel Makro Word

Word-Dateien über Excel in eine ausgewählte Word-Datei übertragen per Makro

Word, Excel Serienbrief Makro in einzelne Datein

Word-Makro von Excel aus starten

Aus Word, Makro in Excel Sheet aufrufen

Word Makro aus Excel starten

Automatische Formatierung und Einbinden von Bildern

Datenaustausch Excel zu Word mit Makro Office 2002