Office: (Office 2010) Automatisch befüllt Combobox hat falsche Darstellung beim ersten Klick

Ich hab eine Combobox erstellt, die sich bei "OnFocus" selbst befüllt.

Wird eine Liste aller Arbeitsblätter erstellt und als Auswahl angezeigt. Dies funktioniert problemlos.

Der letzte Eintrag wird zwischengespeichert, die Liste geleert, neu aufegbaut und der zuletzt gewählte Eintrag wieder hergestellt.
Dabei werden bestimmte Arbeitsblätter ignoriert und nicht in die Liste aufgenommen.
Der dafür verwendete Code:

Code:

Private Sub ComboBox21_GotFocus()
 Dim wsTabelle As Worksheet
 Dim lastvalue As String

lastvalue = ComboBox21.Text
  ComboBox21.Clear
    For Each wsTabelle In Worksheets
        If wsTabelle.Name <> "Template" Then
        If wsTabelle.Name <> "Übersicht" Then
            ComboBox21.AddItem wsTabelle.Name
        End If
        End If
    Next wsTabelle
If lastvalue <> "" Then
ComboBox21.Text = lastvalue
End If
End Sub

Das Problem:
Bei jedem ersten Klick hat ist die Darstellung aber anders als erwartet, erst beim zweiten Klick ist sie so wie vorgesehen.

Darstellung beim ersten Klick (falsch)


Darstellung beim zweiten Klick (richtig)


Wie man sieht ist eine Dropdown Liste aller Elemente das Ziel.
Beim ersten Klick wird aber die gezeigte Darstellung gewählt. Es sind aber alle Listenelemente korrekt erzeugt worden, wenn man sie dann über die kleinen Pfeile durchgeht.

Ich bekomme es nicht hin. Ich weiss nicht warum erst beim zweiten Klick die richtige Darstellung folgt.
Hat jemand Rat?

 

Hi,

benutze ein Array:

Code:

Private Sub ComboBox1_GotFocus()
    Dim wsTabelle As Worksheet
    Dim lastvalue As String
    Dim arrDaten
    ReDim arrDaten(0)
    Dim lngZaehler As Long
    If ComboBox1.ListIndex <> -1 Then lastvalue = ComboBox1.Value
    ComboBox1.Clear
    For Each wsTabelle In Worksheets
        ReDim Preserve arrDaten(0 To lngZaehler)
        arrDaten(lngZaehler) = wsTabelle.Name
        lngZaehler = lngZaehler + 1
    Next wsTabelle
    ComboBox1.List = arrDaten
    If lastvalue <> "" Then ComboBox1.Value = lastvalue
End Sub

Bis später,
Karin

 

Clever. Danke.

Ich habe nur die Filterfunktion wieder eingefügt, die bestimmte Tabellenblätter herausfiltert um deren Anzeige zu verhindern.
Der Vollständigkeit halber daher die komplette Lösung zur Ablage:

Code:

Private Sub ComboBox21_GotFocus()
  Dim wsTabelle As Worksheet
    Dim lastvalue As String
    Dim arrDaten
    ReDim arrDaten(0)
    Dim lngZaehler As Long
    If ComboBox21.ListIndex <> -1 Then lastvalue = ComboBox21.Value
    ComboBox21.Clear
    For Each wsTabelle In Worksheets
        If wsTabelle.Name <> "Template" Then
        If wsTabelle.Name <> "Übersicht" Then
          ReDim Preserve arrDaten(0 To lngZaehler)
          arrDaten(lngZaehler) = wsTabelle.Name
          lngZaehler = lngZaehler + 1
        End If
        End If
    Next wsTabelle
    ComboBox21.List = arrDaten
    If lastvalue <> "" Then ComboBox21.Value = lastvalue
End Sub

 

Die Ausschlusskriterien kannst du in 1 Zeile abhandeln

Code:

        If wsTabelle.Name <> "Template" And wsTabelle.Name <> "Übersicht" Then
          ReDim Preserve arrDaten(0 To lngZaehler)
          arrDaten(lngZaehler) = wsTabelle.Name
          lngZaehler = lngZaehler + 1
        End If

Bis später,
Karin