Office: Auswertung funktioniert nicht

Hallo,

manchmal verstehe ich einfach nicht was in EXCEL schief läuft.
Ich hatte hier im Forum mal eine Frage zu großen Datenmengen und deren Auswertung geschrieben.
Naja, irgendwann war das Problem dann auch gelöst und ich habe munter ein paar verschiede Daten ausgewertet, bis zum heutigen Tag.

Ich sitze jetzt schon mindestens zwei Stunden davor und bekomme die Sache einfach nicht hin. Die Tabelle zeigt mein Problem. Die Berechnungen werden Alles alle als WERT zurückgegeben.

	A	B	C	D	E	F	G
1	ob_time		air_temperature
2						27.02. 07:00	27.02. 08:00
3	27.02.1997	07:00	5		1997	#WERT!	#WERT!
4	27.02.1997	08:00	5		1998
5	27.02.1997	09:00	6

Zelle	Format	Wert
A1	TT.MM.JJJJ	ob_time
B1	hh:mm
A2	TT.MMM - hh:mm;@
B2	TT.MMM - hh:mm;@
C2	TT.MMM - hh:mm;@
D2	TT.MMM - hh:mm;@
F2	TT.MM. hh:mm	27.02.2010 07:00:00
G2	TT.MM. hh:mm	27.02.2010 08:00:00
A3	TT.MM.JJJJ	27.02.1997 07:00:00
B3	hh:mm	07:00
A4	TT.MM.JJJJ	27.02.1997 08:00:00
B4	hh:mm	08:00
A5	TT.MM.JJJJ	27.02.1997 09:00:00
B5	hh:mm	09:00

Zelle	Formel
B3	=TEXT(A3;"hh:mm")
F3	=SUMMENPRODUKT((JAHR($A$3:$A$51798)=$E3)*(TAG($A$3:$A$51798)=TAG(F$2))*(MONAT($A$3:$A$51798)=MONAT(F$2))*(STUNDE($B$3:$B$51798)=STUNDE(F$2))*$C$3:$C$51798)
G3	=SUMMENPRODUKT((JAHR($A$3:$A$51798)=$E3)*(TAG($A$3:$A$51798)=TAG(G$2))*(MONAT($A$3:$A$51798)=MONAT(G$2))*(STUNDE($B$3:$B$51798)=STUNDE(G$2))*$C$3:$C$51798)
B4	=TEXT(A4;"hh:mm")
B5	=TEXT(A5;"hh:mm")

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Was ist da bloß los. Einmal gemacht, hat funktioniert! Ein anderes malgemacht, funktioniert nicht!
Verstehe ich nicht. Kann mir da mal einer erklären was da los ist?

Schöne Grüße
Tauchmann

 

vielleicht hast Du Text in Spalte A, oder Daten die nur ausehen wie Datum. Mal mit Typ prüfen.

 

Hallo Hajo,

der typ wird als 1 zurückgegeben, also eine Zahl.
Ich habe mal die blöde Datei angehängt.

 

Hallo,

die Datei stimmt nicht mit dem ersten Beitrag überein, ich sehe kein #Wert

 

Hallo,

eigentlich war die Datei die Richtige gewesen.
Da die Datei über 50.000 Werte hat, habe ich es auf drei werte runtergeschraubt, also die anderen gelöscht. Als ich nun die überflüssigen Werte gelöscht hatte, wurde der Wert berechnet. Was könnte das sein?


Die orginal Datei ist leider 1.3 MB groß und kann somit nicht hochgeladen werden.

 

das wa ich gesagt habe es ist kein Zahl in Spalte A, Du hast Irgendwo eine Leerstelle drin.

 

Hallo Hajo,

ich habe mal alle Werte mit Typ geprüft und andschließend den Filter benutzt. Leider Alles nur 1.
Wäre es möglich dir die Datei zu schicken?

 

Du hast die Spalte A als auch die Spalte B geprüft. Du bildest ja Stunde(b3)?

 

Hallo,

wenn ich mich hier einmischen darf:

Der kritische Bereich (für das Zustandekommen des Fehlers) sind sicher die Werte in den Spalten A, B und C.
1) Den Kriterien in der SUMMENPRODUKT-Funktion macht es überhaupt nichts aus, wenn in den 3 Spalten entweder numerische bzw. Datums-Werte oder als Datum/Uhrzeit/Zahl getarnte Textwerte stehen, solange diese korrekt gebaut sind (siehe zB. Deine TEXT-Funktion in Spalte B).
2) Aber ganz empfindlich ist SUMMENPRODUKT, wenn in Spalte A,B,C irgendwo nur 1 einzige (scheinbar) leere Zelle ist, die aber in Wahrheit einen leeren Zeichenkettenwert enthält.

Nachdem Dein Bereich (lt. Formeln in F3, G3) bis in Zeile 51798 reicht, wird es sicherlich eine Reihe von leeren Zellen im Anschluss an Deine Daten geben. Vielleicht ist dort irgendwo auch nur 1 Zelle, für die Punkt 2) zutrifft.

Am einfachsten ist es, wenn Du die leeren Zeilen im Anschluss an Deine Daten bis zur Zeile 51798 markierst und dann diese löschst.
Das wirkt sicher Wunder.

 

Ich hatte die Spalte B erstellt, weil meine ersten Formeln (vor zwei Monaten) so ausgesehen hatten.
Weiterhin habe ich jetzt Spalte B gelöscht und in Spalte A das Format geändert, da schon die Zeit integriet war. Anschließend habe ich dann noch die Formel angepasst und leider nichts (grrrr).

Hast du noch eine Idee ?

	A	B	C	D	E	F	G
1	ob_time	air_temp	Typ
2	27.02.1997 07:00	5	1			01.Jan - 00:00	01.Jan - 01:00
3	27.02.1997 08:00	5	1		1997	#WERT!
4	27.02.1997 09:00	6	1		1998
5	27.02.1997 10:00	6	1		1999
6	27.02.1997 11:00	6	1		2000

Zelle	Format	Wert
A1	TT.MM.JJJJ hh:mm	ob_time
A2	TT.MM.JJJJ hh:mm	27.02.1997 07:00:00
E2	TT.MMM - hh:mm;@
F2	TT.MMM - hh:mm;@	01.01.2010
G2	TT.MMM - hh:mm;@	01.01.2010 01:00:00
A3	TT.MM.JJJJ hh:mm	27.02.1997 08:00:00
A4	TT.MM.JJJJ hh:mm	27.02.1997 09:00:00
A5	TT.MM.JJJJ hh:mm	27.02.1997 10:00:00
A6	TT.MM.JJJJ hh:mm	27.02.1997 11:00:00

Zelle	Formel
C2	=TYP(A2)
F2	=DATUM(2010;1;1)+((SPALTE()-SPALTE($F$1))/24)
G2	=DATUM(2010;1;1)+((SPALTE()-SPALTE($F$1))/24)
C3	=TYP(A3)
F3	=SUMMENPRODUKT(((JAHR($A$2:$A$51797)=$E3)*(TAG($A$2:$A$51797)=TAG(F$2))*(MONAT($A$2:$A$51797)=MONAT(F$2))*(STUNDE($A$2:$A$51797)=STUNDE(F$2)))*$B$2:$B$51797)
C4	=TYP(A4)
C5	=TYP(A5)
C6	=TYP(A6)

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Hallo,

hast Du die überzähligen leeren Zeilen gelöscht bis zur Zeile 51797 ?

Deine Typ-Formeln beziehen sich nur auf Spalte A. Der leere Textwert (Typ=2) kann sich auch in der Temperatur-Spalte enthalten sein.

 

Gibt es eine möglichkeit die mit einer formel zu prüfen?

 

Hallo

Problem gelöst. Es waren ein paar Werte ganz am Ende, die das Problem verursacht haben. Danke für Eure Hilfen und Vorschläge, die wie immer funktionieren.

Schöne Grüße

 

Hallo Tauchmann,

warum wertest Du nicht so aus:

Arbeitsblatt mit dem Namen 'Scotland_Dundee_Riverside'
	A	B	C	D	E	F	G
1	ob_time		air_temperature
2						27.02. 07:00	27.02. 08:00
3	27.02.1997	7:00	5		1997	5	5
4	27.02.1997	8:00	5		1998
5	27.02.1997	9:00	6

Zelle	Formel
F3	=SVERWEIS(DATUM($E3;MONAT(F$2);TAG(F$2))+REST(F$2;1);$A$3:$C$30;3;0)
G3	=SVERWEIS(DATUM($E3;MONAT(G$2);TAG(G$2))+REST(G$2;1);$A$3:$C$30;3;0)

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]


Für die geänderte Tabelle:

Arbeitsblatt mit dem Namen 'Scotland_Dundee_Riverside'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	ob_time	air_temperature
2	27.02.1997 07:00	5	1			27.02 00:00	27.02 01:00	27.02 02:00	27.02 03:00	27.02 04:00	27.02 05:00	27.02 06:00	27.02 07:00	27.02 08:00	27.02 09:00
3	27.02.1997 08:00	5	1		1997								5	5	6
4	27.02.1997 09:00	6	1		1998
5	27.02.1997 10:00	6	1		1999
6	27.02.1997 11:00	6	1		2000

Zelle	Formel
F2	=DATUM(2010;2;27)+((SPALTE()-6)/24)
F3	=WENN(ZÄHLENWENN($A:$A;DATUM($E3;MONAT(F$2);TAG(F$2))+REST(F$2;1))=0;"";SVERWEIS(DATUM($E3;MONAT(F$2);TAG(F$2))+REST(F$2;1);$A$2:$C$30;2;0))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]
Gruß

Edgar