Office: (Office 2007) Auslesen Text und Zahl um eins erhöhen

anton100 · 2. Juni 2009

Hallo Forum,
ich habe in der Zelle A1 den Text "Tafel" stehen. Nun möchte ich gerne ab der Zeile A21 den Text "Tafel" eintragen mit einem "_" und da es die erste Zeile ist den Wert 1 hinzufügen.

Wenn jetzt eine neue Zeile mit dem Makro eingefügt wird, soll das Makro die höchste Zahl din der Spalte A ermitteln. Da in der Spalte die Zahlen gemischt vorkommen sollte das Makro die höchste Zahl aus der Zeichenfolge ermitteln.
Anschließend soll eine neue Spalte eingefügt werden und in der Zelle A zu der Zahl höchsten Zahl ein addiert werden.

Vielen Dank im Voraus Anton

:)

BoskoBiati · 4. Juni 2009

Hallo Anton,

in Deinem Beitrag scheinen die Begriffe Zeile und Spalte wild durcheinander zu laufen. Schwer zu durchschauen ist auch dieser Satz:

Anschließend soll eine neue Spalte eingefügt werden und in der Zelle A zu der Zahl höchsten Zahl ein addiert werden.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Bitte kläre doch die Leser etwas besser auf, ggf. mit einer Beispieldatei.

jinx · 4. Juni 2009

Moin, Anton,

die "einfache" Methode wäre eine Schleife und die VBA-Funktion SPLIT, mit der die Zahl vom Text getrennt werden und mit dem Wert der Variable für Max vergleichen werden könnte. Noch einfacher wäre aber das Schreiben der Zahl in eine Hilfsspalte und Auswerten mit der Max-Funktion dort (sag jetzt nicht, dass Du bei Excel2007 alle Spalten ausgefüllt hast *wink.gif*)...

anton100 · 4. Juni 2009

Hallo,

ich habe mal ein Datei angehängt, in der mein erster Versuch eines Makros war.
Das Blatt Start zeigt den Ursprung, das Blatt ziel zeigt das Ergebnis mit zwei eingefügten Zeilen.

Das ganze soll allerdings auf einem Blatt erfolgen

Habt Ihr eine Idee?

jinx · 5. Juni 2009

Moin, Anton,

die einfachste Methode wäre das Speichern des Maximums in B1 z.B.

Code:

Sub anton()
Dim lngLastRow As Long
Dim lngCounter As Long
Dim lngMax As Long

lngLastRow = Cells(Rows.Count, "A").End(xlUp).Row
For lngCounter = 20 To lngLastRow
lngMax = WorksheetFunction.Max(lngMax, fncJustNumbers(Cells(lngCounter, "A")))
Next lngCounter

ActiveCell.Offset(1, 0).EntireRow.Insert
ActiveCell.Offset(1, 0).Value = Range("A1").Value & "_" & lngMax + 1

End Sub

Function fncJustNumbers(rngCell As Range) As Long

Dim lngCounter As Long

With rngCell
For lngCounter = 1 To Len(.Value)
Select Case Asc(Mid(.Value, lngCounter, 1))
Case 48 To 57
fncJustNumbers = fncJustNumbers & Mid(.Value, lngCounter, 1)
End Select
Next lngCounter
End With

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

wobei man die Funktion umschreiben könnte auf InStrRev und bis zum Unterstrich...

anton100 · 14. Juni 2009

Danke für die Lösung jinx, ich habe die Lösung sehr gut gebrauchen könne. Eine Frage noch, kannst Du mir die Case Funktion kurz erklären? Was bedeuten 48 to 57, worauf bezieht sich das?

Select Case Asc(Mid(.Value, lngCounter, 1))
Case 48 To 57
fncJustNumbers = fncJustNumbers & Mid(.Value, lngCounter, 1)
End Select

Gruß Anton

jinx · 15. Juni 2009

Moin, Anton,

die ASCII-Angaben der Zeichen 48 bis 57, die ausgeschrieben den Zahlen 0 bis 9 entsprechen. In diesem Fall wird der Inhalt einer Zelle Zeichen für Zeichen durchlaufen und geprüft.

Alternativer Lösungsvorschlag:

Code:

Public Function NurZahlen(zelle)
Dim Regex As Object
Set Regex = CreateObject("Vbscript.Regexp")
With Regex
.Pattern = "\D"
.Global = True
NurZahlen = .Replace(zelle, "")
End With
Set Regex = Nothing
End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

anton100 · 21. Juni 2009

Hallo jinx,
ich habe zu der Lösung noch eine kleines Problem, vieleicht kannst Du mir dabei auch noch helfen?
Ich habe wie in dem Beispiel verschieden Einträge in Spalte A. Die Nummer soll aber nur hochgezählt werden, wenn eine Übereinstimmung mit Zelle A1 gegeben ist. In dem Beispiel müsste die nächste Nummer Medien_7 sein.

Hast Du dazu auch eine Lösung?

Gruß Anton

jinx · 22. Juni 2009

Moin, Anton,

Code:

Sub anton2()
Dim lngLastRow As Long
Dim lngMax As Long
Dim rngCell As Range

lngLastRow = Cells(Rows.Count, "A").End(xlUp).Row
For Each rngCell In Range("A20:A" & lngLastRow).SpecialCells(xlCellTypeConstants, 23)
If InStr(1, rngCell.Value, Cells(1, 1).Value) > 0 Then lngMax = WorksheetFunction.Max(lngMax, fncJustNumbers(rngCell))
Next rngCell

ActiveCell.Offset(1, 0).EntireRow.Insert
ActiveCell.Offset(1, 0).Value = Range("A1").Value & "_" & lngMax + 1

End Sub

Function fncJustNumbers(rngCell As Range) As Long

Dim lngCounter As Long

With rngCell
For lngCounter = 1 To Len(.Value)
Select Case Asc(Mid(.Value, lngCounter, 1))
Case 48 To 57
fncJustNumbers = fncJustNumbers & Mid(.Value, lngCounter, 1)
End Select
Next lngCounter
End With

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

anton100 · 22. Juni 2009

Hallo jinx,
leider geht das Makro noch nicht vollständig Richtig.
Wenn ich nur eine Zahl mit 10 habe und eine Eintrag mit "Medien_60" (Zelle A1 ist leer) soll die Zahl von 10 auf 11 erhöht werden. Im Moment nimmt er jedoch den höchsten Wert den er finden kann 60 und macht daraus die Zahl 61 anstelle von 11.

Wenn in A1 ein Eintrag enthalten ist, funktioniert das Makro super gut.
Hast Du noch eine Idee?

Gruß Anton

jinx · 23. Juni 2009

Moin, Anton,

wenn Du die Voraussetzungen für das Makro umstellst, darfst Du Dich nicht wundern, dass das Makro diese Änderung nicht versteht und es auch nicht umsetzen kann.
Code:

Sub anton2()
Dim lngLastRow As Long
Dim lngMax As Long
Dim rngCell As Range
Dim rngArea As Range

lngLastRow = Cells(Rows.Count, "A").End(xlUp).Row
If IsEmpty(Range("A1")) Then
Set rngArea = Range("A20:A" & lngLastRow).SpecialCells(xlCellTypeConstants, 1)
Else
Set rngArea = Range("A20:A" & lngLastRow).SpecialCells(xlCellTypeConstants, 2)
End If
If IsEmpty(Cells(1, 1).Value) Then
lngMax = WorksheetFunction.Max(rngArea)
Else
For Each rngCell In rngArea
If InStr(1, rngCell.Value, Cells(1, 1).Value) > 0 Then lngMax = WorksheetFunction.Max(lngMax, fncJustNumbers(rngCell))
Next rngCell
End If

ActiveCell.Offset(1, 0).EntireRow.Insert
ActiveCell.Offset(1, 0).Value = Range("A1").Value & "_" & lngMax + 1

End Sub

Function fncJustNumbers(rngCell As Range) As Long

Dim lngCounter As Long

With rngCell
For lngCounter = 1 To Len(.Value)
Select Case Asc(Mid(.Value, lngCounter, 1))
Case 48 To 57
fncJustNumbers = fncJustNumbers & Mid(.Value, lngCounter, 1)
End Select
Next lngCounter
End With

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: (Office 2007) Auslesen Text und Zahl um eins erhöhen

Auslesen Text und Zahl um eins erhöhen

Auslesen Text und Zahl um eins erhöhen

Auslesen Text und Zahl um eins erhöhen

Auslesen Text und Zahl um eins erhöhen

Auslesen Text und Zahl um eins erhöhen - Similar Threads - Auslesen Text Zahl

Wort aus Index aus Text in Zelle auslesen

Anzahl aus Text auslesen

Text zwischen zwei Zeichen auslesen

text und zahlen aus zelle auslesen

Text auslesen und in Textfelder schreiben

Excel VBA Datum aus Text auslesen

Zahl + Text in einer Zelle -- Zahl Auslesen