Office: (Office 365) Automatische Befüllung eines Bestellfiles

Hallo allerseits.

Ich hab da eine Aufgabe, die meine Excel-Fähigkeiten leider übersteigt und ich hoffe auf Eure Hilfe:

Ich habe eine Auftragserfassungsdatei (Anhang) und möchte, dass sich die Bestelldatei (ebenfalls Anhang) damit wie vorgegeben automatisch befüllt. Ein und derselbe Kunde sollte gebündelt direkt untereinander stehen, danach der nächste usw.

Mengen mit "0" sollten nicht aufgelistet werden und es sollten keine Leerzeile enthalten sein.

Könnt Ihr mir da helfen? Ihr würdet mir einen riesen Gefallen tun.

LG,
Daniel

 

Hola,
A2:
=WENNFEHLER(INDEX([Auftragserfassung.xlsx]Tabelle1!A$13:A$16;AGGREGAT(15;6;ZEILE([Auftragserfassung.xlsx]Tabelle1!$A$13:$A$16)-12/([Auftragserfassung.xlsx]Tabelle1!$C$13:$F$16>0);ZEILE(A1)));"")
B2:
=WENNFEHLER(INDEX([Auftragserfassung.xlsx]Tabelle1!B$13:B$16;AGGREGAT(15;6;ZEILE([Auftragserfassung.xlsx]Tabelle1!$A$13:$A$16)-12/([Auftragserfassung.xlsx]Tabelle1!$C$13:$F$16>0);ZEILE(B1)));"")
C2:
=WENNFEHLER(INDEX([Auftragserfassung.xlsx]Tabelle1!$C$2:$F$2;AGGREGAT(15;6;SPALTE([Auftragserfassung.xlsx]Tabelle1!$C$2:$F$2)-2/(([Auftragserfassung.xlsx]Tabelle1!$A$13:$A$16=$A2)*([Auftragserfassung.xlsx]Tabelle1!$C$13:$F$16>0));ZÄHLENWENN($A$2:A2;A2)));"")
D2:
=WENNFEHLER(INDEX([Auftragserfassung.xlsx]Tabelle1!$C$3:$F$3;AGGREGAT(15;6;SPALTE([Auftragserfassung.xlsx]Tabelle1!$C$2:$F$2)-2/(([Auftragserfassung.xlsx]Tabelle1!$A$13:$A$16=$A2)*([Auftragserfassung.xlsx]Tabelle1!$C$13:$F$16>0));ZÄHLENWENN($A$2:A2;A2)));"")
E2:
=WENNFEHLER(SVERWEIS(A2;[Auftragserfassung.xlsx]Tabelle1!$A$13:$F$16;VERGLEICH(D2;[Auftragserfassung.xlsx]Tabelle1!$A$3:$F$3;0);0);"")
Gruß,
steve1da

 

Hi Steve!

Und wie ich mir gewünscht habe, dass Du Dich meines Problems annimmst!!

Vielen, vielen Dank. Genau so.

 

Rückmeldung:
Ich habe jetzt Deine Formeln in meinen tatsächlichen Files implementiert und was soll ich sagen? Du bist mein Excel-Gott.
Nochmal vielen herzlichen Dank. ❤️

LG,
Daniel

 

Gerne :)