Office: Auswahl und Inhalt mehrerer Zellen verknüpfen

Helfe beim Thema Auswahl und Inhalt mehrerer Zellen verknüpfen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo Community, ich würde gerne 2 Zellen in denen die selbe Dropdownliste enthalten ist so miteinander verknüpfen, dass der Inhalt beider Zellen... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von PhilippThr, 10. April 2014.

  1. Auswahl und Inhalt mehrerer Zellen verknüpfen


    Hallo Community,

    ich würde gerne 2 Zellen in denen die selbe Dropdownliste enthalten ist so miteinander verknüpfen, dass der Inhalt beider Zellen identisch ist.

    Sprich wähle ich in Tabellenblatt 1 in meiner Liste a, b oder c aus, soll meine getroffene Auswahl in Tabellenblatt 2 angezeigt werden. Möchte ich in Tabellenblatt 2 meine Entscheidung von vorher revidieren und beispielsweise nicht mehr a sondern c wählen soll der Inhalt in Tabellenblatt 1 automatisch angepasst werden.

    Im Endeffekt möchte ich also mehrere Auswahlfelder für den gleichen Inhalt erzeugen.

    Ich hoffe ihr könnt mir bei der Lösung dieses Problems helfen.
    Dafür vielen Dank im voraus :)
     
    PhilippThr, 10. April 2014
    #1
  2. Beverly
    Beverly Erfahrener User
    Hi,

    dazu musst du VBA verwenden und zwar das Change-Ereinigs beider Tabellenblätter. Um genaueres sagen zu können müsste man wissen, in welchen Zellen sich die DropDown-Listenfelder befinden.

    Bis später,
    Karin
     
    Beverly, 10. April 2014
    #2
  3. Danke für die schnelle Antwort,

    die genaue Position dieser Felder steht bisher noch nicht wirklich fest, da die Datei noch im Aufbau ist.
    Ist die Position denn noch entscheidend wenn man die Felder über den Namen des Bereichs ansteuert?

    Mit VBA kenne ich mich leider noch nicht wirklich aus. Da würde ich mich gerne erstmal reinarbeiten und in Kürze nochmal auf die Lösung dieses Problems zurückkommen.

    Gruß Philipp
     
    PhilippThr, 10. April 2014
    #3
  4. Beverly
    Beverly Erfahrener User

    Auswahl und Inhalt mehrerer Zellen verknüpfen

    Sicher ist das von Interesse, denn mit dem Change-Ereignis muss man die Zellen ansprechen, in denen sich die Gültigkeit befindet.

    Angenommen in Tabelle1 ist es Zelle A10 und in Tabelle2 ist es B12. Dann würde folgender Code im Codemodul der Tabelle1

    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       If Target.Address = "$A$10" Then Worksheets("Tabelle2").Range("B12") = Target
    End Sub
    
    den Inhalt von B12 in Tabelle2 anpassen und dieser Code

    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       If Target.Address = "$B$12" Then Worksheets("Tabelle1").Range("A10") = Target
    End Sub
    
    passt dann den Inhalt von A10 in Tabelle1 an.

    Bis später,
    Karin
     
    Beverly, 10. April 2014
    #4
  5. Ah ok,

    dann kommen wir mal zu den detailierteren Informationen.

    Wir haben also die Tabellenblätter "Projekt", "2.4.3" und "Listen".

    In Tabellenblatt "Projekt" geht es um die Zelle F101 und in Tabellenblatt "2.4.3" um die Zelle F5.
    In diesen beiden Zellen steht aktuell eine Datenprüfung -> Liste -> =INDIREKT(Listen!$I$18)

    Im Tabellenblatt Listen steht in I18 der Name der Liste die wiedergegeben werden soll.
    Dieser Name setzt sich aus Variablen zusammen damit auf Grund einer vorherigen Angabe verschiedene Listen angesteuert werden können.

    Falls noch mehr Informationen nötig sein sollten liefere ich diese gerne nach.

    Danke :)
     
    PhilippThr, 10. April 2014
    #5
  6. Beverly
    Beverly Erfahrener User
    Ersetze in meinem Code "$A$10" durch "$F$101", "Tabelle2" durch "2.4.3" sowie "$B$12" durch "$F$5", "Tabelle2" durch "Projekt". Der erste Code gehört demnach ins Codemodul des Tabellenblattes "Projekt" und der zweite ins Codemodul des Tabellenblattes "2.3.4"

    Bis später,
    Karin
     
    Beverly, 10. April 2014
    #6
  7. Ich habe das natürlich gleich mal ausprobiert, leider klappt es noch nicht.

    Im Blatt Projekt steht also

    Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$F$101" Then Worksheets("2.4.3").Range("$F$5") = Target
    End Sub

    und im Blatt 2.4.3

    Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$F$5" Then Worksheets("Projekt").Range("$F$101") = Target
    End Sub

    In den beiden Dropdownlisten im VBA-Tool ist jeweils Worksheet und Change ausgewählt.
    Den Dateityp musste ich dann beim speichern in eine Makro-Variante ändern und habe .xlsm gewählt.
     
    PhilippThr, 10. April 2014
    #7
  8. Beverly
    Beverly Erfahrener User

    Auswahl und Inhalt mehrerer Zellen verknüpfen

    Und WAS klappt nicht?

    Bis später,
    Karin
     
    Beverly, 10. April 2014
    #8
  9. Anbei die Datei
     
    PhilippThr, 11. April 2014
    #9
  10. Beverly
    Beverly Erfahrener User
    Ändere den Code wie folgt:

    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       If Target.Address = "$F$101" Then
          Application.EnableEvents = False
          Worksheets("2.4.3").Range("$F$5") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       If Target.Address = "$F$5" Then
          Application.EnableEvents = False
          Worksheets("Projekt").Range("$F$101") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    Bis später,
    Karin
     
    Beverly, 11. April 2014
    #10
  11. Perfekt! Es klappt, danke :)

    Dazu ergeben sich jetzt noch folgende Fragen:
    - wenn ich über den benannten Zellen Zeilen einfüge, wird dies dann angepasst oder funktioniert diese Formatierung dann nicht mehr?
    - wie verhält es sich wenn ich weitere Zellen damit verknüpfen will, beispielsweise Zelle F10 in "Blatt 3.4.1"?
    - ist es möglich diese Verknüpfungen über einen relativen Link in eine geschlossene Datei zu verwenden?
     
    PhilippThr, 11. April 2014
    #11
  12. Beverly
    Beverly Erfahrener User
    zu 1.: die Zelladressen passen sich nicht automatisch an - das musst du entweder von Hand im Code ändern oder du vergibst für die Zellen einen Namen, z.B. "Fachbereich_Projekt" und "Fachbereich_2.4.3". Der Code müsste dann so aussehen

    (in Projekt)
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       Dim strName As String
       On Error Resume Next
       strName = Target.Name.Name
       On Error GoTo 0
       If strName = "Fachbereich_Projekt" Then
          Application.EnableEvents = False
          Worksheets("2.4.3").Range("Fachbereich_2.4.3") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    (in 2.4.3)
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       Dim strName As String
       On Error Resume Next
       strName = Target.Name.Name
       On Error GoTo 0
       If strName = "Fachbereich_2.4.3" Then
          Application.EnableEvents = False
          Worksheets("Projekt").Range("Fachbereich_Projekt") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    zu 2.: in dem Fall müsstest du den Code wie folgt erweitern (vorausgesetzt du hast auch dort für die Zelle mit der relevanten Gültigkeit einen Namen vergeben - z.B. "Fachbereich_3.4.1")

    (in Projekt)
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       Dim strName As String
       On Error Resume Next
       strName = Target.Name.Name
       On Error GoTo 0
       If strName = "Fachbereich_Projekt" Then
          Application.EnableEvents = False
          Worksheets("2.4.3").Range("Fachbereich_2.4.3") = Target
          Worksheets("3.4.1").Range("Fachbereich_3.4.1") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    (in 2.4.3)
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       Dim strName As String
       On Error Resume Next
       strName = Target.Name.Name
       On Error GoTo 0
       If strName = "Fachbereich_2.4.3" Then
          Application.EnableEvents = False
          Worksheets("Projekt").Range("Fachbereich_Projekt") = Target
          Worksheets("3.4.1").Range("Fachbereich_3.4.1") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    (und in 3.4.1)
    Code:
    Private Sub Worksheet_Change(ByVal Target As Range)
       Dim strName As String
       On Error Resume Next
       strName = Target.Name.Name
       On Error GoTo 0
       If strName = "Fachbereich_3.4.1" Then
          Application.EnableEvents = False
          Worksheets("2.4.3").Range("Fachbereich_2.4.3") = Target
          Worksheets("Projekt").Range("Fachbereich_Projekt") = Target
          Application.EnableEvents = True
       End If
    End Sub
    
    zu 3.: diese Frage verstehe ich leider nicht - welche Verknüpfung meinst du?

    Bis später,
    Karin
     
    Beverly, 11. April 2014
    #12
  13. Auswahl und Inhalt mehrerer Zellen verknüpfen

    Die ersten beiden Teile funktionieren super.
    Vielen Dank für die ausführliche Erklärung, dadurch wird jetzt auch das Prinzip verständlich :)

    Und zu 3.:
    Ich würde im Idealfall gerne die Tabs aus der Hauptdatei lösen, da es am Ende extrem viele Tabs werden.
    Die Projektdatei liegt also immer im Hauptordner des jeweiligen Projekts. Die aktuellen Tabs hätte ich gerne in Unterordnern.
    Sprich im Hauptordner liegt der Ordner 2. -> 2.4 -> 2.4.3 und darin unser Tab 2.4.3 nun als eigene Datei.
    Da diese Struktur in jedem Projekt gleich ist würde also nur ein relativer und kein absoluter Link in Frage kommen.

    Beste Grüße,
    Philipp
     
    PhilippThr, 16. April 2014
    #13
  14. Beverly
    Beverly Erfahrener User
    Hi Philipp,

    das funktioniert dann nicht mehr. Wenn du einzelnen Tabellenblätter aus der Hauptdatei löschst, dann läuft der Code selbstverständlich auf einen Fehler, da das betreffende Blatt nicht mehr gefunden wird. Man könnte zwar den Code etwas ändern, um diesen Fehler abzufangen, aber dennoch bleibt das Problem, dass man nichts in einer gschlossenen Arbeitsmappe ändern kann. Auch kannst du dann nicht in z.B. abgelegter Mappe 2.4.3, falls du sie wieder öffnest, irgend etwas ändern, was sich dann in der Hauptdatei ändern soll, denn der Bezug zur Hauptdatei ist ja weg und Excel sucht in der Mappe 2.4.3 nach den im Code angegebenen Tabellenblättern.

    Bis später,
    Karin
     
    Beverly, 16. April 2014
    #14
  15. Das ist natürlich schade.

    Ist denn ein einseitiger Informationsaustausch möglich?
    Ich trage also die Daten in der Projektdatei ein. Wenn ich dann meine Datei 2.4.3 öffne wird dort angezeigt was ich vorher im Projekt eingegeben habe und ich kann es dort nach Bedarf ändern. Das diese Änderung wieder im Projekt angezeigt wird wäre mir nicht so wichtig wie die Dateien zu splitten!?
     
    PhilippThr, 16. April 2014
    #15
Thema:

Auswahl und Inhalt mehrerer Zellen verknüpfen

Die Seite wird geladen...
  1. Auswahl und Inhalt mehrerer Zellen verknüpfen - Similar Threads - Auswahl Inhalt mehrerer

  2. Informationen von ausgewählten Variante übertragen

    in Microsoft Excel Hilfe
    Informationen von ausgewählten Variante übertragen: Hallo zusammen, folgendes Problem kann ich nicht lösen: Ich habe beispielsweise mehrere Varianten zur Auswahl, die ich manuell eingebe in Excel. Am Ende entscheide ich mich für eine Variante,...
  3. Datentabelle mit Namen verknüpfen und mittels Dropdownmenü auswählen

    in Microsoft Excel Hilfe
    Datentabelle mit Namen verknüpfen und mittels Dropdownmenü auswählen: Moin zusammen. Ich soll ein Inventurblatt anfertigen, da bei jedem Mitarbeiter nicht benötigte Ausrüstung aussortiert werden soll. Damit nicht für jeden Mitarbeiter ein eigenes Blatt von Grund auf...
  4. Spalten mittels Dropdown-Auswahl ein- und ausblenden

    in Microsoft Excel Hilfe
    Spalten mittels Dropdown-Auswahl ein- und ausblenden: Hallo, ich bin neu hier im Forum. Mein Name ist Guido, ich bin um die 50 Jahre alt und benötige dringend eure Hilfe bei einem Excel-Problem. Ich erstelle gerade eine Checkliste, die über das Jahr...
  5. Popup bei Dropdown Auswahl

    in Microsoft Excel Hilfe
    Popup bei Dropdown Auswahl: Hallo zusammen, ich würde gern bei einem einfachen Dropdown-Sprachenauswahlmenü ein Popup hinzufügen mit einem englischen Hinweistext und "OK" als Bestätigung, wenn auf Englisch umgestellt wird....
  6. Dropdown-Auswahl in andere Zelle einfügen

    in Microsoft Excel Hilfe
    Dropdown-Auswahl in andere Zelle einfügen: Hallo, Ich hab ein Dropdown in einer Zelle. Das Dropdown besteht aus den Auswahlmöglichkeiten "erledigt" und "ausgefallen". Jetzt möchte ich allerdings, dass der ausgewählte Wert aus dem Dropdown...
  7. OptionButtons sollen Zellen auswählen

    in Microsoft Excel Hilfe
    OptionButtons sollen Zellen auswählen: Hallo zusammen Mein Marketingprojekt ist fast fertig, allerdings komme ich bei einer letzten Sache nicht auf die Lösung. Im Anhang könnt ihr mein Tabellenblatt sehen. Durch eine Userform...
  8. Inhalt mit Dropdown aus verschiedenen Excel-Dateien auswählen

    in Microsoft Excel Hilfe
    Inhalt mit Dropdown aus verschiedenen Excel-Dateien auswählen: Hallo zusammen ich möchte ein Lieferantentool per Excel erstellen... Aktueller Stand: Für jeden der aktuell 23 Lieferanten gibt es ein identisch angelegtes Excel-Dokument, in der er...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden