Office: (Office 2007) Aus Spalte mit Datum eine Erinnerung erzeugen?

Wahlo · 18. September 2007

Hallo,
ich habe in Excel2007 in einer Datei eine Datums-Spalte (z.B. 30.06.2008).
Gibt es eine Möglichkeit, mir eine Outlookerinnerung zukommen zu lassen, wenn das tatsächliche Datum 1 Monat vor den einem Datum in der Spalte ist?

Ist etwas kompliziert?!?

Vorab vielen Dank.

Wahlo

:)

Sebastian Schulz · 19. September 2007

Hallo,

möglich wäre es. Jedoch müsste hier entweder die Mappe ständig geöffnet sein.

EarlFred · 19. September 2007

\@Sebastian
Das geht doch auch OHNE offene Tabelle - dafür ist ja Outlook da! (DAS müsste dann allerdings offen sein!)

Die Spalten müssen noch angepasst werden; im Beispiel ist eine For-Next-Schleife vorgeschlagen, allerdings noch auskommentiert. Zellbezug für das Datum ist mangels genauerer Beschreibung Zelle A1 - bitte entsprechend anpassen, ggf. mit dem Zähler aus der For-Next-Schleife (i).

Code:

Sub Eintrag_bei_Outlook()

Dim OlApp As Outlook.Application
Dim OLSess As Outlook.Namespace
Dim Termin As Outlook.AppointmentItem
Set OlApp = Outlook.Application
Set OLSess = OlApp.GetNamespace("MAPI")
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar)

'For i = 1 To Cells(Rows.Count, 1)

Set Termin = OlApp.CreateItem(olAppointmentItem)
With Termin
.Subject = "Hier wird das Thema beschrieben"
.Body = "Hier folgt eine genaue Beschreibung"
.Start = DateValue(Cells(1, 1)) + TimeValue("10:00:00")
.Duration = 0
.ReminderMinutesBeforeStart = 43200 '=30 Tage
.ReminderSet = True
.Categories = "Erinnerungen"
.Save
End With
Exit Sub

'Next i

Set OlApp = Nothing
Set OLSess = Nothing
Set Ordner = Nothing
Set Termin = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Grüße
EarlFred

EarlFred · 19. September 2007

Achso, vergessen:

Im VBA-Editor unter "Extras"-"Verweise" muss die MS-Outlook Object-Library markiert werden!

Grüße
EarlFred

Sebastian Schulz · 19. September 2007

Hallo earlfred,

du hast recht,wenn du jeden Eintrag in Outlook einträgst. Natürlich nur, wenn man hierfür einen eigenen Kalender anlegt.(Ich möchte nicht die Erinnerung in meinem normalen Kalender haben. Da steht eh schon genug drin) *wink.gif*

Jedoch muss Du noch berücksichtigen, dass bei Änderungen des Eintrages in Excel der alte Wert in Outlook gesucht, gelöscht oder aktualisiert wird. Was ist, wenn jemand Anderes einen Eintrag vornimmt? *entsetzt

Dann musst noch eine Routine implementiert werden, welches die neuen Einträge kennzeichnet und dann in Outlook rüberspielt. Oder du löscht zuvor den alten Kalender und erstellst ihn dann immer neu. (Bei vielen Einträgen kann dies schon dauern) Ich denke jedoch, dass man dann für eine Erinnerungsfunktion zu großen Aufwand betreibt. (Soll nicht als Angriff oder nicht Wertschätzung zu verstehen sein, sondern so ein Thema kann immer recht schnell komplex werden)

@wahlo
Wenn du diesen Weg gehen möchtest (was zugegeben schon eine interessante Lösung wäre), könntest du Dir Uwek Access-Kalender die Routinen anschauen. Die sind denke ich in Excel ziemlich ähnlich (nur eine Vermutung). Hier wird der Wert übertragen, aktualisiert und gelöscht von Access aus.

Wahlo · 19. September 2007

Hallo,

zunächst einmal vielen Dank für die Hilfe.
Das mit dem Aktualisieren und löschen wäre schon genial. Wo genau steht das Access-bezogen?

Bin allerdings ein wenig sketisch, ob ich die Ummünzung auf Excel hinkriege.

Danke.

EarlFred · 9. Februar 2021

von Sebastian Schulz

Hallo earlfred,

du hast recht,wenn du jeden Eintrag in Outlook einträgst. Natürlich nur, wenn man hierfür einen eigenen Kalender anlegt.(Ich möchte nicht die Erinnerung in meinem normalen Kalender haben. Da steht eh schon genug drin) *wink.gif*

Jedoch muss Du noch berücksichtigen, dass bei Änderungen des Eintrages in Excel der alte Wert in Outlook gesucht, gelöscht oder aktualisiert wird. Was ist, wenn jemand Anderes einen Eintrag vornimmt? *entsetzt

Dann musst noch eine Routine implementiert werden, welches die neuen Einträge kennzeichnet und dann in Outlook rüberspielt. Oder du löscht zuvor den alten Kalender und erstellst ihn dann immer neu. (Bei vielen Einträgen kann dies schon dauern) Ich denke jedoch, dass man dann für eine Erinnerungsfunktion zu großen Aufwand betreibt. (Soll nicht als Angriff oder nicht Wertschätzung zu verstehen sein, sondern so ein Thema kann immer recht schnell komplex werden)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hi Sebastian,

Du hast mit allem Recht. ABER: Davon stand nichts in Wahlos Projektanforderungskatalog! Zudem sprengt es irgendwann die Hilfsbereitschaft von vielen Forenusern (u. a. meine!), wenn hier perfekte Rundumsorglospakete für lau abgefordert werden *wink.gif*

Läßt sich aber alles machen, vor allem das mit dem eigenen Kalender geht fix einzubauen.
Vorne ins Makro muss noch (vor Set Termin = ...):
Code:

On Error Resume Next
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders("Erinnerungen")
If Err Then
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders.Add("Erinnerungen")
Err.Clear
End If
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

... und hinten dran (hinter .save):

Code:

.Move Ordner
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mit diesem Code-Paket hat man die ein paar wichtige Grundlagen, um Kalendereinträge in Outlook zu erstellen. Mit ein bisschen Bastelei kann man mit dem gleichen Grundstock auch nach Einträgen suchen und diese änderen. Das kriegt Wahlo aber sicher selbst hin - ist nicht weiter schwer.

Grüße
EarlFred

Sebastian Schulz · 9. Februar 2021

Hallo earlfred,

auch du hast mit allem Recht

von Sebastian Schulz

Soll nicht als Angriff oder nicht Wertschätzung zu verstehen sein.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

EarlFred · 20. September 2007

Hi Sebastian,
keine Angst, habe ich weder als Angriff noch als Meckerei gesehen *wink.gif* Wäre aber wirklich ein Nice-To-Have...
Grüße
EarlFred

Wahlo · 20. September 2007

Hallo,

leider bin ich nicht VBA-fit.

Eine (bzw. zwei) letzte Frage(n):

1. Es soll bspw. für jedes eingetragene Datum in Spalte P (viele Zellen sind leer) ein Termin erstellt werden - wie genau funktioniert das mit der Schleife?
Bei mir klappt die Terminerzeugung nur in Zelle A1, wie in Deinem Beispiel.

2. Königsdisziplin:
Wenn z. B. in Zelle P4 ein Datum steht, soll wie gehabt der Termin erzeugt werden, allerdings soll in diesem Fall im Termin-Body oder Termin-Subject der der Inhalt der benachbarten Zelle P5 stehen!

Sprengt das den Rahmen Eurer Hilfsbereitschaft?
*Smilie *wink.gif*

Vorab vielen Dank

EarlFred · 20. September 2007

\@Wahlo
Wer so nett fragt, bekommt auch 'ne Antwort! *wink.gif*

Mit der Zelle A1 war die benannte Einschränkung. So wie Du es willst, sollte es wie folgt klappen (ungetestet!):

Code:

Sub Eintrag_bei_Outlook()

Dim OlApp As Outlook.Application
Dim OLSess As Outlook.Namespace
Dim Termin As Outlook.AppointmentItem
Set OlApp = Outlook.Application
Set OLSess = OlApp.GetNamespace("MAPI")
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar)

On Error Resume Next
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders("Erinnerungen")
If Err Then
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders.Add("Erinnerungen")
Err.Clear
End If

For i = 1 To Cells(Rows.Count, 16).End(xlUp).Row

If IsDate(Cells(i, 16)) Then
Set Termin = OlApp.CreateItem(olAppointmentItem)
With Termin
.Subject = Cells(i, 17)
'oder
' .Subject = Cells(i+1, 16)
.Body = "Hier folgt eine genaue Beschreibung"
.Start = DateValue(Cells(i, 16)) + TimeValue("10:00:00")
.Duration = 0
.ReminderMinutesBeforeStart = 43200 '=30 Tage
.ReminderSet = True
.Categories = "Erinnerungen"
.Save
.Move Ordner
End With
End If
Next i

Set OlApp = Nothing
Set OLSess = Nothing
Set Ordner = Nothing
Set Termin = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ach ja, ob mit "Nachbarzelle" von P4 wirklich P5 gemeint war, wollte ich nicht so recht glauben - habe mal Q4 angenommen. Ansonsten bei der Befehlszeile ".Subject" die Kommentierung ändern!

Grüße
EarlFred

Wahlo · 20. September 2007

Hallo,

das hilft mir sehr weiter!

Das einzige, was noch nicht funktioniert ist, das löschen der alten Einträge.
So dass nach Änderungen und erneuter Makroausführung die Termine doppelt drin stehen.

Ließe sich das umgehen, wenn ich vorher ein Makro ausführe, welches "Erinnerungen" löscht?

Könnt Ihr mir noch ein solches Makro zeigen? Dann lass ich Euch auch in Ruhe *Smilie ........ zumindest für heute!!! *wink.gif*

EarlFred · 20. September 2007

Hallo Wahlo,

für die "Holzhammer-Methode" habe ich noch Zeit, dann muss ich los:

Code:

Sub Eintrag_bei_Outlook()

Dim OlApp As Outlook.Application
Dim OLSess As Outlook.Namespace
Dim Termin As Outlook.AppointmentItem
Set OlApp = Outlook.Application
Set OLSess = OlApp.GetNamespace("MAPI")
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar)

On Error Resume Next
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders("Erinnerungen")
If Err Then
Set Ordner = OLSess.GetDefaultFolder(olFolderCalendar).Folders.Add("Erinnerungen")
Err.Clear
End If

For i = Ordner.Items.Count To 1 Step -1
Ordner.Items(i).Delete
Next

For i = 1 To Cells(Rows.Count, 16).End(xlUp).Row

If IsDate(Cells(i, 16)) Then
Set Termin = OlApp.CreateItem(olAppointmentItem)
With Termin
.Subject = Cells(i, 17)
'oder
' .Subject = Cells(i+1, 16)
.Body = "Hier folgt eine genaue Beschreibung"
.Start = DateValue(Cells(i, 16)) + TimeValue("10:00:00")
.Duration = 0
.ReminderMinutesBeforeStart = 43200 '=30 Tage
.ReminderSet = True
.Categories = "Erinnerungen"
.Save
.Move Ordner
End With
End If
Next i

Set OlApp = Nothing
Set OLSess = Nothing
Set Ordner = Nothing
Set Termin = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Anmerkung:
Erst werden ALLE Einträge im Kalender "Erinnerungen" gelöscht, dann die neuen hinzugefügt. Kann also schlimmstenfalls etwas dauern, je nach Zahl der Einträge.

Grüße
EarlFred

Wahlo · 20. September 2007

Genial!

Vielen Dank...

Echt super!

EarlFred · 20. September 2007

\@Wahlo,

na gerne doch! Danke für's tolle Feedback.

Grüße
EarlFred

Office: (Office 2007) Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen?

Aus Spalte mit Datum eine Erinnerung erzeugen? - Similar Threads - Spalte Datum Erinnerung

Spalte=andere Spalte, Datum ist aber nicht mehr durcusuchbar

Zählen innerhalb einer Spalte X, wenn in Spalte Y Datum steht

SVERWEIS findet nur Datum aus einer Spalte

Älter als Datum (in 2 Spalten) = "Entsorgen"

Bestimmte Spalten farblich markieren wenn Datum bzw. ein Wochentag erfüllt

Feldauswahl - neu Spalte mit Datumauswahl

Zelle in Spalte D färben, wenn Datum in Spalte C