Office: (Office 365) Ausgangsbasis Datum

Hallo,

=SUMMEWENNS(Kunden!F:F; Kunden!C:C;">="&DATUM(B2;A2;1); Kunden!C:C;"<="&MONATSENDE(DATUM(B2;A2;1);0))
wenn im Arbeitsblatt Kunden die Spalte F summiert werden soll, wobei in Spalte C die Datumkriteriumsspalte enthalten ist und in B2 das Kriteriumsjahr und in A2 der Kriteriumsmonat, der zur Gänze summiert werden soll.

 

perfekt vielen dank exl121150 :-)

 

jetzt fummel ich gerade hier herum aber mit anderen bedingungen
und zwar würde ich gerne die summe von den metern aus spalte F fortlaufend zum (monat,Jahr) ermitteln

 

Hallo,

da ich gerade erst sehe, dass du Excel365 dein Eigen nennst, kann man die Formel (Posting#16) vereinfachen zu:
=LET(dt; DATUM(B2;A2;1); SUMMEWENNS(Kunden!F:F; Kunden!C:C;">="&dt; Kunden!C:C;"<="&MONATSENDE(dt;0)))

zu deinem Posting#18: Was heißt hier "fortlaufend zum (Monat,Jahr)" ?
Heißt das: Summieren vom 1.Januar eines Jahres bis zum Ende eines Monats des betreffenden Jahres?
=LET(dtA;DATUM(B2;1;1); dtE; MONATSENDE(dtA; A2); SUMMEWENNS(Kunden!F:F; Kunden!C:C;">="&dtA; Kunden!C:C;"<="&dtE))

 

danke für deine antwort exl121150. mir wären die alten methoden der formeln lieber, die kann ich nachvollziehen, mit den neuen bin ich nicht bewandert.
ich versuch es zu erklären
also im jänner waren es zb. 50m, im febrauer waren es 20m (ergibt aber für februar 70m), märz 70m (ergibt dann 140m)

mit zählenwenn (=ZÄHLENWENN('Kunden'!C:C;"<="&D2)) hat das gut funktioniert = kundenstand
nur möchte ich jetzt eben nicht die anzahl haben sondern eben die summe von den metern = fortlaufendes meterwachstum pro monat

Kundentabelle:
C = datumsangabe
F = meter
Berichttabelle:
A = Monat
J = Jahr
T (kommt die Formel)

 

Hallo,

was ist da so schwierig? Wenn ich meine letzte Formel hernehme:
=LET(
dtA;DATUM(B2;1;1);
dtE; MONATSENDE(dtA; A2);
SUMMEWENNS(Kunden!F:F; Kunden!C:C;">="&dtA; Kunden!C:C;"<="&dtE)
)
Das einzig Neue ist die äußere Funktion =LET(...), die Variablen enthält, deren Namen man selbst vergeben kann und denen man Werte mit Hilfe von Formeln zuweisen kann:
1.benannte Variable: dtA wird der Wert der Formel DATUM(B2;1;1) zugewiesen. Enthält die Zelle B2 zB. 2022 erhält damit die Variable den Datumswert 1.1.2022 (1.Jänner 2022)
2.benannte Variable: dtE wird der Wert der Formel MONATSENDE(dtA; A2) zugewiesen. Steht in Zelle A2 die Monatszahl bis zu der summiert werden soll, zB. 8 (für August in 2022), dann hat dtE durch die Formel MONATSENDE(dtA; 8) den Wert 31.08.2022
Resultat der LET-Funktion steht im letzten Formelausdruck:
SUMMEWENNS(Kunden!F:F; Kunden!C:C; ">="&dtA; Kunden!C:C;"<="&dtE),
wobei man sich statt dtA den 1.1.2022 und statt dtE den 31.08.2022 eingesetzt denken muss.

dann wird doch hoffentlich folgende Formel auch gut funktionieren:
=SUMMEWENNS(Kunden!F:F; Kunden!C:C; "<="&D2)

 

super, das mit summewenns hat prima funktioniert - danke dir

jetzt hab ich was wirklich schweres, ich denke danach hab ich alles.

ich hab ein tabellenblatt das heißt Kundenkontakte. hier werden alle kunden erfasst die sich mit mir in verbindung setzen
Spalte A: hab ich mir das Monat erstellt
Spalte B: ist das Jahr
Spalte C: ist die Kalenderwoche
Spalte D: ist das Datum der Kontaktaufnahme
Spalte E: kunde
Spalte F: wie wir gefunden wurden (google, empfehlung usw)
Spalte G: wie wir kontaktiert wurden (gebucht, anruf, kontaktanfrage usw..)
Spalte H: Standort (3 Standorte)

Im Tabellenblat Bericht
Spalte AB - hab ich die Anfragen
Hier hätte ich gerne bitte, die Anzahl der Anfragen im jeweiligen Monat zb. Jänner 2020, mit wie wir kontaktiert wurden außer gebucht, unentschlossen, für den standort wien haben.

ich denke es ist wieder summewenns, nur weiß ich nicht wie ich bedingungen auschließen kann..

 

=ZÄHLENWENNS('SR Kundenkontakte'!G:G;'SR Kundenkontakte'!L8:L22;'SR Kundenkontakte'!H:H;'SR Kundenkontakte'!$M$5;'SR Kundenkontakte'!D:D;">="&C2;'SR Kundenkontakte'!D:D;"<="&D2)

SRKundenkontakteL8:L22:
-Gebucht
Anruf
Calendly
Cold Calling
Chatbot
E-Mail
Empfehlung Partner
Empfehlung Kunde
Facebook
internes Netzwerk
sonstiges
Kontaktanfrage
Newsletter
-irgendwas
video

ich hätte gerne das er alles mitzählt, jedoch die mit "-" davor nicht.. da steh ich an...

 

diese formel hat sich erledigt - wäre jedoch nett zu wissen wie sie funktioniert.

 

Hallo,

in der beiliegenden Datei habe ich dir 2 Arbeitsblätter erstellt nach deinen Vorgaben.
In der Zelle Tabelle2!F2 habe ich die (nicht mehr benötigte) Abfrageformel eingefügt:
=LET(AnzJeKontakt;ZÄHLENWENNS(TbKundenKontakte[Kontakt];TbKontaktarten[Arten]; TbKundenKontakte[Standort];'SR Kundenkontakte'!$M$5;TbKundenKontakte[Dat_Kontakt];">="&$C$2;TbKundenKontakte[Dat_Kontakt];"<="&$D$2);
AnzAlleKontakte; SUMME(AnzJeKontakt);
AnzStrichKontakt; SUMME((AnzJeKontakt)*(LINKS(TbKontaktarten[Arten])="-"));
(AnzAlleKontakte-AnzStrichKontakt))

 

vielen lieben dank :-)