Office: Auswahlfenster einfügen

Hallo,

Dropdown kann ich einfügen mit Verweis auf entsprechende Felder. Aber ich möchte im Rahmen einer Teilnehmerliste ein DropDown Feld einfügen mit einem grünen "Haken" für Teilnahme und ein rotes "X" für nimmt nicht teil... Wie bekomme ich das hin !?

Am besten wäre es auch, wenn die beiden Auswahlfelder links und rechts der jeweiligen Spalte wären, damit man schon am "Versatz" das Ergebnis sieht !?

Oder kann ich auch ohne Dropdown arbeiten, indem ich das linke Feld anklicke erscheint ein Haken und das rechte erscheint ein X. Geht das evtl. auch ?

Kann mir jemand helfen !?
Excell 2007

Danke...

 

Hallo!

In der beiliegenden Excel-Datei habe ich Dir eine VBA-Lösung gebastelt, indem das Doppelklick-Ereignis der Maus entsprechend ausgenutzt wird im Arbeitsblatt "Tabelle1".

 

Wahnsinn ! Genauso habe ich es mir überlegt... VBA !?

Ich muss diese VBA - Lösung in meine Tabelle basteln. Kann ich die Felder einfach kopieren oder wie kann ich diese Funktion in meine Tabelle am einfachsten einbauen ?

Danke nochmal. Echt Klasse !

Gruß

 

Hallo!

Du kannst in diesem Fall keine Felder kopieren, weil es keine solchen gibt.
Die alles entscheidende Subroutine zur Ereignisbehandlung des Mause-Doppelklicks für Arbeitsblatt "Tabelle1" befindet sich im Codemodul dieses Arbeitsblattes.
Erreichbar ist das Ganze vom Arbeitsblatt aus wie folgt:
1) Tastenkombination Alt+F11, um in den VBA-Editor zu gelangen
2) Tastenkombination Strg+R, um das Projekt-Fenster im VBA-Editor anzuzeigen
3) In diesem Projektfenster den Eintrag "Tabelle1" markieren und dann F7 drücken => Dadurch wird das Codemodul vom Arbeitsblatt "Tabelle1" im VBA-Editor angezeigt.
Du siehst dann folgenden Visual-Basic-Code:

Code:

Option Explicit
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
   Dim Ok As Boolean
   With Target
      If .Cells.Count <> 1 Then Exit Sub
      If .Column < 2 Or .Column > 3 Then Exit Sub
      
      'Spalte A darf nicht leer sein
      If IsEmpty(Cells(.Row, 1)) Then Exit Sub
      
      Ok = .Column = 2
      If IsEmpty(.Value) Then
        .Value = IIf(Ok, Chr(214), Chr(196))
        With .Font
          .Color = IIf(Ok, vbGreen, vbRed)
          .Name = "Symbol"
        End With
        .HorizontalAlignment = xlCenter
        .Offset(0, IIf(Ok, 1, -1)).Value = ""
      Else
        .Value = ""
      End If
   End With
End Sub

Dieser Code muss in das Codemodul eines anderen Arbeitsblattes kopiert werden, damit in diesem Arbeitsblatt auch diese Funktionalität zur Verfügung steht.
Ein paar Worte zur Code-Erklärung:
Die Variable "Target" ist eine Zellbereichsvariable und speichert den gerade markierten Zellbereich, in dem der Doppelklick mit der Maus ausgeführt wurde.
Zuerst wird abgefragt, ob dieser Zellbereich nur aus 1 Zelle besteht - falls nicht, wird das Programm verlassen (If .Cells.Count <> 1 Then Exit Sub)
Mit .Column wird die Spaltennummer der markierten Zelle abgefragt: Ist diese weder 2 noch 3, wird ebenfalls das Programm verlassen (If .Column < 2 Or .Column > 3 Then Exit Sub)
Dann wird noch geprüft, ob in Spalte 1 (=Spalte A) ein Zellinhalt vorhanden ist: falls nicht, so wird das Programm verlassen (If IsEmpty(Cells(.Row, 1)) Then Exit Sub)
Falls sich die Zelle in Spalte 2 (=Spalte B) befindet, wird die Boolesche Variable "Ok" auf "True" gesetzt, falls es sich um Spalte 3 (Spalte C) handelt, wird "Ok" auf "False" gesetzt (Ok = .Column = 2). Diese Variable wird im Folgenden in den 3 IIf-Funktionen ausgewertet, um jeweils 2 verschiedene Werte aufzurufen.
Dabei verhält sich die VBA-Funktion "IIf(..)" genauso wie die "WENN(...)"-Funktion im Arbeitsblatt.

 

Hallo,

sry, dass ich mich erst jetzt melde. Habe es nicht hinbekommen und musste es an einen Kollegen weiterleiten, der sich besser auskennt. Vielen Dank für deine Mühe und die klasse Umsetzung.

Gruß,
dive