Office: Ausdruck in Makro durch Zellbezug ersetzen

Hallo liebe Leute,

ich habe ein Makro, das in einem Bereich etwas sucht und ersetzt. Dann springt es einen Bereich weiter nach rechts (nächste Spalte) und macht da dasselbe.

Allerdings soll das Makro in jeder Spalte einen anderen Wert einsetzen, den es sich erst aus der Tabelle besorgen soll. Und zwar soll es der Wert sein, der eine Zelle über dem gerade markierten Suchbereich ist.

Wie kann ich also in dem folgenden Makro den Ausdruck Anmerkung ersetzen durch diesen Zellbezug? Hab schon mal versucht, das einzusetzen:

Replacement:="ActiveCell.Offset(1, 0).value"

Dann wirft er mir aber nur den Text "ActiveCell.Offset(1, 0).value" aus

Könnt Ihr mir weiterhelfen?

Hier das Makro:

Sub XErsetzen()
'
' XErsetzen Makro
'
Sheets("KomplettQuer").Select
Range("A2").Select


'Er soll das 100mal machen...

For A = 1 To 100


'In nächste Spalte nach rechts gehen
'
ActiveCell.Offset(0, 1).Select

'Kopieren

Selection.Copy

'
'Einen nach unten gehen in den Bereich der "Xe"
ActiveCell.Offset(1, 0).Select

'Markieren

Dim Alt As String, Neu As String
Alt = Selection.Address
Selection.Resize(1500, 1).Select
' wobei Resize die Größe (dh. Anzahl der Zeilen (hier 1)
' und Spalten (hier 5) des entsprechenden Bereiches neu festlegt.
Neu = Selection.Address


'Jetzt soll er ersetzen X durch den oben kopierten Wert, aber das klappt nicht - er fügt einfach das Wort ein, was in der Ersetzenmaske schon vorher drin stand - nämlich "Anmerkung"

Selection.Replace What:="x", Replacement:="Anmerkung", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False

'In die Zelle oben drüber gehen
ActiveCell.Offset(-1, 0).Select


'Und wieder von vorne beginnen (100mal...)

Next A


End Sub


Tausend Dank für Eure Antworten!!!

 

Hallo,

meinst Du ein Makro wie folgendes?

Code:

Option Explicit

Sub XErsetzen()
  
  Dim A As Integer
  Dim txtErsetz As String
  Dim RngBereich As Range
  
  Sheets("KomplettQuer").Activate
  Set RngBereich = Range("A2")
  
  For A = 1 To 100
    Set RngBereich = RngBereich.Offset(0, 1)
    With RngBereich
      txtErsetz = .Value
      .Offset(1, 0).Resize(1500, 1).Replace what:="x", replacement:=txtErsetz, _
             LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, _
             searchformat:=False, ReplaceFormat:=False
    End With
  Next A

End Sub

 

Hallo Exl121150,

danke für den Hinweis. Die Frage hat sich (leider) gerade für mich erledigt und ich habe das entsprechende Tabellenblatt nun auch nicht mehr in der Form. Daher kann ich das Makro nicht überprüfen.

Es scheint meine Frage aber richtig zu beantworten. Daher wird es wohl für viele zukünftigen Forenbesucher wertvoll sein!!

Danke also nevertheless!!

LG
Fin