Office: Auswertung eines Schätzspiels

Hallo zusammen!

Ich habe Probleme bei der Auswertung eines Schätzspiels. Die Daten werden über ein Online-Formular übertragen und pro Person bis zu 5 Tipps gesammelt.
Ich würde gerne die Auswertung auf einem zweiten Tabellenblatt haben, wo ich nur das Ergebnis eintragen muss und dann die Namen der 15 besten Tipps (positive sowie negative Abweichung) ausgegeben bekomme. Wenn eine Person zwei gute Tipps abgegeben hat, soll hier nur der bessere gezählt werden.
Ich habe es schon mit den Funktionen Index und Match versucht, komme hier aber nicht wirklich weiter.
Hat jemand von euch Tipps, wie ich es noch versuchen könnte?

Danke schon Mal!

 

Hi,

da du keine Version angegeben hast, gehe ich davon aus, dass du ein aktuelles Excel hast (365 oder 2021)
in Werte!H2: =LET(a;C2:G2;b;Auswertung!$B$1;c;ABS(b-a);d;MIN(c);e;XVERWEIS(d;c;a);HSTAPELN(d;e))
runter ziehen
in Auswertung!B4: =SPALTENWAHL(SORTIEREN(Werte!B2:I4;7);1;-1)

 

Hallo,

meine Version geht von einem Excel365 aus.
Im Namensmanager habe ich folgende Lambda-Funktion "Platzierungen" eingefügt:

Im Arbeitsblatt "Auswertung" habe ich in Zelle B4 folgende Formel eingefügt:
=Platzierungen(Werte!$B$2:$G$4; $B$1; 10)

 

Hi,

hier noch eine Formel für H2 ohne runter ziehen:

Code:

=LET(a;C2:G4;
b;Auswertung!$B$1;
c;ABS(b-a);
d;NACHZEILE(c;LAMBDA(x;MIN(x)));
e;HSTAPELN(d;c);
f;NACHZEILE(e;LAMBDA(x;XVERGLEICH(ÜBERNEHMEN(x;;1);WEGLASSEN(x;;1))));
g;HSTAPELN(f;a);
h;NACHZEILE(g;LAMBDA(x;SPALTENWAHL(x;ÜBERNEHMEN(x;;1)+1)));
i;HSTAPELN(d;h);
i)

Dabei bedeuten
a: Bereich der Tipps
b: Vergleichswert aus Blatt "Auswertung"
c: Diff zum Vergleichswert
d: Minium aus c
e: Matrix d:c
f: Pos von d in c
g: Matrix f:a
h: Wert an Pos f in a
i: Matrix d:h sprich kleinster Abstand eines Tipps und Tipp