Office: Aus Excel PDF erzeugen und per E-mail versenden

Franz00 · 18. Oktober 2010

Hallo zusammen,
ich möchte aus einer Excel Sheet ein PDF erzeugen und dieses per Outlook an mehrere E-mail Empfänger senden. Mein Problem ist, dass ich das PDF erzeugen kann, aber die E-mail Empfänger werden nicht eingetragen! Wie muss ich den Code anpassen, das ich das erzeugte PDF mit der E-mail Verteilerliste versenden kann? Anbei mein Lösungsansatz. Hat jemand eine Idee?
Danke. Gruß Franz

Code:

Sub PDF_erzeugen_und_versenden()

'Variable für Outlook'

Dim olApp As Object
Dim objNachricht As Object 'Variable für die Mail
Dim objRecipient As Object 'Variable für die Empfänger
Set olApp = CreateObject("Outlook.Application") 'Erzeuge Outlook-Sitzung
'Erstelle eine neue Nachricht, die 0 in CreateItem steht für olMailItem
Set objNachricht = olApp.CreateItem(0)
ActiveobjNachricht = ActiveWorkbook.FullName

With objNachricht
.Subject = "Nachricht vom - " & Now()

'Erzeuge 2 Adressaten: Der 1. wird als primärer, der 2.
'Kopieempfänger angegeben

Set objRecipient = .Recipients.Add("E-mail Adresse1")
Set objRecipient = .Recipients.Add("E-mail Adresse2")
Set objRecipient = .Recipients.Add("E-mail Adresse3")
Set objRecipient = .Recipients.Add("E-mail Adresse4")

'PDF Druck erzeugen'
Application.ScreenUpdating = False
Dim sPrinter As String
sPrinter = Application.ActivePrinter
Application.ActivePrinter = "\\srv15\PDF0001 auf Ne05:"
Drucker = Application.ActivePrinter
Worksheets("Stationsanzeige").PrintOut ActivePrinter:=Drucker
Application.ScreenUpdating = True

'Hänge eine PDF-Datei an die Mail
.Attachments.Add 'Erzeugte PDF-Datei'
.DeleteAfterSubmit = True 'Nach dem Senden direkt wieder löschen (nicht aufheben)
.Display 'Anzeige im Outlook
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

mumpel · 20. Oktober 2010

Hallo!

Viel einfacher.

Sub PDF_erzeugen_und_versenden()

'Variable für Outlook'

Dim olApp As Object
Dim sPath As String

Rem PDF-Datei auf dem Desktop mit Namen des Tabellenblattes speichern
sPath = Environ("Userprofile") & "\Desktop\" & ActiveSheet.Name & ".pdf"

Rem Pdf erzeugen
Worksheets("Stationsanzeige").ExportAsFixedFormat Type:=xlTypePDF, Filename:=sPath, _
Quality:=xlQualityStandard, IncludeDocProperties:=False, _
IgnorePrintAreas:=True, OpenAfterPublish:=False

Set olApp = CreateObject("Outlook.Application")

With olApp.CreateItem(0)
.to = "empfänger1@server.de" ' Empfänger
.cc = "empfänger2@server.de;empfänger3@server.de" 'Kopie an
.Subject = "Nachricht vom - " & Now() ' Betreff
.Attachments.Add sPath
.DeleteAfterSubmit = True 'Nach dem Senden direkt wieder löschen (nicht aufheben)
.Display 'Anzeige im Outlook
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code eingefügt mit VBA in HTML 2.0
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, René

Franz00 · 20. Oktober 2010

Hallo Réne,

danke für Deine Unterstützung.

Bei der Codezeile

Rem Pdf erzeugen
Worksheets(" ...

bekomme ich den Laufzeitfehler:
Objekt unterstützt diese Eigenschaft oder Methode nicht (Fehler 438)

Auf meinem Exceltabellenblatt habe ich eine Schaltfläche wo ich den code ausführe. Das Problem liegt wohl an der Erstellung der PDF-Datei. Mit meinem Code kann ich die PDF-Datei erstellen, aber nicht an das E-mail mit den Empfänger dranhängen! Hast Du noch eine Idee?

Gruß Franz

mumpel · 12. Januar 2021

1. :

von Franz00

...bekomme ich den Laufzeitfehler:
Objekt unterstützt diese Eigenschaft oder Methode nicht (Fehler 438)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Du hast doch Excel 2007 oder Excel 2010? Hast Du zumindest angegeben. In Excel 2003 gibt es "ExportAsFixedFormat" nicht. Ich richte meine Antworten IMMER auf die Versionsangabe aus, ich muss mich also auf die Versionsangabe verlassen können.

2. Solltest Du Excel 2007 haben, dann bitte das aktuelle Servicepack installieren. Damit wird auch das PDF-Add-In installiert und "ExportAsFixedFormat" steht dann auch zur Verfügung.

3. Du müsstest Dein Makro nur so aufbauen wie das meine. Erst die PDF-Datei erstellen, dann die Email.

Sub PDF_erzeugen_und_versenden()

'Variable für Outlook'

Dim olApp As Object
Dim sPath As String

'PDF Druck erzeugen'
Application.ScreenUpdating = False
Dim sPrinter As String
sPrinter = Application.ActivePrinter
Application.ActivePrinter = "\\srv15\PDF0001 auf Ne05:"
Drucker = Application.ActivePrinter
Worksheets("Stationsanzeige").PrintOut ActivePrinter:=Drucker
Application.ScreenUpdating = True

Set olApp = CreateObject("Outlook.Application")

With olApp.CreateItem(0)
.to = "empfänger1@server.de" ' Empfänger
.cc = "empfänger2@server.de;empfänger3@server.de" 'Kopie an
.Subject = "Nachricht vom - " & Now() ' Betreff
.Attachments.Add 'Erzeugte PD-Datei
.DeleteAfterSubmit = True 'Nach dem Senden direkt wieder löschen (nicht aufheben)
.Display 'Anzeige im Outlook
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code eingefügt mit VBA in HTML 2.0
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Franz00 · 20. Oktober 2010

Hallo Réne,

sorry, das war mein Fehler ich habe noch Excel 2003. Konnte ich aber bei meiner Anfrage auch nicht auswählen!

Beim durchlaufen Deines Codes bekomme bei der Zeile .Attachments.Add 'Erzeugte jetzt den Laufzeitfehler "Die Dateianlage kann nicht hinzugefügt werden. Es wurde keine Datenquelle bereitgestellt.
Hast Du noch eine Idee, wie ich das hinbekomme?
Danke.
Gruß Franz

mumpel · 21. Oktober 2010

Bei ".Attachments.Add" musst Du den kompletten Pfad zur PDF-Datei angeben. Diese könnte sich zum Beispiel im Pfad der Arbeitsmappe befinden, dann wäre es .Attachments.Add ThisWorkbook.Path & "Stationsanzeige" & ".pdf"

Franz00 · 21. Oktober 2010

Hallo Réne,

wenn ich das PDF mit dem Vollprogramm Adobe Acrobat erzeuge und die PDF in das Verzeichnis lege funktioniert der code!
Nun erzeuge ich das PDF mit Pdffactory 3 (aus Kostengründen) und unter den Druckereinstellungen muss ich das Anzeigefenster einblenden, sonst wird die PDF nicht erstellt. Vielleicht gibt es noch ein Befehl bei pdffactroy wie ich das einstellen kann?
Gruss Franz

mumpel · 21. Oktober 2010

PDFCreator. Lade den PDFCreator herunter. Nach der Installation über Extras->Verweise PDFCreator in der Liste suchen und auswählen. Dann mit folgendem Makro versuchen.

Sub PrintToPDF_AndMail()
'Author : Ken Puls (www.excelguru.ca)
'Macro Purpose: Print to PDF file using PDFCreator
'Designed for early bind, set reference to PDFCreator
'On Error Resume Next
Dim pdfjob As PDFCreator.clsPDFCreator
Dim sPDFName As String
Dim sPDFPath As String
Dim DefaultPrinter

'/// Change the output file name here! ///
sPDFName = ActiveSheet.Name & ".pdf"
'sPDFPath = ActiveWorkbook.Path & Application.PathSeparator
sPDFPath = Environ("Userprofile") & "\Desktop\"

'Check if worksheet is empty and exit if so
'If IsEmpty(Worksheets(Blattname).UsedRange) Then Exit Sub

Set pdfjob = New PDFCreator.clsPDFCreator

With pdfjob
If .cStart("/NoProcessingAtStartup") = False Then
MsgBox "Can't initialize PDFCreator.", vbCritical + _
vbOKOnly, "PrtPDFCreator"
Exit Sub
End If
.cOption("UseAutosave") = 1
.cOption("UseAutosaveDirectory") = 1
.cOption("AutosaveDirectory") = sPDFPath
.cOption("AutosaveFilename") = sPDFName
.cOption("AutosaveFormat") = 0 ' 0 = PDF
.cClearCache
.cPrinterStop = False '
End With

Rem Angegebene tabelle als PDF speichern
Worksheets("Stationsanzeige").PrintOut copies:=1, ActivePrinter:="PDFCreator"

BreaK:

'Wait until the print job has entered the print queue
Do Until pdfjob.cCountOfPrintjobs = 1
DoEvents
Loop

pdfjob.cPrinterStop = False

'Wait until PDF creator is finished then release the objects
Do Until pdfjob.cCountOfPrintjobs = 0
DoEvents
'Sleep 250
Loop

' MsgBox "PDF Dokument wurde erzeugt"

pdfjob.cClose
Set pdfjob = Nothing

Rem Email erstellen

Set olApp = CreateObject("Outlook.Application")

With olApp.CreateItem(0)
.to = "empfänger1@server.de" ' Empfänger
.cc = "empfänger2@server.de;empfänger3@server.de" 'Kopie an
.Subject = "Nachricht vom - " & Now() ' Betreff
.Attachments.Add sPDFPath & sPDFName 'Erzeugte PD-Datei
.DeleteAfterSubmit = True 'Nach dem Senden direkt wieder löschen (nicht aufheben)
.Display 'Anzeige im Outlook
End With

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code eingefügt mit VBA in HTML 2.0
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Franz00 · 21. Oktober 2010

Ok, wunderbar, ich werde den PDFCreator installieren und ausprobieren!
Vielen Dank für die Hilfe!
Gruß Franz

Office: Aus Excel PDF erzeugen und per E-mail versenden

Aus Excel PDF erzeugen und per E-mail versenden

Aus Excel PDF erzeugen und per E-mail versenden

Aus Excel PDF erzeugen und per E-mail versenden

Aus Excel PDF erzeugen und per E-mail versenden

Aus Excel PDF erzeugen und per E-mail versenden - Similar Threads - Excel PDF erzeugen

pdf drucken mit button in excel einfügen

Excel Tabellenblatt als PDF speichern unter Vorgabe Dateinamen aus einer Zelle

XY-Diagramm-Grafik mit zusätzlichen Daten erweitern

huge PDF to EXCEL

Komplexes Makro ohne Ahnung :-/

VBA Makro - PDF erstellen und speichern auf lokalem Netzwerk

Excel beim Speichern automatisch PDF erzeugen/ersetzen